git.squeep.com Git - akkoma/blob - lib/pleroma/web/o_auth/token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Token do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.OAuth.App
  13   alias Pleroma.Web.OAuth.Authorization
  14   alias Pleroma.Web.OAuth.Token
  15   alias Pleroma.Web.OAuth.Token.Query
  16
  17   @type t :: %__MODULE__{}
  18
  19   schema "oauth_tokens" do
  20     field(:token, :string)
  21     field(:refresh_token, :string)
  22     field(:scopes, {:array, :string}, default: [])
  23     field(:valid_until, :naive_datetime_usec)
  24     belongs_to(:user, User, type: FlakeId.Ecto.CompatType)
  25     belongs_to(:app, App)
  26
  27     timestamps()
  28   end
  29
  30   @doc "Gets token by unique access token"
  31   @spec get_by_token(String.t()) :: {:ok, t()} | {:error, :not_found}
  32   def get_by_token(token) do
  33     token
  34     |> Query.get_by_token()
  35     |> Repo.find_resource()
  36   end
  37
  38   @doc "Gets token for app by access token"
  39   @spec get_by_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  40   def get_by_token(%App{id: app_id} = _app, token) do
  41     Query.get_by_app(app_id)
  42     |> Query.get_by_token(token)
  43     |> Repo.find_resource()
  44   end
  45
  46   @doc "Gets token for app by refresh token"
  47   @spec get_by_refresh_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  48   def get_by_refresh_token(%App{id: app_id} = _app, token) do
  49     Query.get_by_app(app_id)
  50     |> Query.get_by_refresh_token(token)
  51     |> Query.preload([:user])
  52     |> Repo.find_resource()
  53   end
  54
  55   @spec exchange_token(App.t(), Authorization.t()) :: {:ok, Token.t()} | {:error, Changeset.t()}
  56   def exchange_token(app, auth) do
  57     with {:ok, auth} <- Authorization.use_token(auth),
  58          true <- auth.app_id == app.id do
  59       user = if auth.user_id, do: User.get_cached_by_id(auth.user_id), else: %User{}
  60
  61       create(
  62         app,
  63         user,
  64         %{scopes: auth.scopes}
  65       )
  66     end
  67   end
  68
  69   defp put_token(changeset) do
  70     changeset
  71     |> change(%{token: Token.Utils.generate_token()})
  72     |> validate_required([:token])
  73     |> unique_constraint(:token)
  74   end
  75
  76   defp put_refresh_token(changeset, attrs) do
  77     refresh_token = Map.get(attrs, :refresh_token, Token.Utils.generate_token())
  78
  79     changeset
  80     |> change(%{refresh_token: refresh_token})
  81     |> validate_required([:refresh_token])
  82     |> unique_constraint(:refresh_token)
  83   end
  84
  85   defp put_valid_until(changeset, attrs) do
  86     expires_in =
  87       Map.get(attrs, :valid_until, NaiveDateTime.add(NaiveDateTime.utc_now(), expires_in()))
  88
  89     changeset
  90     |> change(%{valid_until: expires_in})
  91     |> validate_required([:valid_until])
  92   end
  93
  94   @spec create(App.t(), User.t(), map()) :: {:ok, Token} | {:error, Changeset.t()}
  95   def create(%App{} = app, %User{} = user, attrs \\ %{}) do
  96     with {:ok, token} <- do_create(app, user, attrs) do
  97       if Pleroma.Config.get([:oauth2, :clean_expired_tokens]) do
  98         Pleroma.Workers.PurgeExpiredToken.enqueue(%{
  99           token_id: token.id,
 100           valid_until: DateTime.from_naive!(token.valid_until, "Etc/UTC"),
 101           mod: __MODULE__
 102         })
 103       end
 104
 105       {:ok, token}
 106     end
 107   end
 108
 109   defp do_create(app, user, attrs) do
 110     %__MODULE__{user_id: user.id, app_id: app.id}
 111     |> cast(%{scopes: attrs[:scopes] || app.scopes}, [:scopes])
 112     |> validate_required([:scopes, :app_id])
 113     |> put_valid_until(attrs)
 114     |> put_token()
 115     |> put_refresh_token(attrs)
 116     |> Repo.insert()
 117   end
 118
 119   def delete_user_tokens(%User{id: user_id}) do
 120     Query.get_by_user(user_id)
 121     |> Repo.delete_all()
 122   end
 123
 124   def delete_user_token(%User{id: user_id}, token_id) do
 125     Query.get_by_user(user_id)
 126     |> Query.get_by_id(token_id)
 127     |> Repo.delete_all()
 128   end
 129
 130   def get_user_tokens(%User{id: user_id}) do
 131     Query.get_by_user(user_id)
 132     |> Query.preload([:app])
 133     |> Repo.all()
 134   end
 135
 136   def is_expired?(%__MODULE__{valid_until: valid_until}) do
 137     NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) > 0
 138   end
 139
 140   def is_expired?(_), do: false
 141
 142   defp expires_in, do: Pleroma.Config.get([:oauth2, :token_expires_in], 600)
 143 end