git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   2   use Pleroma.Web, :controller
   3
   4   alias Pleroma.Stats
   5   alias Pleroma.Web
   6   alias Pleroma.{User, Repo}
   7   alias Pleroma.Web.ActivityPub.MRF
   8
   9   plug(Pleroma.Web.FederatingPlug)
  10
  11   def schemas(conn, _params) do
  12     response = %{
  13       links: [
  14         %{
  15           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  16           href: Web.base_url() <> "/nodeinfo/2.0.json"
  17         }
  18       ]
  19     }
  20
  21     json(conn, response)
  22   end
  23
  24   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
  25   def nodeinfo(conn, %{"version" => "2.0"}) do
  26     instance = Application.get_env(:pleroma, :instance)
  27     media_proxy = Application.get_env(:pleroma, :media_proxy)
  28     suggestions = Application.get_env(:pleroma, :suggestions)
  29     chat = Application.get_env(:pleroma, :chat)
  30     gopher = Application.get_env(:pleroma, :gopher)
  31     stats = Stats.get_stats()
  32
  33     mrf_simple =
  34       Application.get_env(:pleroma, :mrf_simple)
  35       |> Enum.into(%{})
  36
  37     mrf_policies =
  38       MRF.get_policies()
  39       |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)
  40
  41     quarantined = Keyword.get(instance, :quarantined_instances)
  42
  43     quarantined =
  44       if is_list(quarantined) do
  45         quarantined
  46       else
  47         []
  48       end
  49
  50     staff_accounts =
  51       User.moderator_user_query()
  52       |> Repo.all()
  53       |> Enum.map(fn u -> u.ap_id end)
  54
  55     mrf_transparency = Keyword.get(instance, :mrf_transparency)
  56
  57     federation_response =
  58       if mrf_transparency do
  59         %{
  60           mrf_policies: mrf_policies,
  61           mrf_simple: mrf_simple,
  62           quarantined_instances: quarantined
  63         }
  64       else
  65         %{}
  66       end
  67
  68     features = [
  69       "pleroma_api",
  70       "mastodon_api",
  71       "mastodon_api_streaming",
  72       if Keyword.get(media_proxy, :enabled) do
  73         "media_proxy"
  74       end,
  75       if Keyword.get(gopher, :enabled) do
  76         "gopher"
  77       end,
  78       if Keyword.get(chat, :enabled) do
  79         "chat"
  80       end,
  81       if Keyword.get(suggestions, :enabled) do
  82         "suggestions"
  83       end
  84     ]
  85
  86     response = %{
  87       version: "2.0",
  88       software: %{
  89         name: "pleroma",
  90         version: Keyword.get(instance, :version)
  91       },
  92       protocols: ["ostatus", "activitypub"],
  93       services: %{
  94         inbound: [],
  95         outbound: []
  96       },
  97       openRegistrations: Keyword.get(instance, :registrations_open),
  98       usage: %{
  99         users: %{
 100           total: stats.user_count || 0
 101         },
 102         localPosts: stats.status_count || 0
 103       },
 104       metadata: %{
 105         nodeName: Keyword.get(instance, :name),
 106         nodeDescription: Keyword.get(instance, :description),
 107         private: !Keyword.get(instance, :public, true),
 108         suggestions: %{
 109           enabled: Keyword.get(suggestions, :enabled, false),
 110           thirdPartyEngine: Keyword.get(suggestions, :third_party_engine, ""),
 111           timeout: Keyword.get(suggestions, :timeout, 5000),
 112           limit: Keyword.get(suggestions, :limit, 23),
 113           web: Keyword.get(suggestions, :web, "")
 114         },
 115         staffAccounts: staff_accounts,
 116         federation: federation_response,
 117         postFormats: Keyword.get(instance, :allowed_post_formats),
 118         uploadLimits: %{
 119           general: Keyword.get(instance, :upload_limit),
 120           avatar: Keyword.get(instance, :avatar_upload_limit),
 121           banner: Keyword.get(instance, :banner_upload_limit),
 122           background: Keyword.get(instance, :background_upload_limit)
 123         },
 124         features: features
 125       }
 126     }
 127
 128     conn
 129     |> put_resp_header(
 130       "content-type",
 131       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 132     )
 133     |> json(response)
 134   end
 135
 136   def nodeinfo(conn, _) do
 137     conn
 138     |> put_status(404)
 139     |> json(%{error: "Nodeinfo schema version not handled"})
 140   end
 141 end