git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Helpers.MediaHelper
  10   alias Pleroma.ReverseProxy
  11   alias Pleroma.Web.MediaProxy
  12
  13   def remote(conn, %{"sig" => sig64, "url" => url64}) do
  14     with {_, true} <- {:enabled, MediaProxy.enabled?()},
  15          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  16          {_, false} <- {:in_banned_urls, MediaProxy.in_banned_urls(url)},
  17          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  18       proxy_opts = Config.get([:media_proxy, :proxy_opts], [])
  19       ReverseProxy.call(conn, url, proxy_opts)
  20     else
  21       {:enabled, false} ->
  22         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  23
  24       {:in_banned_urls, true} ->
  25         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  26
  27       {:error, :invalid_signature} ->
  28         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  29
  30       {:wrong_filename, filename} ->
  31         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  32     end
  33   end
  34
  35   def preview(conn, %{"sig" => sig64, "url" => url64}) do
  36     with {_, true} <- {:enabled, MediaProxy.preview_enabled?()},
  37          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  38          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  39       handle_preview(conn, url)
  40     else
  41       {:enabled, false} ->
  42         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  43
  44       {:error, :invalid_signature} ->
  45         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  46
  47       {:wrong_filename, filename} ->
  48         redirect(conn, external: MediaProxy.build_preview_url(sig64, url64, filename))
  49     end
  50   end
  51
  52   defp handle_preview(conn, url) do
  53     with {:ok, %{status: status} = head_response} when status in 200..299 <-
  54            Tesla.head(url, opts: [adapter: [timeout: preview_head_request_timeout()]]) do
  55       content_type = Tesla.get_header(head_response, "content-type")
  56       handle_preview(content_type, conn, url)
  57     else
  58       {_, %{status: status}} ->
  59         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers (HTTP #{status}).")
  60
  61       {:error, :recv_response_timeout} ->
  62         send_resp(conn, :failed_dependency, "HEAD request timeout.")
  63
  64       _ ->
  65         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers.")
  66     end
  67   end
  68
  69   defp handle_preview("image/" <> _ = _content_type, conn, url) do
  70     handle_image_or_video_preview(conn, url)
  71   end
  72
  73   defp handle_preview("video/" <> _ = _content_type, conn, url) do
  74     handle_image_or_video_preview(conn, url)
  75   end
  76
  77   defp handle_preview(content_type, conn, _url) do
  78     send_resp(conn, :unprocessable_entity, "Unsupported content type: #{content_type}.")
  79   end
  80
  81   defp handle_image_or_video_preview(%{params: params} = conn, url) do
  82     with {thumbnail_max_width, thumbnail_max_height} <- thumbnail_max_dimensions(params),
  83          media_proxy_url <- MediaProxy.url(url),
  84          {:ok, thumbnail_binary} <-
  85            MediaHelper.ffmpeg_resize(
  86              media_proxy_url,
  87              %{max_width: thumbnail_max_width, max_height: thumbnail_max_height}
  88            ) do
  89       conn
  90       |> put_resp_header("content-type", "image/jpeg")
  91       |> send_resp(200, thumbnail_binary)
  92     else
  93       _ ->
  94         send_resp(conn, :failed_dependency, "Can't handle preview.")
  95     end
  96   end
  97
  98   defp thumbnail_max_dimensions(params) do
  99     config = Config.get([:media_preview_proxy], [])
 100
 101     thumbnail_max_width =
 102       if w = params["thumbnail_max_width"] do
 103         String.to_integer(w)
 104       else
 105         Keyword.fetch!(config, :thumbnail_max_width)
 106       end
 107
 108     thumbnail_max_height =
 109       if h = params["thumbnail_max_height"] do
 110         String.to_integer(h)
 111       else
 112         Keyword.fetch!(config, :thumbnail_max_height)
 113       end
 114
 115     {thumbnail_max_width, thumbnail_max_height}
 116   end
 117
 118   defp preview_head_request_timeout do
 119     Config.get([:media_preview_proxy, :proxy_opts, :head_request_max_read_duration]) ||
 120       preview_timeout()
 121   end
 122
 123   defp preview_timeout do
 124     Config.get([:media_preview_proxy, :proxy_opts, :max_read_duration]) ||
 125       Config.get([:media_proxy, :proxy_opts, :max_read_duration]) ||
 126       ReverseProxy.max_read_duration_default()
 127   end
 128 end