git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Helpers.MediaHelper
  10   alias Pleroma.ReverseProxy
  11   alias Pleroma.Web.MediaProxy
  12
  13   def remote(conn, %{"sig" => sig64, "url" => url64}) do
  14     with {_, true} <- {:enabled, MediaProxy.enabled?()},
  15          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  16          {_, false} <- {:in_banned_urls, MediaProxy.in_banned_urls(url)},
  17          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  18       ReverseProxy.call(conn, url, media_proxy_opts())
  19     else
  20       {:enabled, false} ->
  21         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  22
  23       {:in_banned_urls, true} ->
  24         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  25
  26       {:error, :invalid_signature} ->
  27         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  28
  29       {:wrong_filename, filename} ->
  30         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  31     end
  32   end
  33
  34   def preview(conn, %{"sig" => sig64, "url" => url64}) do
  35     with {_, true} <- {:enabled, MediaProxy.preview_enabled?()},
  36          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  37          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  38       handle_preview(conn, url)
  39     else
  40       {:enabled, false} ->
  41         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  42
  43       {:error, :invalid_signature} ->
  44         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  45
  46       {:wrong_filename, filename} ->
  47         redirect(conn, external: MediaProxy.build_preview_url(sig64, url64, filename))
  48     end
  49   end
  50
  51   defp handle_preview(conn, url) do
  52     with {:ok, %{status: status} = head_response} when status in 200..299 <-
  53            Tesla.head(url, opts: [adapter: [timeout: preview_head_request_timeout()]]) do
  54       content_type = Tesla.get_header(head_response, "content-type")
  55       handle_preview(content_type, conn, url)
  56     else
  57       {_, %{status: status}} ->
  58         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers (HTTP #{status}).")
  59
  60       {:error, :recv_response_timeout} ->
  61         send_resp(conn, :failed_dependency, "HEAD request timeout.")
  62
  63       _ ->
  64         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers.")
  65     end
  66   end
  67
  68   defp handle_preview("image/" <> _ = _content_type, conn, url) do
  69     handle_image_preview(conn, url)
  70   end
  71
  72   defp handle_preview(content_type, conn, _url) do
  73     send_resp(conn, :unprocessable_entity, "Unsupported content type: #{content_type}.")
  74   end
  75
  76   defp handle_image_preview(%{params: params} = conn, url) do
  77     quality = Config.get!([:media_preview_proxy, :image_quality])
  78
  79     with {thumbnail_max_width, thumbnail_max_height} <- thumbnail_max_dimensions(params),
  80          {:ok, thumbnail_binary} <-
  81            MediaHelper.image_resize(
  82              url,
  83              %{max_width: thumbnail_max_width, max_height: thumbnail_max_height, quality: quality}
  84            ) do
  85       conn
  86       |> put_resp_header("content-type", "image/jpeg")
  87       |> put_resp_header("content-disposition", "inline; filename=\"preview.jpg\"")
  88       |> send_resp(200, thumbnail_binary)
  89     else
  90       _ ->
  91         send_resp(conn, :failed_dependency, "Can't handle preview.")
  92     end
  93   end
  94
  95   defp thumbnail_max_dimensions(params) do
  96     config = Config.get([:media_preview_proxy], [])
  97
  98     thumbnail_max_width =
  99       if w = params["thumbnail_max_width"] do
 100         String.to_integer(w)
 101       else
 102         Keyword.fetch!(config, :thumbnail_max_width)
 103       end
 104
 105     thumbnail_max_height =
 106       if h = params["thumbnail_max_height"] do
 107         String.to_integer(h)
 108       else
 109         Keyword.fetch!(config, :thumbnail_max_height)
 110       end
 111
 112     {thumbnail_max_width, thumbnail_max_height}
 113   end
 114
 115   defp preview_head_request_timeout do
 116     Keyword.get(media_preview_proxy_opts(), :head_request_max_read_duration) ||
 117       Keyword.get(media_proxy_opts(), :max_read_duration) ||
 118       ReverseProxy.max_read_duration_default()
 119   end
 120
 121   defp media_proxy_opts do
 122     Config.get([:media_proxy, :proxy_opts], [])
 123   end
 124
 125   defp media_preview_proxy_opts do
 126     Config.get([:media_preview_proxy, :proxy_opts], [])
 127   end
 128 end