git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/oauth_controller.ex

   1 defmodule Pleroma.Web.OAuth.OAuthController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.Web.OAuth.{Authorization, Token, App}
   5   alias Pleroma.{Repo, User}
   6   alias Comeonin.Pbkdf2
   7
   8   plug(:fetch_session)
   9   plug(:fetch_flash)
  10
  11   action_fallback(Pleroma.Web.OAuth.FallbackController)
  12
  13   def authorize(conn, params) do
  14     render(conn, "show.html", %{
  15       response_type: params["response_type"],
  16       client_id: params["client_id"],
  17       scope: params["scope"],
  18       redirect_uri: params["redirect_uri"],
  19       state: params["state"]
  20     })
  21   end
  22
  23   def create_authorization(conn, %{
  24         "authorization" =>
  25           %{
  26             "name" => name,
  27             "password" => password,
  28             "client_id" => client_id,
  29             "redirect_uri" => redirect_uri
  30           } = params
  31       }) do
  32     with %User{} = user <- User.get_by_nickname_or_email(name),
  33          true <- Pbkdf2.checkpw(password, user.password_hash),
  34          %App{} = app <- Repo.get_by(App, client_id: client_id),
  35          {:ok, auth} <- Authorization.create_authorization(app, user) do
  36       if redirect_uri == "urn:ietf:wg:oauth:2.0:oob" do
  37         render(conn, "results.html", %{
  38           auth: auth
  39         })
  40       else
  41         connector = if String.contains?(redirect_uri, "?"), do: "&", else: "?"
  42         url = "#{redirect_uri}#{connector}"
  43         url_params = %{:code => auth.token}
  44
  45         url_params =
  46           if params["state"] do
  47             Map.put(url_params, :state, params["state"])
  48           else
  49             url_params
  50           end
  51
  52         url = "#{url}#{Plug.Conn.Query.encode(url_params)}"
  53
  54         redirect(conn, external: url)
  55       end
  56     end
  57   end
  58
  59   # TODO
  60   # - proper scope handling
  61   def token_exchange(conn, %{"grant_type" => "authorization_code"} = params) do
  62     with %App{} = app <- get_app_from_request(conn, params),
  63          fixed_token = fix_padding(params["code"]),
  64          %Authorization{} = auth <-
  65            Repo.get_by(Authorization, token: fixed_token, app_id: app.id),
  66          {:ok, token} <- Token.exchange_token(app, auth),
  67          {:ok, inserted_at} <- DateTime.from_naive(token.inserted_at, "Etc/UTC") do
  68       response = %{
  69         token_type: "Bearer",
  70         access_token: token.token,
  71         refresh_token: token.refresh_token,
  72         created_at: DateTime.to_unix(inserted_at),
  73         expires_in: 60 * 10,
  74         scope: "read write follow"
  75       }
  76
  77       json(conn, response)
  78     else
  79       _error ->
  80         put_status(conn, 400)
  81         |> json(%{error: "Invalid credentials"})
  82     end
  83   end
  84
  85   # TODO
  86   # - investigate a way to verify the user wants to grant read/write/follow once scope handling is done
  87   def token_exchange(
  88         conn,
  89         %{"grant_type" => "password", "username" => name, "password" => password} = params
  90       ) do
  91     with %App{} = app <- get_app_from_request(conn, params),
  92          %User{} = user <- User.get_by_nickname_or_email(name),
  93          true <- Pbkdf2.checkpw(password, user.password_hash),
  94          {:ok, auth} <- Authorization.create_authorization(app, user),
  95          {:ok, token} <- Token.exchange_token(app, auth) do
  96       response = %{
  97         token_type: "Bearer",
  98         access_token: token.token,
  99         refresh_token: token.refresh_token,
 100         expires_in: 60 * 10,
 101         scope: "read write follow"
 102       }
 103
 104       json(conn, response)
 105     else
 106       _error ->
 107         put_status(conn, 400)
 108         |> json(%{error: "Invalid credentials"})
 109     end
 110   end
 111
 112   def token_exchange(
 113         conn,
 114         %{"grant_type" => "password", "name" => name, "password" => password} = params
 115       ) do
 116     params =
 117       params
 118       |> Map.delete("name")
 119       |> Map.put("username", name)
 120
 121     token_exchange(conn, params)
 122   end
 123
 124   def token_revoke(conn, %{"token" => token} = params) do
 125     with %App{} = app <- get_app_from_request(conn, params),
 126          %Token{} = token <- Repo.get_by(Token, token: token, app_id: app.id),
 127          {:ok, %Token{}} <- Repo.delete(token) do
 128       json(conn, %{})
 129     else
 130       _error ->
 131         # RFC 7009: invalid tokens [in the request] do not cause an error response
 132         json(conn, %{})
 133     end
 134   end
 135
 136   defp fix_padding(token) do
 137     token
 138     |> Base.url_decode64!(padding: false)
 139     |> Base.url_encode64()
 140   end
 141
 142   defp get_app_from_request(conn, params) do
 143     # Per RFC 6749, HTTP Basic is preferred to body params
 144     {client_id, client_secret} =
 145       with ["Basic " <> encoded] <- get_req_header(conn, "authorization"),
 146            {:ok, decoded} <- Base.decode64(encoded),
 147            [id, secret] <-
 148              String.split(decoded, ":")
 149              |> Enum.map(fn s -> URI.decode_www_form(s) end) do
 150         {id, secret}
 151       else
 152         _ -> {params["client_id"], params["client_secret"]}
 153       end
 154
 155     if client_id && client_secret do
 156       Repo.get_by(
 157         App,
 158         client_id: client_id,
 159         client_secret: client_secret
 160       )
 161     else
 162       nil
 163     end
 164   end
 165 end