git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Helpers.MediaHelper
  10   alias Pleroma.ReverseProxy
  11   alias Pleroma.Web.MediaProxy
  12
  13   def remote(conn, %{"sig" => sig64, "url" => url64}) do
  14     with {_, true} <- {:enabled, MediaProxy.enabled?()},
  15          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  16          {_, false} <- {:in_banned_urls, MediaProxy.in_banned_urls(url)},
  17          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  18       ReverseProxy.call(conn, url, media_proxy_opts())
  19     else
  20       {:enabled, false} ->
  21         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  22
  23       {:in_banned_urls, true} ->
  24         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  25
  26       {:error, :invalid_signature} ->
  27         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  28
  29       {:wrong_filename, filename} ->
  30         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  31     end
  32   end
  33
  34   def preview(conn, %{"sig" => sig64, "url" => url64}) do
  35     with {_, true} <- {:enabled, MediaProxy.preview_enabled?()},
  36          {:ok, url} <- MediaProxy.decode_url(sig64, url64) do
  37       handle_preview(conn, url)
  38     else
  39       {:enabled, false} ->
  40         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  41
  42       {:error, :invalid_signature} ->
  43         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  44
  45       {:wrong_filename, filename} ->
  46         redirect(conn, external: MediaProxy.build_preview_url(sig64, url64, filename))
  47     end
  48   end
  49
  50   defp handle_preview(conn, url) do
  51     media_proxy_url = MediaProxy.url(url)
  52
  53     with {:ok, %{status: status} = head_response} when status in 200..299 <-
  54            Pleroma.HTTP.request("head", media_proxy_url, [], [], adapter: [pool: :media]) do
  55       content_type = Tesla.get_header(head_response, "content-type")
  56       handle_preview(content_type, conn, media_proxy_url)
  57     else
  58       {_, %{status: status}} ->
  59         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers (HTTP #{status}).")
  60
  61       {:error, :recv_response_timeout} ->
  62         send_resp(conn, :failed_dependency, "HEAD request timeout.")
  63
  64       _ ->
  65         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers.")
  66     end
  67   end
  68
  69   defp handle_preview(
  70          "image/" <> _ = _content_type,
  71          %{params: %{"output_format" => "jpeg"}} = conn,
  72          media_proxy_url
  73        ) do
  74     handle_jpeg_preview(conn, media_proxy_url)
  75   end
  76
  77   defp handle_preview("image/gif" = _content_type, conn, media_proxy_url) do
  78     redirect(conn, external: media_proxy_url)
  79   end
  80
  81   defp handle_preview("image/png" <> _ = _content_type, conn, media_proxy_url) do
  82     handle_png_preview(conn, media_proxy_url)
  83   end
  84
  85   defp handle_preview("image/" <> _ = _content_type, conn, media_proxy_url) do
  86     handle_jpeg_preview(conn, media_proxy_url)
  87   end
  88
  89   defp handle_preview("video/" <> _ = _content_type, conn, media_proxy_url) do
  90     handle_video_preview(conn, media_proxy_url)
  91   end
  92
  93   defp handle_preview(content_type, conn, _media_proxy_url) do
  94     send_resp(conn, :unprocessable_entity, "Unsupported content type: #{content_type}.")
  95   end
  96
  97   defp handle_png_preview(%{params: params} = conn, media_proxy_url) do
  98     quality = Config.get!([:media_preview_proxy, :image_quality])
  99
 100     with {thumbnail_max_width, thumbnail_max_height} <- thumbnail_max_dimensions(params),
 101          {:ok, thumbnail_binary} <-
 102            MediaHelper.image_resize(
 103              media_proxy_url,
 104              %{
 105                max_width: thumbnail_max_width,
 106                max_height: thumbnail_max_height,
 107                quality: quality,
 108                format: "png"
 109              }
 110            ) do
 111       conn
 112       |> put_preview_response_headers(["image/png", "preview.png"])
 113       |> send_resp(200, thumbnail_binary)
 114     else
 115       _ ->
 116         send_resp(conn, :failed_dependency, "Can't handle preview.")
 117     end
 118   end
 119
 120   defp handle_jpeg_preview(%{params: params} = conn, media_proxy_url) do
 121     quality = Config.get!([:media_preview_proxy, :image_quality])
 122
 123     with {thumbnail_max_width, thumbnail_max_height} <- thumbnail_max_dimensions(params),
 124          {:ok, thumbnail_binary} <-
 125            MediaHelper.image_resize(
 126              media_proxy_url,
 127              %{max_width: thumbnail_max_width, max_height: thumbnail_max_height, quality: quality}
 128            ) do
 129       conn
 130       |> put_preview_response_headers()
 131       |> send_resp(200, thumbnail_binary)
 132     else
 133       _ ->
 134         send_resp(conn, :failed_dependency, "Can't handle preview.")
 135     end
 136   end
 137
 138   defp handle_video_preview(conn, media_proxy_url) do
 139     with {:ok, thumbnail_binary} <-
 140            MediaHelper.video_framegrab(media_proxy_url) do
 141       conn
 142       |> put_preview_response_headers()
 143       |> send_resp(200, thumbnail_binary)
 144     else
 145       _ ->
 146         send_resp(conn, :failed_dependency, "Can't handle preview.")
 147     end
 148   end
 149
 150   defp put_preview_response_headers(
 151          conn,
 152          [content_type, filename] = _content_info \\ ["image/jpeg", "preview.jpg"]
 153        ) do
 154     conn
 155     |> put_resp_header("content-type", content_type)
 156     |> put_resp_header("content-disposition", "inline; filename=\"#{filename}\"")
 157     |> put_resp_header("cache-control", ReverseProxy.default_cache_control_header())
 158   end
 159
 160   defp thumbnail_max_dimensions(params) do
 161     config = Config.get([:media_preview_proxy], [])
 162
 163     thumbnail_max_width =
 164       if w = params["thumbnail_max_width"] do
 165         String.to_integer(w)
 166       else
 167         Keyword.fetch!(config, :thumbnail_max_width)
 168       end
 169
 170     thumbnail_max_height =
 171       if h = params["thumbnail_max_height"] do
 172         String.to_integer(h)
 173       else
 174         Keyword.fetch!(config, :thumbnail_max_height)
 175       end
 176
 177     {thumbnail_max_width, thumbnail_max_height}
 178   end
 179
 180   defp media_proxy_opts do
 181     Config.get([:media_proxy, :proxy_opts], [])
 182   end
 183 end