git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/oauth_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.OAuthController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Web.OAuth.Authorization
   9   alias Pleroma.Web.OAuth.Token
  10   alias Pleroma.Web.OAuth.App
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Comeonin.Pbkdf2
  14
  15   import Pleroma.Web.ControllerHelper, only: [oauth_scopes: 2]
  16
  17   plug(:fetch_session)
  18   plug(:fetch_flash)
  19
  20   action_fallback(Pleroma.Web.OAuth.FallbackController)
  21
  22   def authorize(conn, params) do
  23     app = Repo.get_by(App, client_id: params["client_id"])
  24     available_scopes = (app && app.scopes) || []
  25     scopes = oauth_scopes(params, nil) || available_scopes
  26
  27     render(conn, "show.html", %{
  28       response_type: params["response_type"],
  29       client_id: params["client_id"],
  30       available_scopes: available_scopes,
  31       scopes: scopes,
  32       redirect_uri: params["redirect_uri"],
  33       state: params["state"]
  34     })
  35   end
  36
  37   def create_authorization(conn, %{
  38         "authorization" =>
  39           %{
  40             "name" => name,
  41             "password" => password,
  42             "client_id" => client_id,
  43             "redirect_uri" => redirect_uri
  44           } = auth_params
  45       }) do
  46     with %User{} = user <- User.get_by_nickname_or_email(name),
  47          true <- Pbkdf2.checkpw(password, user.password_hash),
  48          %App{} = app <- Repo.get_by(App, client_id: client_id),
  49          true <- redirect_uri in String.split(app.redirect_uris),
  50          scopes <- oauth_scopes(auth_params, []),
  51          {:unsupported_scopes, []} <- {:unsupported_scopes, scopes -- app.scopes},
  52          # Note: `scope` param is intentionally not optional in this context
  53          {:missing_scopes, false} <- {:missing_scopes, scopes == []},
  54          {:auth_active, true} <- {:auth_active, User.auth_active?(user)},
  55          {:ok, auth} <- Authorization.create_authorization(app, user, scopes) do
  56       # Special case: Local MastodonFE.
  57       redirect_uri =
  58         if redirect_uri == "." do
  59           mastodon_api_url(conn, :login)
  60         else
  61           redirect_uri
  62         end
  63
  64       cond do
  65         redirect_uri == "urn:ietf:wg:oauth:2.0:oob" ->
  66           render(conn, "results.html", %{
  67             auth: auth
  68           })
  69
  70         true ->
  71           connector = if String.contains?(redirect_uri, "?"), do: "&", else: "?"
  72           url = "#{redirect_uri}#{connector}"
  73           url_params = %{:code => auth.token}
  74
  75           url_params =
  76             if auth_params["state"] do
  77               Map.put(url_params, :state, auth_params["state"])
  78             else
  79               url_params
  80             end
  81
  82           url = "#{url}#{Plug.Conn.Query.encode(url_params)}"
  83
  84           redirect(conn, external: url)
  85       end
  86     else
  87       {scopes_issue, _} when scopes_issue in [:unsupported_scopes, :missing_scopes] ->
  88         conn
  89         |> put_flash(:error, "Permissions not specified.")
  90         |> put_status(:unauthorized)
  91         |> authorize(auth_params)
  92
  93       {:auth_active, false} ->
  94         conn
  95         |> put_flash(:error, "Account confirmation pending.")
  96         |> put_status(:forbidden)
  97         |> authorize(auth_params)
  98
  99       error ->
 100         error
 101     end
 102   end
 103
 104   def token_exchange(conn, %{"grant_type" => "authorization_code"} = params) do
 105     with %App{} = app <- get_app_from_request(conn, params),
 106          fixed_token = fix_padding(params["code"]),
 107          %Authorization{} = auth <-
 108            Repo.get_by(Authorization, token: fixed_token, app_id: app.id),
 109          {:ok, token} <- Token.exchange_token(app, auth),
 110          {:ok, inserted_at} <- DateTime.from_naive(token.inserted_at, "Etc/UTC") do
 111       response = %{
 112         token_type: "Bearer",
 113         access_token: token.token,
 114         refresh_token: token.refresh_token,
 115         created_at: DateTime.to_unix(inserted_at),
 116         expires_in: 60 * 10,
 117         scope: Enum.join(token.scopes)
 118       }
 119
 120       json(conn, response)
 121     else
 122       _error ->
 123         put_status(conn, 400)
 124         |> json(%{error: "Invalid credentials"})
 125     end
 126   end
 127
 128   def token_exchange(
 129         conn,
 130         %{"grant_type" => "password", "username" => name, "password" => password} = params
 131       ) do
 132     with %App{} = app <- get_app_from_request(conn, params),
 133          %User{} = user <- User.get_by_nickname_or_email(name),
 134          true <- Pbkdf2.checkpw(password, user.password_hash),
 135          {:auth_active, true} <- {:auth_active, User.auth_active?(user)},
 136          scopes <- oauth_scopes(params, app.scopes),
 137          [] <- scopes -- app.scopes,
 138          true <- Enum.any?(scopes),
 139          {:ok, auth} <- Authorization.create_authorization(app, user, scopes),
 140          {:ok, token} <- Token.exchange_token(app, auth) do
 141       response = %{
 142         token_type: "Bearer",
 143         access_token: token.token,
 144         refresh_token: token.refresh_token,
 145         expires_in: 60 * 10,
 146         scope: Enum.join(token.scopes, " ")
 147       }
 148
 149       json(conn, response)
 150     else
 151       {:auth_active, false} ->
 152         conn
 153         |> put_status(:forbidden)
 154         |> json(%{error: "Account confirmation pending"})
 155
 156       _error ->
 157         put_status(conn, 400)
 158         |> json(%{error: "Invalid credentials"})
 159     end
 160   end
 161
 162   def token_exchange(
 163         conn,
 164         %{"grant_type" => "password", "name" => name, "password" => _password} = params
 165       ) do
 166     params =
 167       params
 168       |> Map.delete("name")
 169       |> Map.put("username", name)
 170
 171     token_exchange(conn, params)
 172   end
 173
 174   def token_revoke(conn, %{"token" => token} = params) do
 175     with %App{} = app <- get_app_from_request(conn, params),
 176          %Token{} = token <- Repo.get_by(Token, token: token, app_id: app.id),
 177          {:ok, %Token{}} <- Repo.delete(token) do
 178       json(conn, %{})
 179     else
 180       _error ->
 181         # RFC 7009: invalid tokens [in the request] do not cause an error response
 182         json(conn, %{})
 183     end
 184   end
 185
 186   # XXX - for whatever reason our token arrives urlencoded, but Plug.Conn should be
 187   # decoding it.  Investigate sometime.
 188   defp fix_padding(token) do
 189     token
 190     |> URI.decode()
 191     |> Base.url_decode64!(padding: false)
 192     |> Base.url_encode64(padding: false)
 193   end
 194
 195   defp get_app_from_request(conn, params) do
 196     # Per RFC 6749, HTTP Basic is preferred to body params
 197     {client_id, client_secret} =
 198       with ["Basic " <> encoded] <- get_req_header(conn, "authorization"),
 199            {:ok, decoded} <- Base.decode64(encoded),
 200            [id, secret] <-
 201              String.split(decoded, ":")
 202              |> Enum.map(fn s -> URI.decode_www_form(s) end) do
 203         {id, secret}
 204       else
 205         _ -> {params["client_id"], params["client_secret"]}
 206       end
 207
 208     if client_id && client_secret do
 209       Repo.get_by(
 210         App,
 211         client_id: client_id,
 212         client_secret: client_secret
 213       )
 214     else
 215       nil
 216     end
 217   end
 218 end