git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy_controller.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   6   use Pleroma.Web, :controller
   7
   8   alias Pleroma.Config
   9   alias Pleroma.Helpers.MogrifyHelper
  10   alias Pleroma.ReverseProxy
  11   alias Pleroma.Web.MediaProxy
  12
  13   def remote(conn, %{"sig" => sig64, "url" => url64}) do
  14     with {_, true} <- {:enabled, MediaProxy.enabled?()},
  15          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  16          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  17       proxy_opts = Config.get([:media_proxy, :proxy_opts], [])
  18       ReverseProxy.call(conn, url, proxy_opts)
  19     else
  20       {:enabled, false} ->
  21         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  22
  23       {:error, :invalid_signature} ->
  24         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  25
  26       {:wrong_filename, filename} ->
  27         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  28     end
  29   end
  30
  31   def preview(conn, %{"sig" => sig64, "url" => url64}) do
  32     with {_, true} <- {:enabled, MediaProxy.preview_enabled?()},
  33          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  34          :ok <- MediaProxy.verify_request_path_and_url(conn, url) do
  35       handle_preview(conn, url)
  36     else
  37       {:enabled, false} ->
  38         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  39
  40       {:error, :invalid_signature} ->
  41         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  42
  43       {:wrong_filename, filename} ->
  44         redirect(conn, external: MediaProxy.build_preview_url(sig64, url64, filename))
  45     end
  46   end
  47
  48   defp handle_preview(conn, url) do
  49     with {:ok, %{status: status} = head_response} when status in 200..299 <-
  50            Tesla.head(url, opts: [adapter: [timeout: preview_head_request_timeout()]]) do
  51       content_type = Tesla.get_header(head_response, "content-type")
  52       handle_preview(content_type, conn, url)
  53     else
  54       {_, %{status: status}} ->
  55         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers (HTTP #{status}).")
  56
  57       {:error, :recv_response_timeout} ->
  58         send_resp(conn, :failed_dependency, "HEAD request timeout.")
  59
  60       _ ->
  61         send_resp(conn, :failed_dependency, "Can't fetch HTTP headers.")
  62     end
  63   end
  64
  65   defp handle_preview("image/" <> _ = content_type, %{params: params} = conn, url) do
  66     with {:ok, %{status: status, body: body}} when status in 200..299 <-
  67            url
  68            |> MediaProxy.url()
  69            |> Tesla.get(opts: [adapter: [timeout: preview_timeout()]]),
  70          {:ok, path} <- MogrifyHelper.store_as_temporary_file(url, body),
  71          resize_dimensions <-
  72            Map.get(
  73              params,
  74              "limit_dimensions",
  75              Config.get([:media_preview_proxy, :limit_dimensions])
  76            ),
  77          %Mogrify.Image{} <- MogrifyHelper.in_place_resize_to_limit(path, resize_dimensions),
  78          {:ok, image_binary} <- File.read(path),
  79          _ <- File.rm(path) do
  80       conn
  81       |> put_resp_header("content-type", content_type)
  82       |> send_resp(200, image_binary)
  83     else
  84       {_, %{status: _}} ->
  85         send_resp(conn, :failed_dependency, "Can't fetch the image.")
  86
  87       {:error, :recv_response_timeout} ->
  88         send_resp(conn, :failed_dependency, "Downstream timeout.")
  89
  90       _ ->
  91         send_resp(conn, :failed_dependency, "Can't handle image preview.")
  92     end
  93   end
  94
  95   defp handle_preview(content_type, conn, _url) do
  96     send_resp(conn, :unprocessable_entity, "Unsupported content type: #{content_type}.")
  97   end
  98
  99   defp preview_head_request_timeout do
 100     Config.get([:media_preview_proxy, :proxy_opts, :head_request_max_read_duration]) ||
 101       preview_timeout()
 102   end
 103
 104   defp preview_timeout do
 105     Config.get([:media_preview_proxy, :proxy_opts, :max_read_duration]) ||
 106       Config.get([:media_proxy, :proxy_opts, :max_read_duration]) ||
 107       ReverseProxy.max_read_duration_default()
 108   end
 109 end