git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.ActivityPub.MRF
  13   alias Pleroma.Web.Federator.Publisher
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36     exclusions = Config.get([:instance, :mrf_transparency_exclusions], [])
  37
  38     quarantined =
  39       Config.get([:instance, :quarantined_instances], [])
  40       |> Enum.filter(fn x -> !Enum.member?(exclusions, x) end)
  41
  42     staff_accounts =
  43       User.all_superusers()
  44       |> Enum.map(fn u -> u.ap_id end)
  45       |> Enum.filter(fn u -> not Enum.member?(Config.get([:instance, :staff_transparency]), u) end)
  46
  47     federation_response =
  48       if Config.get([:instance, :mrf_transparency]) do
  49         {:ok, data} = MRF.describe()
  50
  51         data
  52         |> Map.merge(%{quarantined_instances: quarantined})
  53         |> Map.put(:enabled, Config.get([:instance, :federating]))
  54       else
  55         %{}
  56       end
  57
  58     features =
  59       [
  60         "pleroma_api",
  61         "mastodon_api",
  62         "mastodon_api_streaming",
  63         "polls",
  64         "pleroma_explicit_addressing",
  65         "shareable_emoji_packs",
  66         "multifetch",
  67         if Config.get([:media_proxy, :enabled]) do
  68           "media_proxy"
  69         end,
  70         if Config.get([:gopher, :enabled]) do
  71           "gopher"
  72         end,
  73         if Config.get([:chat, :enabled]) do
  74           "chat"
  75         end,
  76         if Config.get([:suggestions, :enabled]) do
  77           "suggestions"
  78         end,
  79         if Config.get([:instance, :allow_relay]) do
  80           "relay"
  81         end,
  82         if Config.get([:instance, :safe_dm_mentions]) do
  83           "safe_dm_mentions"
  84         end
  85       ]
  86       |> Enum.filter(& &1)
  87
  88     %{
  89       version: "2.0",
  90       software: %{
  91         name: Pleroma.Application.name() |> String.downcase(),
  92         version: Pleroma.Application.version()
  93       },
  94       protocols: Publisher.gather_nodeinfo_protocol_names(),
  95       services: %{
  96         inbound: [],
  97         outbound: []
  98       },
  99       openRegistrations: Config.get([:instance, :registrations_open]),
 100       usage: %{
 101         users: %{
 102           total: stats.user_count || 0
 103         },
 104         localPosts: stats.status_count || 0
 105       },
 106       metadata: %{
 107         nodeName: Config.get([:instance, :name]),
 108         nodeDescription: Config.get([:instance, :description]),
 109         private: !Config.get([:instance, :public], true),
 110         suggestions: %{
 111           enabled: Config.get([:suggestions, :enabled], false),
 112           thirdPartyEngine: Config.get([:suggestions, :third_party_engine], ""),
 113           timeout: Config.get([:suggestions, :timeout], 5000),
 114           limit: Config.get([:suggestions, :limit], 23),
 115           web: Config.get([:suggestions, :web], "")
 116         },
 117         staffAccounts: staff_accounts,
 118         federation: federation_response,
 119         pollLimits: Config.get([:instance, :poll_limits]),
 120         postFormats: Config.get([:instance, :allowed_post_formats]),
 121         uploadLimits: %{
 122           general: Config.get([:instance, :upload_limit]),
 123           avatar: Config.get([:instance, :avatar_upload_limit]),
 124           banner: Config.get([:instance, :banner_upload_limit]),
 125           background: Config.get([:instance, :background_upload_limit])
 126         },
 127         fieldsLimits: %{
 128           maxFields: Config.get([:instance, :max_account_fields]),
 129           maxRemoteFields: Config.get([:instance, :max_remote_account_fields]),
 130           nameLength: Config.get([:instance, :account_field_name_length]),
 131           valueLength: Config.get([:instance, :account_field_value_length])
 132         },
 133         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 134         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 135         mailerEnabled: Config.get([Pleroma.Emails.Mailer, :enabled], false),
 136         features: features,
 137         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames]),
 138         skipThreadContainment: Config.get([:instance, :skip_thread_containment], false)
 139       }
 140     }
 141   end
 142
 143   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
 144   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
 145   def nodeinfo(conn, %{"version" => "2.0"}) do
 146     conn
 147     |> put_resp_header(
 148       "content-type",
 149       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 150     )
 151     |> json(raw_nodeinfo())
 152   end
 153
 154   def nodeinfo(conn, %{"version" => "2.1"}) do
 155     raw_response = raw_nodeinfo()
 156
 157     updated_software =
 158       raw_response
 159       |> Map.get(:software)
 160       |> Map.put(:repository, Pleroma.Application.repository())
 161
 162     response =
 163       raw_response
 164       |> Map.put(:software, updated_software)
 165       |> Map.put(:version, "2.1")
 166
 167     conn
 168     |> put_resp_header(
 169       "content-type",
 170       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 171     )
 172     |> json(response)
 173   end
 174
 175   def nodeinfo(conn, _) do
 176     render_error(conn, :not_found, "Nodeinfo schema version not handled")
 177   end
 178 end