git.squeep.com Git - akkoma/blob - lib/pleroma/web/nodeinfo/nodeinfo.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Nodeinfo.Nodeinfo do
   6   alias Pleroma.Config
   7   alias Pleroma.Stats
   8   alias Pleroma.User
   9   alias Pleroma.Web.ActivityPub.MRF
  10   alias Pleroma.Web.Federator.Publisher
  11
  12   # returns a nodeinfo 2.0 map, since 2.1 just adds a repository field
  13   # under software.
  14   def get_nodeinfo("2.0") do
  15     stats = Stats.get_stats()
  16
  17     quarantined = Config.get([:instance, :quarantined_instances], [])
  18
  19     staff_accounts =
  20       User.all_superusers()
  21       |> Enum.map(fn u -> u.ap_id end)
  22
  23     federation_response =
  24       if Config.get([:instance, :mrf_transparency]) do
  25         {:ok, data} = MRF.describe()
  26
  27         data
  28         |> Map.merge(%{quarantined_instances: quarantined})
  29       else
  30         %{}
  31       end
  32       |> Map.put(:enabled, Config.get([:instance, :federating]))
  33
  34     features =
  35       [
  36         "pleroma_api",
  37         "mastodon_api",
  38         "mastodon_api_streaming",
  39         "polls",
  40         "pleroma_explicit_addressing",
  41         "shareable_emoji_packs",
  42         "multifetch",
  43         "pleroma:api/v1/notifications:include_types_filter",
  44         if Config.get([:media_proxy, :enabled]) do
  45           "media_proxy"
  46         end,
  47         if Config.get([:gopher, :enabled]) do
  48           "gopher"
  49         end,
  50         if Config.get([:chat, :enabled]) do
  51           "chat"
  52         end,
  53         if Config.get([:instance, :allow_relay]) do
  54           "relay"
  55         end,
  56         if Config.get([:instance, :safe_dm_mentions]) do
  57           "safe_dm_mentions"
  58         end,
  59         "pleroma_emoji_reactions"
  60       ]
  61       |> Enum.filter(& &1)
  62
  63     %{
  64       version: "2.0",
  65       software: %{
  66         name: Pleroma.Application.name() |> String.downcase(),
  67         version: Pleroma.Application.version()
  68       },
  69       protocols: Publisher.gather_nodeinfo_protocol_names(),
  70       services: %{
  71         inbound: [],
  72         outbound: []
  73       },
  74       openRegistrations: Config.get([:instance, :registrations_open]),
  75       usage: %{
  76         users: %{
  77           total: Map.get(stats, :user_count, 0)
  78         },
  79         localPosts: Map.get(stats, :status_count, 0)
  80       },
  81       metadata: %{
  82         nodeName: Config.get([:instance, :name]),
  83         nodeDescription: Config.get([:instance, :description]),
  84         private: !Config.get([:instance, :public], true),
  85         suggestions: %{
  86           enabled: false
  87         },
  88         staffAccounts: staff_accounts,
  89         federation: federation_response,
  90         pollLimits: Config.get([:instance, :poll_limits]),
  91         postFormats: Config.get([:instance, :allowed_post_formats]),
  92         uploadLimits: %{
  93           general: Config.get([:instance, :upload_limit]),
  94           avatar: Config.get([:instance, :avatar_upload_limit]),
  95           banner: Config.get([:instance, :banner_upload_limit]),
  96           background: Config.get([:instance, :background_upload_limit])
  97         },
  98         fieldsLimits: %{
  99           maxFields: Config.get([:instance, :max_account_fields]),
 100           maxRemoteFields: Config.get([:instance, :max_remote_account_fields]),
 101           nameLength: Config.get([:instance, :account_field_name_length]),
 102           valueLength: Config.get([:instance, :account_field_value_length])
 103         },
 104         accountActivationRequired: Config.get([:instance, :account_activation_required], false),
 105         invitesEnabled: Config.get([:instance, :invites_enabled], false),
 106         mailerEnabled: Config.get([Pleroma.Emails.Mailer, :enabled], false),
 107         features: features,
 108         restrictedNicknames: Config.get([Pleroma.User, :restricted_nicknames]),
 109         skipThreadContainment: Config.get([:instance, :skip_thread_containment], false)
 110       }
 111     }
 112   end
 113
 114   def get_nodeinfo("2.1") do
 115     raw_response = get_nodeinfo("2.0")
 116
 117     updated_software =
 118       raw_response
 119       |> Map.get(:software)
 120       |> Map.put(:repository, Pleroma.Application.repository())
 121
 122     raw_response
 123     |> Map.put(:software, updated_software)
 124     |> Map.put(:version, "2.1")
 125   end
 126
 127   def get_nodeinfo(_version) do
 128     {:error, :missing}
 129   end
 130 end