git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   alias Pleroma.Config
   7   alias Pleroma.Helpers.UriHelper
   8   alias Pleroma.Upload
   9   alias Pleroma.Web
  10   alias Pleroma.Web.MediaProxy.Invalidation
  11
  12   @base64_opts [padding: false]
  13   @cache_table :banned_urls_cache
  14
  15   @cachex Pleroma.Config.get([:cachex, :provider], Cachex)
  16
  17   def cache_table, do: @cache_table
  18
  19   @spec in_banned_urls(String.t()) :: boolean()
  20   def in_banned_urls(url), do: elem(@cachex.exists?(@cache_table, url(url)), 1)
  21
  22   def remove_from_banned_urls(urls) when is_list(urls) do
  23     @cachex.execute!(@cache_table, fn cache ->
  24       Enum.each(Invalidation.prepare_urls(urls), &@cachex.del(cache, &1))
  25     end)
  26   end
  27
  28   def remove_from_banned_urls(url) when is_binary(url) do
  29     @cachex.del(@cache_table, url(url))
  30   end
  31
  32   def put_in_banned_urls(urls) when is_list(urls) do
  33     @cachex.execute!(@cache_table, fn cache ->
  34       Enum.each(Invalidation.prepare_urls(urls), &@cachex.put(cache, &1, true))
  35     end)
  36   end
  37
  38   def put_in_banned_urls(url) when is_binary(url) do
  39     @cachex.put(@cache_table, url(url), true)
  40   end
  41
  42   def url(url) when is_nil(url) or url == "", do: nil
  43   def url("/" <> _ = url), do: url
  44
  45   def url(url) do
  46     if enabled?() and url_proxiable?(url) do
  47       encode_url(url)
  48     else
  49       url
  50     end
  51   end
  52
  53   @spec url_proxiable?(String.t()) :: boolean()
  54   def url_proxiable?(url) do
  55     not local?(url) and not whitelisted?(url)
  56   end
  57
  58   def preview_url(url, preview_params \\ []) do
  59     if preview_enabled?() do
  60       encode_preview_url(url, preview_params)
  61     else
  62       url(url)
  63     end
  64   end
  65
  66   def enabled?, do: Config.get([:media_proxy, :enabled], false)
  67
  68   # Note: media proxy must be enabled for media preview proxy in order to load all
  69   #   non-local non-whitelisted URLs through it and be sure that body size constraint is preserved.
  70   def preview_enabled?, do: enabled?() and !!Config.get([:media_preview_proxy, :enabled])
  71
  72   def local?(url), do: String.starts_with?(url, Pleroma.Web.base_url())
  73
  74   def whitelisted?(url) do
  75     %{host: domain} = URI.parse(url)
  76
  77     mediaproxy_whitelist_domains =
  78       [:media_proxy, :whitelist]
  79       |> Config.get()
  80       |> Enum.map(&maybe_get_domain_from_url/1)
  81
  82     whitelist_domains =
  83       if base_url = Config.get([Upload, :base_url]) do
  84         %{host: base_domain} = URI.parse(base_url)
  85         [base_domain | mediaproxy_whitelist_domains]
  86       else
  87         mediaproxy_whitelist_domains
  88       end
  89
  90     domain in whitelist_domains
  91   end
  92
  93   defp maybe_get_domain_from_url("http" <> _ = url) do
  94     URI.parse(url).host
  95   end
  96
  97   defp maybe_get_domain_from_url(domain), do: domain
  98
  99   defp base64_sig64(url) do
 100     base64 = Base.url_encode64(url, @base64_opts)
 101
 102     sig64 =
 103       base64
 104       |> signed_url()
 105       |> Base.url_encode64(@base64_opts)
 106
 107     {base64, sig64}
 108   end
 109
 110   def encode_url(url) do
 111     {base64, sig64} = base64_sig64(url)
 112
 113     build_url(sig64, base64, filename(url))
 114   end
 115
 116   def encode_preview_url(url, preview_params \\ []) do
 117     {base64, sig64} = base64_sig64(url)
 118
 119     build_preview_url(sig64, base64, filename(url), preview_params)
 120   end
 121
 122   def decode_url(sig, url) do
 123     with {:ok, sig} <- Base.url_decode64(sig, @base64_opts),
 124          signature when signature == sig <- signed_url(url) do
 125       {:ok, Base.url_decode64!(url, @base64_opts)}
 126     else
 127       _ -> {:error, :invalid_signature}
 128     end
 129   end
 130
 131   defp signed_url(url) do
 132     :crypto.hmac(:sha, Config.get([Web.Endpoint, :secret_key_base]), url)
 133   end
 134
 135   def filename(url_or_path) do
 136     if path = URI.parse(url_or_path).path, do: Path.basename(path)
 137   end
 138
 139   def base_url do
 140     Config.get([:media_proxy, :base_url], Web.base_url())
 141   end
 142
 143   defp proxy_url(path, sig_base64, url_base64, filename) do
 144     [
 145       base_url(),
 146       path,
 147       sig_base64,
 148       url_base64,
 149       filename
 150     ]
 151     |> Enum.filter(& &1)
 152     |> Path.join()
 153   end
 154
 155   def build_url(sig_base64, url_base64, filename \\ nil) do
 156     proxy_url("proxy", sig_base64, url_base64, filename)
 157   end
 158
 159   def build_preview_url(sig_base64, url_base64, filename \\ nil, preview_params \\ []) do
 160     uri = proxy_url("proxy/preview", sig_base64, url_base64, filename)
 161
 162     UriHelper.modify_uri_params(uri, preview_params)
 163   end
 164
 165   def verify_request_path_and_url(
 166         %Plug.Conn{params: %{"filename" => _}, request_path: request_path},
 167         url
 168       ) do
 169     verify_request_path_and_url(request_path, url)
 170   end
 171
 172   def verify_request_path_and_url(request_path, url) when is_binary(request_path) do
 173     filename = filename(url)
 174
 175     if filename && not basename_matches?(request_path, filename) do
 176       {:wrong_filename, filename}
 177     else
 178       :ok
 179     end
 180   end
 181
 182   def verify_request_path_and_url(_, _), do: :ok
 183
 184   defp basename_matches?(path, filename) do
 185     basename = Path.basename(path)
 186     basename == filename or URI.decode(basename) == filename or URI.encode(basename) == filename
 187   end
 188 end