git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.ActivityPub.MRF
  13   alias Pleroma.Web.Federator.Publisher
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36
  37     mrf_simple =
  38       Config.get(:mrf_simple)
  39       |> Enum.into(%{})
  40
  41     # This horror is needed to convert regex sigils to strings
  42     mrf_keyword =
  43       Config.get(:mrf_keyword, [])
  44       |> Enum.map(fn {key, value} ->
  45         {key,
  46          Enum.map(value, fn
  47            {pattern, replacement} ->
  48              %{
  49                "pattern" =>
  50                  if not is_binary(pattern) do
  51                    inspect(pattern)
  52                  else
  53                    pattern
  54                  end,
  55                "replacement" => replacement
  56              }
  57
  58            pattern ->
  59              if not is_binary(pattern) do
  60                inspect(pattern)
  61              else
  62                pattern
  63              end
  64          end)}
  65       end)
  66       |> Enum.into(%{})
  67
  68     mrf_policies =
  69       MRF.get_policies()
  70       |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)
  71
  72     quarantined = Config.get([:instance, :quarantined_instances], [])
  73
  74     staff_accounts =
  75       User.all_superusers()
  76       |> Enum.map(fn u -> u.ap_id end)
  77
  78     mrf_user_allowlist =
  79       Config.get([:mrf_user_allowlist], [])
  80       |> Enum.into(%{}, fn {k, v} -> {k, length(v)} end)
  81
  82     federation_response =
  83       if Config.get([:instance, :mrf_transparency]) do
  84         %{
  85           mrf_policies: mrf_policies,
  86           mrf_simple: mrf_simple,
  87           mrf_keyword: mrf_keyword,
  88           mrf_user_allowlist: mrf_user_allowlist,
  89           quarantined_instances: quarantined
  90         }
  91       else
  92         %{}
  93       end
  94
  95     features =
  96       [
  97         "pleroma_api",
  98         "mastodon_api",
  99         "mastodon_api_streaming",
 100         "polls",
 101         if Config.get([:media_proxy, :enabled]) do
 102           "media_proxy"
 103         end,
 104         if Config.get([:gopher, :enabled]) do
 105           "gopher"
 106         end,
 107         if Config.get([:chat, :enabled]) do
 108           "chat"
 109         end,
 110         if Config.get([:suggestions, :enabled]) do
 111           "suggestions"
 112         end,
 113         if Config.get([:instance, :allow_relay]) do
 114           "relay"
 115         end,
 116         if Config.get([:instance, :safe_dm_mentions]) do
 117           "safe_dm_mentions"
 118         end
 119       ]
 120       |> Enum.filter(& &1)
 121
 122     %{
 123       version: "2.0",
 124       software: %{
 125         name: Pleroma.Application.name() |> String.downcase(),
 126         version: Pleroma.Application.version()
 127       },
 128       protocols: Publisher.gather_nodeinfo_protocol_names(),
 129       services: %{
 130         inbound: [],
 131         outbound: []
 132       },
 133       openRegistrations: Config.get([:instance, :registrations_open]),
 134       usage: %{
 135         users: %{
 136           total: stats.user_count || 0
 137         },
 138         localPosts: stats.status_count || 0
 139       },
 140       metadata: %{
 141         nodeName: Config.get([:instance, :name]),
 142         nodeDescription: Config.get([:instance, :description]),
 143         private: !Config.get([:instance, :public], true),
 144         suggestions: %{
 145           enabled: Config.get([:suggestions, :enabled], false),
 146           thirdPartyEngine: Config.get([:suggestions, :third_party_engine], ""),
 147           timeout: Config.get([:suggestions, :timeout], 5000),
 148           limit: Config.get([:suggestions, :limit], 23),
 149           web: Config.get([:suggestions, :web], "")
 150         },
 151         staffAccounts: staff_accounts,
 152         federation: federation_response,
 153         pollLimits: Config.get([:instance, :poll_limits]),
 154         postFormats: Config.get([:instance, :allowed_post_formats]),
 155         uploadLimits: %{
 156           general: Config.get([:instance, :upload_limit]),
 157           avatar: Config.get([:instance, :avatar_upload_limit]),
 158           banner: Config.get([:instance, :banner_upload_limit]),
 159           background: Config.get([:instance, :background_upload_limit])
 160         },
 161         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 162         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 163         features: features,
 164         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames])
 165       }
 166     }
 167   end
 168
 169   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
 170   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
 171   def nodeinfo(conn, %{"version" => "2.0"}) do
 172     conn
 173     |> put_resp_header(
 174       "content-type",
 175       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 176     )
 177     |> json(raw_nodeinfo())
 178   end
 179
 180   def nodeinfo(conn, %{"version" => "2.1"}) do
 181     raw_response = raw_nodeinfo()
 182
 183     updated_software =
 184       raw_response
 185       |> Map.get(:software)
 186       |> Map.put(:repository, Pleroma.Application.repository())
 187
 188     response =
 189       raw_response
 190       |> Map.put(:software, updated_software)
 191       |> Map.put(:version, "2.1")
 192
 193     conn
 194     |> put_resp_header(
 195       "content-type",
 196       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 197     )
 198     |> json(response)
 199   end
 200
 201   def nodeinfo(conn, _) do
 202     conn
 203     |> put_status(404)
 204     |> json(%{error: "Nodeinfo schema version not handled"})
 205   end
 206 end