git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Helpers.MediaHelper
  10   alias Pleroma.ReverseProxy
  11   alias Pleroma.Web.MediaProxy
  12
  13   def remote(conn, %{"sig" => sig64, "url" => url64}) do
  14     with {_, true} <- {:enabled, MediaProxy.enabled?()},
  15          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  16          {_, false} <- {:in_banned_urls, MediaProxy.in_banned_urls(url)},
  17          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  18       ReverseProxy.call(conn, url, media_proxy_opts())
  19     else
  20       {:enabled, false} ->
  21         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  22
  23       {:in_banned_urls, true} ->
  24         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  25
  26       {:error, :invalid_signature} ->
  27         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  28
  29       {:wrong_filename, filename} ->
  30         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  31     end
  32   end
  33
  34   def preview(conn, %{"sig" => sig64, "url" => url64}) do
  35     with {_, true} <- {:enabled, MediaProxy.preview_enabled?()},
  36          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  37          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  38       handle_preview(conn, url)
  39     else
  40       {:enabled, false} ->
  41         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  42
  43       {:error, :invalid_signature} ->
  44         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  45
  46       {:wrong_filename, filename} ->
  47         redirect(conn, external: MediaProxy.build_preview_url(sig64, url64, filename))
  48     end
  49   end
  50
  51   defp handle_preview(conn, url) do
  52     with {:ok, %{status: status} = head_response} when status in 200..299 <-
  53            Tesla.head(url,
  54              opts: [adapter: [timeout: preview_head_request_timeout(), follow_redirect: true]]
  55            ) do
  56       content_type = Tesla.get_header(head_response, "content-type")
  57       handle_preview(content_type, conn, url)
  58     else
  59       {_, %{status: status}} ->
  60         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers (HTTP #{status}).")
  61
  62       {:error, :recv_response_timeout} ->
  63         send_resp(conn, :failed_dependency, "HEAD request timeout.")
  64
  65       _ ->
  66         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers.")
  67     end
  68   end
  69
  70   # TODO: find a workaround so avatar_static and banner_static can work.
  71   # Those only permit GIFs for animation, so we have to permit a way to
  72   # allow those to get real static variants.
  73   defp handle_preview("image/gif" = _content_type, conn, url) do
  74     mediaproxy_url = url |> MediaProxy.url()
  75
  76     redirect(conn, external: mediaproxy_url)
  77   end
  78
  79   defp handle_preview("image/" <> _ = _content_type, conn, url) do
  80     handle_image_preview(conn, url)
  81   end
  82
  83   defp handle_preview("video/" <> _ = _content_type, conn, url) do
  84     handle_video_preview(conn, url)
  85   end
  86
  87   defp handle_preview(content_type, conn, _url) do
  88     send_resp(conn, :unprocessable_entity, "Unsupported content type: #{content_type}.")
  89   end
  90
  91   defp handle_image_preview(%{params: params} = conn, url) do
  92     quality = Config.get!([:media_preview_proxy, :image_quality])
  93
  94     with {thumbnail_max_width, thumbnail_max_height} <- thumbnail_max_dimensions(params),
  95          {:ok, thumbnail_binary} <-
  96            MediaHelper.image_resize(
  97              url,
  98              %{max_width: thumbnail_max_width, max_height: thumbnail_max_height, quality: quality}
  99            ) do
 100       conn
 101       |> put_resp_header("content-type", "image/jpeg")
 102       |> put_resp_header("content-disposition", "inline; filename=\"preview.jpg\"")
 103       |> send_resp(200, thumbnail_binary)
 104     else
 105       _ ->
 106         send_resp(conn, :failed_dependency, "Can't handle preview.")
 107     end
 108   end
 109
 110   defp handle_video_preview(conn, url) do
 111     with {:ok, thumbnail_binary} <-
 112            MediaHelper.video_framegrab(url) do
 113       conn
 114       |> put_resp_header("content-type", "image/jpeg")
 115       |> put_resp_header("content-disposition", "inline; filename=\"preview.jpg\"")
 116       |> send_resp(200, thumbnail_binary)
 117     else
 118       _ ->
 119         send_resp(conn, :failed_dependency, "Can't handle preview.")
 120     end
 121   end
 122
 123   defp thumbnail_max_dimensions(params) do
 124     config = Config.get([:media_preview_proxy], [])
 125
 126     thumbnail_max_width =
 127       if w = params["thumbnail_max_width"] do
 128         String.to_integer(w)
 129       else
 130         Keyword.fetch!(config, :thumbnail_max_width)
 131       end
 132
 133     thumbnail_max_height =
 134       if h = params["thumbnail_max_height"] do
 135         String.to_integer(h)
 136       else
 137         Keyword.fetch!(config, :thumbnail_max_height)
 138       end
 139
 140     {thumbnail_max_width, thumbnail_max_height}
 141   end
 142
 143   defp preview_head_request_timeout do
 144     Keyword.get(media_preview_proxy_opts(), :head_request_max_read_duration) ||
 145       Keyword.get(media_proxy_opts(), :max_read_duration) ||
 146       ReverseProxy.max_read_duration_default()
 147   end
 148
 149   defp media_proxy_opts do
 150     Config.get([:media_proxy, :proxy_opts], [])
 151   end
 152
 153   defp media_preview_proxy_opts do
 154     Config.get([:media_preview_proxy, :proxy_opts], [])
 155   end
 156 end