git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Helpers.MediaHelper
  10   alias Pleroma.ReverseProxy
  11   alias Pleroma.Web.MediaProxy
  12
  13   def remote(conn, %{"sig" => sig64, "url" => url64}) do
  14     with {_, true} <- {:enabled, MediaProxy.enabled?()},
  15          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  16          {_, false} <- {:in_banned_urls, MediaProxy.in_banned_urls(url)},
  17          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  18       ReverseProxy.call(conn, url, media_proxy_opts())
  19     else
  20       {:enabled, false} ->
  21         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  22
  23       {:in_banned_urls, true} ->
  24         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  25
  26       {:error, :invalid_signature} ->
  27         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  28
  29       {:wrong_filename, filename} ->
  30         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  31     end
  32   end
  33
  34   def preview(conn, %{"sig" => sig64, "url" => url64}) do
  35     with {_, true} <- {:enabled, MediaProxy.preview_enabled?()},
  36          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  37          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  38       handle_preview(conn, url)
  39     else
  40       {:enabled, false} ->
  41         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  42
  43       {:error, :invalid_signature} ->
  44         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  45
  46       {:wrong_filename, filename} ->
  47         redirect(conn, external: MediaProxy.build_preview_url(sig64, url64, filename))
  48     end
  49   end
  50
  51   defp handle_preview(conn, url) do
  52     with {:ok, %{status: status} = head_response} when status in 200..299 <-
  53            Tesla.head(url,
  54              opts: [adapter: [timeout: preview_head_request_timeout(), follow_redirect: true]]
  55            ) do
  56       content_type = Tesla.get_header(head_response, "content-type")
  57       handle_preview(content_type, conn, url)
  58     else
  59       {_, %{status: status}} ->
  60         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers (HTTP #{status}).")
  61
  62       {:error, :recv_response_timeout} ->
  63         send_resp(conn, :failed_dependency, "HEAD request timeout.")
  64
  65       _ ->
  66         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers.")
  67     end
  68   end
  69
  70   defp handle_preview("image/gif" = _content_type, conn, url) do
  71     mediaproxy_url = url |> MediaProxy.url()
  72
  73     redirect(conn, external: mediaproxy_url)
  74   end
  75
  76   defp handle_preview("image/" <> _ = _content_type, conn, url) do
  77     handle_image_preview(conn, url)
  78   end
  79
  80   defp handle_preview("video/" <> _ = _content_type, conn, url) do
  81     handle_video_preview(conn, url)
  82   end
  83
  84   defp handle_preview(content_type, conn, _url) do
  85     send_resp(conn, :unprocessable_entity, "Unsupported content type: #{content_type}.")
  86   end
  87
  88   defp handle_image_preview(%{params: params} = conn, url) do
  89     quality = Config.get!([:media_preview_proxy, :image_quality])
  90
  91     with {thumbnail_max_width, thumbnail_max_height} <- thumbnail_max_dimensions(params),
  92          {:ok, thumbnail_binary} <-
  93            MediaHelper.image_resize(
  94              url,
  95              %{max_width: thumbnail_max_width, max_height: thumbnail_max_height, quality: quality}
  96            ) do
  97       conn
  98       |> put_resp_header("content-type", "image/jpeg")
  99       |> put_resp_header("content-disposition", "inline; filename=\"preview.jpg\"")
 100       |> send_resp(200, thumbnail_binary)
 101     else
 102       _ ->
 103         send_resp(conn, :failed_dependency, "Can't handle preview.")
 104     end
 105   end
 106
 107   defp handle_video_preview(conn, url) do
 108     with {:ok, thumbnail_binary} <-
 109            MediaHelper.video_framegrab(url) do
 110       conn
 111       |> put_resp_header("content-type", "image/jpeg")
 112       |> put_resp_header("content-disposition", "inline; filename=\"preview.jpg\"")
 113       |> send_resp(200, thumbnail_binary)
 114     else
 115       _ ->
 116         send_resp(conn, :failed_dependency, "Can't handle preview.")
 117     end
 118   end
 119
 120   defp thumbnail_max_dimensions(params) do
 121     config = Config.get([:media_preview_proxy], [])
 122
 123     thumbnail_max_width =
 124       if w = params["thumbnail_max_width"] do
 125         String.to_integer(w)
 126       else
 127         Keyword.fetch!(config, :thumbnail_max_width)
 128       end
 129
 130     thumbnail_max_height =
 131       if h = params["thumbnail_max_height"] do
 132         String.to_integer(h)
 133       else
 134         Keyword.fetch!(config, :thumbnail_max_height)
 135       end
 136
 137     {thumbnail_max_width, thumbnail_max_height}
 138   end
 139
 140   defp preview_head_request_timeout do
 141     Keyword.get(media_preview_proxy_opts(), :head_request_max_read_duration) ||
 142       Keyword.get(media_proxy_opts(), :max_read_duration) ||
 143       ReverseProxy.max_read_duration_default()
 144   end
 145
 146   defp media_proxy_opts do
 147     Config.get([:media_proxy, :proxy_opts], [])
 148   end
 149
 150   defp media_preview_proxy_opts do
 151     Config.get([:media_preview_proxy, :proxy_opts], [])
 152   end
 153 end