git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.Federator.Publisher
  13   alias Pleroma.Web.MastodonAPI.InstanceView
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36
  37     staff_accounts =
  38       User.all_superusers()
  39       |> Enum.map(fn u -> u.ap_id end)
  40
  41     features = InstanceView.features()
  42     federation = InstanceView.federation()
  43
  44     %{
  45       version: "2.0",
  46       software: %{
  47         name: Pleroma.Application.name() |> String.downcase(),
  48         version: Pleroma.Application.version()
  49       },
  50       protocols: Publisher.gather_nodeinfo_protocol_names(),
  51       services: %{
  52         inbound: [],
  53         outbound: []
  54       },
  55       openRegistrations: Config.get([:instance, :registrations_open]),
  56       usage: %{
  57         users: %{
  58           total: Map.get(stats, :user_count, 0)
  59         },
  60         localPosts: Map.get(stats, :status_count, 0)
  61       },
  62       metadata: %{
  63         nodeName: Config.get([:instance, :name]),
  64         nodeDescription: Config.get([:instance, :description]),
  65         private: !Config.get([:instance, :public], true),
  66         suggestions: %{
  67           enabled: false
  68         },
  69         staffAccounts: staff_accounts,
  70         federation: federation,
  71         pollLimits: Config.get([:instance, :poll_limits]),
  72         postFormats: Config.get([:instance, :allowed_post_formats]),
  73         uploadLimits: %{
  74           general: Config.get([:instance, :upload_limit]),
  75           avatar: Config.get([:instance, :avatar_upload_limit]),
  76           banner: Config.get([:instance, :banner_upload_limit]),
  77           background: Config.get([:instance, :background_upload_limit])
  78         },
  79         fieldsLimits: %{
  80           maxFields: Config.get([:instance, :max_account_fields]),
  81           maxRemoteFields: Config.get([:instance, :max_remote_account_fields]),
  82           nameLength: Config.get([:instance, :account_field_name_length]),
  83           valueLength: Config.get([:instance, :account_field_value_length])
  84         },
  85         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
  86         invitesEnabled: Config.get([:instance, :invites_enabled], false),
  87         mailerEnabled: Config.get([Pleroma.Emails.Mailer, :enabled], false),
  88         features: features,
  89         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames]),
  90         skipThreadContainment: Config.get([:instance, :skip_thread_containment], false)
  91       }
  92     }
  93   end
  94
  95   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
  96   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
  97   def nodeinfo(conn, %{"version" => "2.0"}) do
  98     conn
  99     |> put_resp_header(
 100       "content-type",
 101       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 102     )
 103     |> json(raw_nodeinfo())
 104   end
 105
 106   def nodeinfo(conn, %{"version" => "2.1"}) do
 107     raw_response = raw_nodeinfo()
 108
 109     updated_software =
 110       raw_response
 111       |> Map.get(:software)
 112       |> Map.put(:repository, Pleroma.Application.repository())
 113
 114     response =
 115       raw_response
 116       |> Map.put(:software, updated_software)
 117       |> Map.put(:version, "2.1")
 118
 119     conn
 120     |> put_resp_header(
 121       "content-type",
 122       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 123     )
 124     |> json(response)
 125   end
 126
 127   def nodeinfo(conn, _) do
 128     render_error(conn, :not_found, "Nodeinfo schema version not handled")
 129   end
 130 end