git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.ActivityPub.MRF
  13   alias Pleroma.Web.Federator.Publisher
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36
  37     mrf_simple =
  38       Config.get(:mrf_simple)
  39       |> Enum.into(%{})
  40
  41     # This horror is needed to convert regex sigils to strings
  42     mrf_keyword =
  43       Config.get(:mrf_keyword, [])
  44       |> Enum.map(fn {key, value} ->
  45         {key,
  46          Enum.map(value, fn
  47            {pattern, replacement} ->
  48              %{
  49                "pattern" =>
  50                  if not is_binary(pattern) do
  51                    inspect(pattern)
  52                  else
  53                    pattern
  54                  end,
  55                "replacement" => replacement
  56              }
  57
  58            pattern ->
  59              if not is_binary(pattern) do
  60                inspect(pattern)
  61              else
  62                pattern
  63              end
  64          end)}
  65       end)
  66       |> Enum.into(%{})
  67
  68     mrf_policies =
  69       MRF.get_policies()
  70       |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)
  71
  72     quarantined = Config.get([:instance, :quarantined_instances], [])
  73
  74     staff_accounts =
  75       User.all_superusers()
  76       |> Enum.map(fn u -> u.ap_id end)
  77
  78     mrf_user_allowlist =
  79       Config.get([:mrf_user_allowlist], [])
  80       |> Enum.into(%{}, fn {k, v} -> {k, length(v)} end)
  81
  82     federation_response =
  83       if Config.get([:instance, :mrf_transparency]) do
  84         %{
  85           mrf_policies: mrf_policies,
  86           mrf_simple: mrf_simple,
  87           mrf_keyword: mrf_keyword,
  88           mrf_user_allowlist: mrf_user_allowlist,
  89           quarantined_instances: quarantined
  90         }
  91       else
  92         %{}
  93       end
  94
  95     features =
  96       [
  97         "pleroma_api",
  98         "mastodon_api",
  99         "mastodon_api_streaming",
 100         if Config.get([:media_proxy, :enabled]) do
 101           "media_proxy"
 102         end,
 103         if Config.get([:gopher, :enabled]) do
 104           "gopher"
 105         end,
 106         if Config.get([:chat, :enabled]) do
 107           "chat"
 108         end,
 109         if Config.get([:suggestions, :enabled]) do
 110           "suggestions"
 111         end,
 112         if Config.get([:instance, :allow_relay]) do
 113           "relay"
 114         end,
 115         if Config.get([:instance, :safe_dm_mentions]) do
 116           "safe_dm_mentions"
 117         end
 118       ]
 119       |> Enum.filter(& &1)
 120
 121     %{
 122       version: "2.0",
 123       software: %{
 124         name: Pleroma.Application.name() |> String.downcase(),
 125         version: Pleroma.Application.version()
 126       },
 127       protocols: Publisher.gather_nodeinfo_protocol_names(),
 128       services: %{
 129         inbound: [],
 130         outbound: []
 131       },
 132       openRegistrations: Config.get([:instance, :registrations_open]),
 133       usage: %{
 134         users: %{
 135           total: stats.user_count || 0
 136         },
 137         localPosts: stats.status_count || 0
 138       },
 139       metadata: %{
 140         nodeName: Config.get([:instance, :name]),
 141         nodeDescription: Config.get([:instance, :description]),
 142         private: !Config.get([:instance, :public], true),
 143         suggestions: %{
 144           enabled: Config.get([:suggestions, :enabled], false),
 145           thirdPartyEngine: Config.get([:suggestions, :third_party_engine], ""),
 146           timeout: Config.get([:suggestions, :timeout], 5000),
 147           limit: Config.get([:suggestions, :limit], 23),
 148           web: Config.get([:suggestions, :web], "")
 149         },
 150         staffAccounts: staff_accounts,
 151         federation: federation_response,
 152         postFormats: Config.get([:instance, :allowed_post_formats]),
 153         uploadLimits: %{
 154           general: Config.get([:instance, :upload_limit]),
 155           avatar: Config.get([:instance, :avatar_upload_limit]),
 156           banner: Config.get([:instance, :banner_upload_limit]),
 157           background: Config.get([:instance, :background_upload_limit])
 158         },
 159         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 160         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 161         features: features,
 162         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames])
 163       }
 164     }
 165   end
 166
 167   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
 168   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
 169   def nodeinfo(conn, %{"version" => "2.0"}) do
 170     conn
 171     |> put_resp_header(
 172       "content-type",
 173       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 174     )
 175     |> json(raw_nodeinfo())
 176   end
 177
 178   def nodeinfo(conn, %{"version" => "2.1"}) do
 179     raw_response = raw_nodeinfo()
 180
 181     updated_software =
 182       raw_response
 183       |> Map.get(:software)
 184       |> Map.put(:repository, Pleroma.Application.repository())
 185
 186     response =
 187       raw_response
 188       |> Map.put(:software, updated_software)
 189       |> Map.put(:version, "2.1")
 190
 191     conn
 192     |> put_resp_header(
 193       "content-type",
 194       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 195     )
 196     |> json(response)
 197   end
 198
 199   def nodeinfo(conn, _) do
 200     conn
 201     |> put_status(404)
 202     |> json(%{error: "Nodeinfo schema version not handled"})
 203   end
 204 end