git.squeep.com Git - akkoma/blob - lib/pleroma/web/metadata/opengraph.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.Metadata.Providers.OpenGraph do
   6   alias Pleroma.User
   7   alias Pleroma.Web.Metadata
   8   alias Pleroma.Web.Metadata.Providers.Provider
   9   alias Pleroma.Web.Metadata.Utils
  10
  11   @behaviour Provider
  12
  13   @impl Provider
  14   def build_tags(%{
  15         object: object,
  16         url: url,
  17         user: user
  18       }) do
  19     attachments = build_attachments(object)
  20     scrubbed_content = Utils.scrub_html_and_truncate(object)
  21     # Zero width space
  22     content =
  23       if scrubbed_content != "" and scrubbed_content != "\u200B" do
  24         ": “" <> scrubbed_content <> "”"
  25       else
  26         ""
  27       end
  28
  29     # Most previews only show og:title which is inconvenient. Instagram
  30     # hacks this by putting the description in the title and making the
  31     # description longer prefixed by how many likes and shares the post
  32     # has. Here we use the descriptive nickname in the title, and expand
  33     # the full account & nickname in the description. We also use the cute^Wevil
  34     # smart quotes around the status text like Instagram, too.
  35     [
  36       {:meta,
  37        [
  38          property: "og:title",
  39          content: "#{user.name}" <> content
  40        ], []},
  41       {:meta, [property: "og:url", content: url], []},
  42       {:meta,
  43        [
  44          property: "og:description",
  45          content: "#{Utils.user_name_string(user)}" <> content
  46        ], []},
  47       {:meta, [property: "og:type", content: "website"], []}
  48     ] ++
  49       if attachments == [] or Metadata.activity_nsfw?(object) do
  50         [
  51           {:meta, [property: "og:image", content: Utils.attachment_url(User.avatar_url(user))],
  52            []},
  53           {:meta, [property: "og:image:width", content: 150], []},
  54           {:meta, [property: "og:image:height", content: 150], []}
  55         ]
  56       else
  57         attachments
  58       end
  59   end
  60
  61   @impl Provider
  62   def build_tags(%{user: user}) do
  63     with truncated_bio = Utils.scrub_html_and_truncate(user.bio || "") do
  64       [
  65         {:meta,
  66          [
  67            property: "og:title",
  68            content: Utils.user_name_string(user)
  69          ], []},
  70         {:meta, [property: "og:url", content: User.profile_url(user)], []},
  71         {:meta, [property: "og:description", content: truncated_bio], []},
  72         {:meta, [property: "og:type", content: "website"], []},
  73         {:meta, [property: "og:image", content: Utils.attachment_url(User.avatar_url(user))], []},
  74         {:meta, [property: "og:image:width", content: 150], []},
  75         {:meta, [property: "og:image:height", content: 150], []}
  76       ]
  77     end
  78   end
  79
  80   defp build_attachments(%{data: %{"attachment" => attachments}}) do
  81     Enum.reduce(attachments, [], fn attachment, acc ->
  82       rendered_tags =
  83         Enum.reduce(attachment["url"], [], fn url, acc ->
  84           media_type =
  85             Enum.find(["image", "audio", "video"], fn media_type ->
  86               String.starts_with?(url["mediaType"], media_type)
  87             end)
  88
  89           # TODO: Add additional properties to objects when we have the data available.
  90           # Also, Whatsapp only wants JPEG or PNGs. It seems that if we add a second og:image
  91           # object when a Video or GIF is attached it will display that in the Whatsapp Rich Preview.
  92           case media_type do
  93             "audio" ->
  94               [
  95                 {:meta,
  96                  [property: "og:" <> media_type, content: Utils.attachment_url(url["href"])], []}
  97                 | acc
  98               ]
  99
 100             "image" ->
 101               [
 102                 {:meta, [property: "og:" <> media_type, content: Utils.attachment_url(url["href"])],
 103                  []},
 104                 {:meta, [property: "og:image:width", content: 150], []},
 105                 {:meta, [property: "og:image:height", content: 150], []}
 106                 | acc
 107               ]
 108
 109             "video" ->
 110               [
 111                 {:meta,
 112                  [property: "og:" <> media_type, content: Utils.attachment_url(url["href"])], []}
 113                 | acc
 114               ]
 115
 116             _ ->
 117               acc
 118           end
 119         end)
 120
 121       acc ++ rendered_tags
 122     end)
 123   end
 124 end