git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/authorization.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Authorization do
   6   use Ecto.Schema
   7
   8   alias Pleroma.User
   9   alias Pleroma.Repo
  10   alias Pleroma.Web.OAuth.Authorization
  11   alias Pleroma.Web.OAuth.App
  12
  13   import Ecto.{Changeset, Query}
  14
  15   schema "oauth_authorizations" do
  16     field(:token, :string)
  17     field(:valid_until, :naive_datetime)
  18     field(:used, :boolean, default: false)
  19     belongs_to(:user, Pleroma.User, type: Pleroma.FlakeId)
  20     belongs_to(:app, App)
  21
  22     timestamps()
  23   end
  24
  25   def create_authorization(%App{} = app, %User{} = user) do
  26     token = :crypto.strong_rand_bytes(32) |> Base.url_encode64()
  27
  28     authorization = %Authorization{
  29       token: token,
  30       used: false,
  31       user_id: user.id,
  32       app_id: app.id,
  33       valid_until: NaiveDateTime.add(NaiveDateTime.utc_now(), 60 * 10)
  34     }
  35
  36     Repo.insert(authorization)
  37   end
  38
  39   def use_changeset(%Authorization{} = auth, params) do
  40     auth
  41     |> cast(params, [:used])
  42     |> validate_required([:used])
  43   end
  44
  45   def use_token(%Authorization{used: false, valid_until: valid_until} = auth) do
  46     if NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) < 0 do
  47       Repo.update(use_changeset(auth, %{used: true}))
  48     else
  49       {:error, "token expired"}
  50     end
  51   end
  52
  53   def use_token(%Authorization{used: true}), do: {:error, "already used"}
  54
  55   def delete_user_authorizations(%User{id: user_id}) do
  56     from(
  57       a in Pleroma.Web.OAuth.Authorization,
  58       where: a.user_id == ^user_id
  59     )
  60     |> Repo.delete_all()
  61   end
  62 end