git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.NodeinfoController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Stats
  10   alias Pleroma.User
  11   alias Pleroma.Web
  12   alias Pleroma.Web.ActivityPub.MRF
  13   alias Pleroma.Web.Federator.Publisher
  14
  15   def schemas(conn, _params) do
  16     response = %{
  17       links: [
  18         %{
  19           rel: "http://nodeinfo.diaspora.software/ns/schema/2.0",
  20           href: Web.base_url() <> "/nodeinfo/2.0.json"
  21         },
  22         %{
  23           rel: "http://nodeinfo.diaspora.software/ns/schema/2.1",
  24           href: Web.base_url() <> "/nodeinfo/2.1.json"
  25         }
  26       ]
  27     }
  28
  29     json(conn, response)
  30   end
  31
  32   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  33   # under software.
  34   def raw_nodeinfo do
  35     stats = Stats.get_stats()
  36     exclusions = Config.get([:instance, :mrf_transparency_exclusions], [])
  37
  38     quarantined =
  39       Config.get([:instance, :quarantined_instances], [])
  40       |> Enum.filter(fn x -> !Enum.member?(exclusions, x) end)
  41
  42     staff_accounts =
  43       User.all_superusers()
  44       |> Enum.map(fn u -> u.ap_id end)
  45       |> Enum.filter(fn u -> not Enum.member?(Config.get([:instance, :staff_transparency]), u) end)
  46
  47     federation_response =
  48       if Config.get([:instance, :mrf_transparency]) do
  49         {:ok, data} = MRF.describe()
  50
  51         data
  52         |> Map.merge(%{quarantined_instances: quarantined})
  53       else
  54         %{}
  55       end
  56       |> Map.put(:enabled, Config.get([:instance, :federating]))
  57
  58     features =
  59       [
  60         "pleroma_api",
  61         "mastodon_api",
  62         "mastodon_api_streaming",
  63         "polls",
  64         "pleroma_explicit_addressing",
  65         "shareable_emoji_packs",
  66         "multifetch",
  67         if Config.get([:media_proxy, :enabled]) do
  68           "media_proxy"
  69         end,
  70         if Config.get([:gopher, :enabled]) do
  71           "gopher"
  72         end,
  73         if Config.get([:chat, :enabled]) do
  74           "chat"
  75         end,
  76         if Config.get([:instance, :allow_relay]) do
  77           "relay"
  78         end,
  79         if Config.get([:instance, :safe_dm_mentions]) do
  80           "safe_dm_mentions"
  81         end
  82       ]
  83       |> Enum.filter(& &1)
  84
  85     %{
  86       version: "2.0",
  87       software: %{
  88         name: Pleroma.Application.name() |> String.downcase(),
  89         version: Pleroma.Application.version()
  90       },
  91       protocols: Publisher.gather_nodeinfo_protocol_names(),
  92       services: %{
  93         inbound: [],
  94         outbound: []
  95       },
  96       openRegistrations: Config.get([:instance, :registrations_open]),
  97       usage: %{
  98         users: %{
  99           total: stats.user_count || 0
 100         },
 101         localPosts: stats.status_count || 0
 102       },
 103       metadata: %{
 104         nodeName: Config.get([:instance, :name]),
 105         nodeDescription: Config.get([:instance, :description]),
 106         private: !Config.get([:instance, :public], true),
 107         suggestions: %{
 108           enabled: false
 109         },
 110         staffAccounts: staff_accounts,
 111         federation: federation_response,
 112         pollLimits: Config.get([:instance, :poll_limits]),
 113         postFormats: Config.get([:instance, :allowed_post_formats]),
 114         uploadLimits: %{
 115           general: Config.get([:instance, :upload_limit]),
 116           avatar: Config.get([:instance, :avatar_upload_limit]),
 117           banner: Config.get([:instance, :banner_upload_limit]),
 118           background: Config.get([:instance, :background_upload_limit])
 119         },
 120         fieldsLimits: %{
 121           maxFields: Config.get([:instance, :max_account_fields]),
 122           maxRemoteFields: Config.get([:instance, :max_remote_account_fields]),
 123           nameLength: Config.get([:instance, :account_field_name_length]),
 124           valueLength: Config.get([:instance, :account_field_value_length])
 125         },
 126         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 127         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 128         mailerEnabled: Config.get([Pleroma.Emails.Mailer, :enabled], false),
 129         features: features,
 130         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames]),
 131         skipThreadContainment: Config.get([:instance, :skip_thread_containment], false)
 132       }
 133     }
 134   end
 135
 136   # Schema definition: https://github.com/jhass/nodeinfo/blob/master/schemas/2.0/schema.json
 137   # and https://github.com/jhass/nodeinfo/blob/master/schemas/2.1/schema.json
 138   def nodeinfo(conn, %{"version" => "2.0"}) do
 139     conn
 140     |> put_resp_header(
 141       "content-type",
 142       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.0#; charset=utf-8"
 143     )
 144     |> json(raw_nodeinfo())
 145   end
 146
 147   def nodeinfo(conn, %{"version" => "2.1"}) do
 148     raw_response = raw_nodeinfo()
 149
 150     updated_software =
 151       raw_response
 152       |> Map.get(:software)
 153       |> Map.put(:repository, Pleroma.Application.repository())
 154
 155     response =
 156       raw_response
 157       |> Map.put(:software, updated_software)
 158       |> Map.put(:version, "2.1")
 159
 160     conn
 161     |> put_resp_header(
 162       "content-type",
 163       "application/json; profile=http://nodeinfo.diaspora.software/ns/schema/2.1#; charset=utf-8"
 164     )
 165     |> json(response)
 166   end
 167
 168   def nodeinfo(conn, _) do
 169     render_error(conn, :not_found, "Nodeinfo schema version not handled")
 170   end
 171 end