git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   6   use Pleroma.Web, :controller
   7   alias Pleroma.ReverseProxy
   8   alias Pleroma.Web.MediaProxy
   9
  10   @default_proxy_opts [max_body_length: 25 * 1_048_576, http: [follow_redirect: true]]
  11
  12   def remote(conn, %{"sig" => sig64, "url" => url64} = params) do
  13     with config <- Pleroma.Config.get([:media_proxy], []),
  14          true <- Keyword.get(config, :enabled, false),
  15          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  16          :ok <- filename_matches(params, conn.request_path, url) do
  17       ReverseProxy.call(conn, url, Keyword.get(config, :proxy_opts, @default_proxy_opts))
  18     else
  19       false ->
  20         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  21
  22       {:error, :invalid_signature} ->
  23         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  24
  25       {:wrong_filename, filename} ->
  26         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  27     end
  28   end
  29
  30   def filename_matches(%{"filename" => _} = _, path, url) do
  31     filename = MediaProxy.filename(url)
  32
  33     if filename && does_not_match(path, filename) do
  34       {:wrong_filename, filename}
  35     else
  36       :ok
  37     end
  38   end
  39
  40   def filename_matches(_, _, _), do: :ok
  41
  42   defp does_not_match(path, filename) do
  43     basename = Path.basename(path)
  44     basename != filename and URI.decode(basename) != filename and URI.encode(basename) != filename
  45   end
  46 end