git.squeep.com Git - akkoma/blob - lib/pleroma/web/oauth/app.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.App do
   6   use Ecto.Schema
   7   import Ecto.Changeset
   8   import Ecto.Query
   9   alias Pleroma.Repo
  10
  11   @type t :: %__MODULE__{}
  12
  13   schema "apps" do
  14     field(:client_name, :string)
  15     field(:redirect_uris, :string)
  16     field(:scopes, {:array, :string}, default: [])
  17     field(:website, :string)
  18     field(:client_id, :string)
  19     field(:client_secret, :string)
  20     field(:trusted, :boolean, default: false)
  21
  22     has_many(:oauth_authorizations, Pleroma.Web.OAuth.Authorization, on_delete: :delete_all)
  23     has_many(:oauth_tokens, Pleroma.Web.OAuth.Token, on_delete: :delete_all)
  24
  25     timestamps()
  26   end
  27
  28   @spec changeset(App.t(), map()) :: Ecto.Changeset.t()
  29   def changeset(struct, params) do
  30     cast(struct, params, [:client_name, :redirect_uris, :scopes, :website, :trusted])
  31   end
  32
  33   @spec register_changeset(App.t(), map()) :: Ecto.Changeset.t()
  34   def register_changeset(struct, params \\ %{}) do
  35     changeset =
  36       struct
  37       |> changeset(params)
  38       |> validate_required([:client_name, :redirect_uris, :scopes])
  39
  40     if changeset.valid? do
  41       changeset
  42       |> put_change(
  43         :client_id,
  44         :crypto.strong_rand_bytes(32) |> Base.url_encode64(padding: false)
  45       )
  46       |> put_change(
  47         :client_secret,
  48         :crypto.strong_rand_bytes(32) |> Base.url_encode64(padding: false)
  49       )
  50     else
  51       changeset
  52     end
  53   end
  54
  55   @spec create(map()) :: {:ok, App.t()} | {:error, Ecto.Changeset.t()}
  56   def create(params) do
  57     with changeset <- __MODULE__.register_changeset(%__MODULE__{}, params) do
  58       Repo.insert(changeset)
  59     end
  60   end
  61
  62   @spec update(map()) :: {:ok, App.t()} | {:error, Ecto.Changeset.t()}
  63   def update(params) do
  64     with %__MODULE__{} = app <- Repo.get(__MODULE__, params["id"]),
  65          changeset <- changeset(app, params) do
  66       Repo.update(changeset)
  67     end
  68   end
  69
  70   @doc """
  71   Gets app by attrs or create new  with attrs.
  72   And updates the scopes if need.
  73   """
  74   @spec get_or_make(map(), list(String.t())) :: {:ok, App.t()} | {:error, Ecto.Changeset.t()}
  75   def get_or_make(attrs, scopes) do
  76     with %__MODULE__{} = app <- Repo.get_by(__MODULE__, attrs) do
  77       update_scopes(app, scopes)
  78     else
  79       _e ->
  80         %__MODULE__{}
  81         |> register_changeset(Map.put(attrs, :scopes, scopes))
  82         |> Repo.insert()
  83     end
  84   end
  85
  86   defp update_scopes(%__MODULE__{} = app, []), do: {:ok, app}
  87   defp update_scopes(%__MODULE__{scopes: scopes} = app, scopes), do: {:ok, app}
  88
  89   defp update_scopes(%__MODULE__{} = app, scopes) do
  90     app
  91     |> change(%{scopes: scopes})
  92     |> Repo.update()
  93   end
  94
  95   @spec search(map()) :: {:ok, [App.t()], non_neg_integer()}
  96   def search(params) do
  97     query = from(a in __MODULE__)
  98
  99     query =
 100       if params[:client_name] do
 101         from(a in query, where: a.client_name == ^params[:client_name])
 102       else
 103         query
 104       end
 105
 106     query =
 107       if params[:client_id] do
 108         from(a in query, where: a.client_id == ^params[:client_id])
 109       else
 110         query
 111       end
 112
 113     query =
 114       if Map.has_key?(params, :trusted) do
 115         from(a in query, where: a.trusted == ^params[:trusted])
 116       else
 117         query
 118       end
 119
 120     query =
 121       from(u in query,
 122         limit: ^params[:page_size],
 123         offset: ^((params[:page] - 1) * params[:page_size])
 124       )
 125
 126     count = Repo.aggregate(__MODULE__, :count, :id)
 127
 128     {:ok, Repo.all(query), count}
 129   end
 130
 131   @spec destroy(pos_integer()) :: {:ok, App.t()} | {:error, Ecto.Changeset.t()}
 132   def destroy(id) do
 133     with %__MODULE__{} = app <- Repo.get(__MODULE__, id) do
 134       Repo.delete(app)
 135     end
 136   end
 137
 138   @spec errors(Ecto.Changeset.t()) :: map()
 139   def errors(changeset) do
 140     Enum.reduce(changeset.errors, %{}, fn
 141       {:client_name, {error, _}}, acc ->
 142         Map.put(acc, :name, error)
 143
 144       {key, {error, _}}, acc ->
 145         Map.put(acc, key, error)
 146     end)
 147   end
 148 end