git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/scopes.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Scopes do
   6   @moduledoc """
   7   Functions for dealing with scopes.
   8   """
   9
  10   alias Pleroma.Plugs.OAuthScopesPlug
  11   alias Pleroma.User
  12
  13   @doc """
  14   Fetch scopes from request params.
  15
  16   Note: `scopes` is used by Mastodon — supporting it but sticking to
  17   OAuth's standard `scope` wherever we control it
  18   """
  19   @spec fetch_scopes(map(), list()) :: list()
  20   def fetch_scopes(params, default) do
  21     parse_scopes(params["scope"] || params["scopes"], default)
  22   end
  23
  24   def parse_scopes(scopes, _default) when is_list(scopes) do
  25     Enum.filter(scopes, &(&1 not in [nil, ""]))
  26   end
  27
  28   def parse_scopes(scopes, default) when is_binary(scopes) do
  29     scopes
  30     |> to_list
  31     |> parse_scopes(default)
  32   end
  33
  34   def parse_scopes(_, default) do
  35     default
  36   end
  37
  38   @doc """
  39   Convert scopes string to list
  40   """
  41   @spec to_list(binary()) :: [binary()]
  42   def to_list(nil), do: []
  43
  44   def to_list(str) do
  45     str
  46     |> String.trim()
  47     |> String.split(~r/[\s,]+/)
  48   end
  49
  50   @doc """
  51   Convert scopes list to string
  52   """
  53   @spec to_string(list()) :: binary()
  54   def to_string(scopes), do: Enum.join(scopes, " ")
  55
  56   @doc """
  57   Validates scopes.
  58   """
  59   @spec validate(list() | nil, list(), User.t()) ::
  60           {:ok, list()} | {:error, :missing_scopes | :unsupported_scopes}
  61   def validate(blank_scopes, _app_scopes, _user) when blank_scopes in [nil, []],
  62     do: {:error, :missing_scopes}
  63
  64   def validate(scopes, app_scopes, %User{} = user) do
  65     with {:ok, _} <- ensure_scopes_support(scopes, app_scopes),
  66          {:ok, scopes} <- authorize_admin_scopes(scopes, app_scopes, user) do
  67       {:ok, scopes}
  68     end
  69   end
  70
  71   defp ensure_scopes_support(scopes, app_scopes) do
  72     case OAuthScopesPlug.filter_descendants(scopes, app_scopes) do
  73       ^scopes -> {:ok, scopes}
  74       _ -> {:error, :unsupported_scopes}
  75     end
  76   end
  77
  78   defp authorize_admin_scopes(scopes, app_scopes, %User{} = user) do
  79     if user.is_admin || !contains_admin_scopes?(scopes) || !contains_admin_scopes?(app_scopes) do
  80       {:ok, scopes}
  81     else
  82       # Gracefully dropping admin scopes from requested scopes if user isn't an admin (not raising)
  83       scopes = scopes -- OAuthScopesPlug.filter_descendants(scopes, ["admin"])
  84       validate(scopes, app_scopes, user)
  85     end
  86   end
  87
  88   def contains_admin_scopes?(scopes) do
  89     scopes
  90     |> OAuthScopesPlug.filter_descendants(["admin"])
  91     |> Enum.any?()
  92   end
  93 end