git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.ActivityPub.MRF
  13   alias Pleroma.Web.Federator.Publisher
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36
  37     quarantined = Config.get([:instance, :quarantined_instances], [])
  38
  39     staff_accounts =
  40       User.all_superusers()
  41       |> Enum.map(fn u -> u.ap_id end)
  42
  43     federation_response =
  44       if Config.get([:instance, :mrf_transparency]) do
  45         {:ok, data} = MRF.describe()
  46
  47         data
  48         |> Map.merge(%{quarantined_instances: quarantined})
  49       else
  50         %{}
  51       end
  52       |> Map.put(:enabled, Config.get([:instance, :federating]))
  53
  54     features =
  55       [
  56         "pleroma_api",
  57         "mastodon_api",
  58         "mastodon_api_streaming",
  59         "polls",
  60         "pleroma_explicit_addressing",
  61         "shareable_emoji_packs",
  62         "multifetch",
  63         "pleroma:api/v1/notifications:include_types_filter",
  64         if Config.get([:media_proxy, :enabled]) do
  65           "media_proxy"
  66         end,
  67         if Config.get([:gopher, :enabled]) do
  68           "gopher"
  69         end,
  70         if Config.get([:chat, :enabled]) do
  71           "chat"
  72         end,
  73         if Config.get([:instance, :allow_relay]) do
  74           "relay"
  75         end,
  76         if Config.get([:instance, :safe_dm_mentions]) do
  77           "safe_dm_mentions"
  78         end,
  79         "pleroma_emoji_reactions"
  80       ]
  81       |> Enum.filter(& &1)
  82
  83     %{
  84       version: "2.0",
  85       software: %{
  86         name: Pleroma.Application.name() |> String.downcase(),
  87         version: Pleroma.Application.version()
  88       },
  89       protocols: Publisher.gather_nodeinfo_protocol_names(),
  90       services: %{
  91         inbound: [],
  92         outbound: []
  93       },
  94       openRegistrations: Config.get([:instance, :registrations_open]),
  95       usage: %{
  96         users: %{
  97           total: Map.get(stats, :user_count, 0)
  98         },
  99         localPosts: Map.get(stats, :status_count, 0)
 100       },
 101       metadata: %{
 102         nodeName: Config.get([:instance, :name]),
 103         nodeDescription: Config.get([:instance, :description]),
 104         private: !Config.get([:instance, :public], true),
 105         suggestions: %{
 106           enabled: false
 107         },
 108         staffAccounts: staff_accounts,
 109         federation: federation_response,
 110         pollLimits: Config.get([:instance, :poll_limits]),
 111         postFormats: Config.get([:instance, :allowed_post_formats]),
 112         uploadLimits: %{
 113           general: Config.get([:instance, :upload_limit]),
 114           avatar: Config.get([:instance, :avatar_upload_limit]),
 115           banner: Config.get([:instance, :banner_upload_limit]),
 116           background: Config.get([:instance, :background_upload_limit])
 117         },
 118         fieldsLimits: %{
 119           maxFields: Config.get([:instance, :max_account_fields]),
 120           maxRemoteFields: Config.get([:instance, :max_remote_account_fields]),
 121           nameLength: Config.get([:instance, :account_field_name_length]),
 122           valueLength: Config.get([:instance, :account_field_value_length])
 123         },
 124         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 125         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 126         mailerEnabled: Config.get([Pleroma.Emails.Mailer, :enabled], false),
 127         features: features,
 128         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames]),
 129         skipThreadContainment: Config.get([:instance, :skip_thread_containment], false)
 130       }
 131     }
 132   end
 133
 134   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
 135   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
 136   def nodeinfo(conn, %{"version" => "2.0"}) do
 137     conn
 138     |> put_resp_header(
 139       "content-type",
 140       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 141     )
 142     |> json(raw_nodeinfo())
 143   end
 144
 145   def nodeinfo(conn, %{"version" => "2.1"}) do
 146     raw_response = raw_nodeinfo()
 147
 148     updated_software =
 149       raw_response
 150       |> Map.get(:software)
 151       |> Map.put(:repository, Pleroma.Application.repository())
 152
 153     response =
 154       raw_response
 155       |> Map.put(:software, updated_software)
 156       |> Map.put(:version, "2.1")
 157
 158     conn
 159     |> put_resp_header(
 160       "content-type",
 161       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 162     )
 163     |> json(response)
 164   end
 165
 166   def nodeinfo(conn, _) do
 167     render_error(conn, :not_found, "Nodeinfo schema version not handled")
 168   end
 169 end