git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.Stats
   5   alias Pleroma.Web
   6   alias Pleroma.{User, Repo}
   7   alias Pleroma.Web.ActivityPub.MRF
   8
   9   def schemas(conn, _params) do
  10     response = %{
  11       links: [
  12         %{
  13           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  14           href: Web.base_url() <> "/nodeinfo/2.0.json"
  15         }
  16       ]
  17     }
  18
  19     json(conn, response)
  20   end
  21
  22   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
  23   def nodeinfo(conn, %{"version" => "2.0"}) do
  24     instance = Application.get_env(:pleroma, :instance)
  25     media_proxy = Application.get_env(:pleroma, :media_proxy)
  26     suggestions = Application.get_env(:pleroma, :suggestions)
  27     chat = Application.get_env(:pleroma, :chat)
  28     gopher = Application.get_env(:pleroma, :gopher)
  29     stats = Stats.get_stats()
  30
  31     mrf_simple =
  32       Application.get_env(:pleroma, :mrf_simple)
  33       |> Enum.into(%{})
  34
  35     mrf_policies =
  36       MRF.get_policies()
  37       |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)
  38
  39     quarantined = Keyword.get(instance, :quarantined_instances)
  40
  41     quarantined =
  42       if is_list(quarantined) do
  43         quarantined
  44       else
  45         []
  46       end
  47
  48     staff_accounts =
  49       User.moderator_user_query()
  50       |> Repo.all()
  51       |> Enum.map(fn u -> u.ap_id end)
  52
  53     mrf_transparency = Keyword.get(instance, :mrf_transparency)
  54
  55     federation_response =
  56       if mrf_transparency do
  57         %{
  58           mrf_policies: mrf_policies,
  59           mrf_simple: mrf_simple,
  60           quarantined_instances: quarantined
  61         }
  62       else
  63         %{}
  64       end
  65
  66     response = %{
  67       version: "2.0",
  68       software: %{
  69         name: "pleroma",
  70         version: Keyword.get(instance, :version)
  71       },
  72       protocols: ["ostatus", "activitypub"],
  73       services: %{
  74         inbound: [],
  75         outbound: []
  76       },
  77       openRegistrations: Keyword.get(instance, :registrations_open),
  78       usage: %{
  79         users: %{
  80           total: stats.user_count || 0
  81         },
  82         localPosts: stats.status_count || 0
  83       },
  84       metadata: %{
  85         nodeName: Keyword.get(instance, :name),
  86         nodeDescription: Keyword.get(instance, :description),
  87         mediaProxy: Keyword.get(media_proxy, :enabled),
  88         private: !Keyword.get(instance, :public, true),
  89         suggestions: %{
  90           enabled: Keyword.get(suggestions, :enabled, false),
  91           thirdPartyEngine: Keyword.get(suggestions, :third_party_engine, ""),
  92           timeout: Keyword.get(suggestions, :timeout, 5000),
  93           limit: Keyword.get(suggestions, :limit, 23),
  94           web: Keyword.get(suggestions, :web, "")
  95         },
  96         staffAccounts: staff_accounts,
  97         chat: Keyword.get(chat, :enabled),
  98         gopher: Keyword.get(gopher, :enabled),
  99         federation: federation_response,
 100         postFormats: Keyword.get(instance, :allowed_post_formats)
 101       }
 102     }
 103
 104     conn
 105     |> put_resp_header(
 106       "content-type",
 107       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 108     )
 109     |> json(response)
 110   end
 111
 112   def nodeinfo(conn, _) do
 113     conn
 114     |> put_status(404)
 115     |> json(%{error: "Nodeinfo schema version not handled"})
 116   end
 117 end