git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.ActivityPub.MRF
  13   alias Pleroma.Web.Federator.Publisher
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36     exclusions = Config.get([:instance, :mrf_transparency_exclusions], [])
  37
  38     quarantined =
  39       Config.get([:instance, :quarantined_instances], [])
  40       |> Enum.filter(fn x -> !Enum.member?(exclusions, x) end)
  41
  42     staff_accounts =
  43       User.all_superusers()
  44       |> Enum.map(fn u -> u.ap_id end)
  45
  46     federation_response =
  47       if Config.get([:instance, :mrf_transparency]) do
  48         {:ok, data} = MRF.describe()
  49
  50         data
  51         |> Map.merge(%{quarantined_instances: quarantined})
  52         |> Map.put(:enabled, Config.get([:instance, :federating]))
  53       else
  54         %{}
  55       end
  56
  57     features =
  58       [
  59         "pleroma_api",
  60         "mastodon_api",
  61         "mastodon_api_streaming",
  62         "polls",
  63         "pleroma_explicit_addressing",
  64         "shareable_emoji_packs",
  65         "multifetch",
  66         if Config.get([:media_proxy, :enabled]) do
  67           "media_proxy"
  68         end,
  69         if Config.get([:gopher, :enabled]) do
  70           "gopher"
  71         end,
  72         if Config.get([:chat, :enabled]) do
  73           "chat"
  74         end,
  75         if Config.get([:suggestions, :enabled]) do
  76           "suggestions"
  77         end,
  78         if Config.get([:instance, :allow_relay]) do
  79           "relay"
  80         end,
  81         if Config.get([:instance, :safe_dm_mentions]) do
  82           "safe_dm_mentions"
  83         end
  84       ]
  85       |> Enum.filter(& &1)
  86
  87     %{
  88       version: "2.0",
  89       software: %{
  90         name: Pleroma.Application.name() |> String.downcase(),
  91         version: Pleroma.Application.version()
  92       },
  93       protocols: Publisher.gather_nodeinfo_protocol_names(),
  94       services: %{
  95         inbound: [],
  96         outbound: []
  97       },
  98       openRegistrations: Config.get([:instance, :registrations_open]),
  99       usage: %{
 100         users: %{
 101           total: stats.user_count || 0
 102         },
 103         localPosts: stats.status_count || 0
 104       },
 105       metadata: %{
 106         nodeName: Config.get([:instance, :name]),
 107         nodeDescription: Config.get([:instance, :description]),
 108         private: !Config.get([:instance, :public], true),
 109         suggestions: %{
 110           enabled: Config.get([:suggestions, :enabled], false),
 111           thirdPartyEngine: Config.get([:suggestions, :third_party_engine], ""),
 112           timeout: Config.get([:suggestions, :timeout], 5000),
 113           limit: Config.get([:suggestions, :limit], 23),
 114           web: Config.get([:suggestions, :web], "")
 115         },
 116         staffAccounts: staff_accounts,
 117         federation: federation_response,
 118         pollLimits: Config.get([:instance, :poll_limits]),
 119         postFormats: Config.get([:instance, :allowed_post_formats]),
 120         uploadLimits: %{
 121           general: Config.get([:instance, :upload_limit]),
 122           avatar: Config.get([:instance, :avatar_upload_limit]),
 123           banner: Config.get([:instance, :banner_upload_limit]),
 124           background: Config.get([:instance, :background_upload_limit])
 125         },
 126         fieldsLimits: %{
 127           maxFields: Config.get([:instance, :max_account_fields]),
 128           maxRemoteFields: Config.get([:instance, :max_remote_account_fields]),
 129           nameLength: Config.get([:instance, :account_field_name_length]),
 130           valueLength: Config.get([:instance, :account_field_value_length])
 131         },
 132         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 133         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 134         mailerEnabled: Config.get([Pleroma.Emails.Mailer, :enabled], false),
 135         features: features,
 136         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames]),
 137         skipThreadContainment: Config.get([:instance, :skip_thread_containment], false)
 138       }
 139     }
 140   end
 141
 142   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
 143   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
 144   def nodeinfo(conn, %{"version" => "2.0"}) do
 145     conn
 146     |> put_resp_header(
 147       "content-type",
 148       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 149     )
 150     |> json(raw_nodeinfo())
 151   end
 152
 153   def nodeinfo(conn, %{"version" => "2.1"}) do
 154     raw_response = raw_nodeinfo()
 155
 156     updated_software =
 157       raw_response
 158       |> Map.get(:software)
 159       |> Map.put(:repository, Pleroma.Application.repository())
 160
 161     response =
 162       raw_response
 163       |> Map.put(:software, updated_software)
 164       |> Map.put(:version, "2.1")
 165
 166     conn
 167     |> put_resp_header(
 168       "content-type",
 169       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 170     )
 171     |> json(response)
 172   end
 173
 174   def nodeinfo(conn, _) do
 175     render_error(conn, :not_found, "Nodeinfo schema version not handled")
 176   end
 177 end