git.squeep.com Git - akkoma/blob - lib/pleroma/web/o_auth/token.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2021 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.OAuth.Token do
   6   use Ecto.Schema
   7
   8   import Ecto.Changeset
   9
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.OAuth.App
  13   alias Pleroma.Web.OAuth.Authorization
  14   alias Pleroma.Web.OAuth.Token
  15   alias Pleroma.Web.OAuth.Token.Query
  16
  17   @type t :: %__MODULE__{}
  18
  19   schema "oauth_tokens" do
  20     field(:token, :string)
  21     field(:refresh_token, :string)
  22     field(:scopes, {:array, :string}, default: [])
  23     field(:valid_until, :naive_datetime_usec)
  24     belongs_to(:user, User, type: FlakeId.Ecto.CompatType)
  25     belongs_to(:app, App)
  26
  27     timestamps()
  28   end
  29
  30   def lifespan do
  31     Pleroma.Config.get!([:oauth2, :token_expires_in])
  32   end
  33
  34   @doc "Gets token by unique access token"
  35   @spec get_by_token(String.t()) :: {:ok, t()} | {:error, :not_found}
  36   def get_by_token(token) do
  37     token
  38     |> Query.get_by_token()
  39     |> Repo.find_resource()
  40   end
  41
  42   def get_by_app(%App{} = app) do
  43     app.id
  44     |> Query.get_unexpired_by_app()
  45     |> Repo.find_resource()
  46   end
  47
  48   @doc "Gets token for app by access token"
  49   @spec get_by_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  50   def get_by_token(%App{id: app_id} = _app, token) do
  51     Query.get_by_app(app_id)
  52     |> Query.get_by_token(token)
  53     |> Repo.find_resource()
  54   end
  55
  56   @doc "Gets token for app by refresh token"
  57   @spec get_by_refresh_token(App.t(), String.t()) :: {:ok, t()} | {:error, :not_found}
  58   def get_by_refresh_token(%App{id: app_id} = _app, token) do
  59     Query.get_by_app(app_id)
  60     |> Query.get_by_refresh_token(token)
  61     |> Query.preload([:user])
  62     |> Repo.find_resource()
  63   end
  64
  65   @spec exchange_token(App.t(), Authorization.t()) :: {:ok, Token.t()} | {:error, Changeset.t()}
  66   def exchange_token(app, auth) do
  67     with {:ok, auth} <- Authorization.use_token(auth),
  68          true <- auth.app_id == app.id do
  69       user = if auth.user_id, do: User.get_cached_by_id(auth.user_id), else: %User{}
  70
  71       create(
  72         app,
  73         user,
  74         %{scopes: auth.scopes}
  75       )
  76     end
  77   end
  78
  79   defp put_token(changeset) do
  80     changeset
  81     |> change(%{token: Token.Utils.generate_token()})
  82     |> validate_required([:token])
  83     |> unique_constraint(:token)
  84   end
  85
  86   defp put_refresh_token(changeset, attrs) do
  87     refresh_token = Map.get(attrs, :refresh_token, Token.Utils.generate_token())
  88
  89     changeset
  90     |> change(%{refresh_token: refresh_token})
  91     |> validate_required([:refresh_token])
  92     |> unique_constraint(:refresh_token)
  93   end
  94
  95   defp put_valid_until(changeset, attrs) do
  96     valid_until =
  97       Map.get(attrs, :valid_until, NaiveDateTime.add(NaiveDateTime.utc_now(), lifespan()))
  98
  99     changeset
 100     |> change(%{valid_until: valid_until})
 101     |> validate_required([:valid_until])
 102   end
 103
 104   @spec create(App.t(), User.t(), map()) :: {:ok, Token} | {:error, Changeset.t()}
 105   def create(%App{} = app, %User{} = user, attrs \\ %{}) do
 106     with {:ok, token} <- do_create(app, user, attrs) do
 107       if Pleroma.Config.get([:oauth2, :clean_expired_tokens]) do
 108         Pleroma.Workers.PurgeExpiredToken.enqueue(%{
 109           token_id: token.id,
 110           valid_until: DateTime.from_naive!(token.valid_until, "Etc/UTC"),
 111           mod: __MODULE__
 112         })
 113       end
 114
 115       {:ok, token}
 116     end
 117   end
 118
 119   defp do_create(app, user, attrs) do
 120     %__MODULE__{user_id: user.id, app_id: app.id}
 121     |> cast(%{scopes: attrs[:scopes] || app.scopes}, [:scopes])
 122     |> validate_required([:scopes, :app_id])
 123     |> put_valid_until(attrs)
 124     |> put_token()
 125     |> put_refresh_token(attrs)
 126     |> Repo.insert()
 127   end
 128
 129   def delete_user_tokens(%User{id: user_id}) do
 130     Query.get_by_user(user_id)
 131     |> Repo.delete_all()
 132   end
 133
 134   def delete_user_token(%User{id: user_id}, token_id) do
 135     Query.get_by_user(user_id)
 136     |> Query.get_by_id(token_id)
 137     |> Repo.delete_all()
 138   end
 139
 140   def get_user_tokens(%User{id: user_id}) do
 141     Query.get_by_user(user_id)
 142     |> Query.preload([:app])
 143     |> Repo.all()
 144   end
 145
 146   def is_expired?(%__MODULE__{valid_until: valid_until}) do
 147     NaiveDateTime.diff(NaiveDateTime.utc_now(), valid_until) > 0
 148   end
 149
 150   def is_expired?(_), do: false
 151 end