git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   alias Pleroma.Config
   7   alias Pleroma.Upload
   8   alias Pleroma.Web
   9
  10   @base64_opts [padding: false]
  11
  12   def url(url) when is_nil(url) or url == "", do: nil
  13   def url("/" <> _ = url), do: url
  14
  15   def url(url) do
  16     if disabled?() or local?(url) or whitelisted?(url) do
  17       url
  18     else
  19       encode_url(url)
  20     end
  21   end
  22
  23   def preview_url(url) do
  24     if disabled?() or whitelisted?(url) do
  25       url
  26     else
  27       encode_preview_url(url)
  28     end
  29   end
  30
  31   defp disabled?, do: !Config.get([:media_proxy, :enabled], false)
  32
  33   defp local?(url), do: String.starts_with?(url, Pleroma.Web.base_url())
  34
  35   defp whitelisted?(url) do
  36     %{host: domain} = URI.parse(url)
  37
  38     mediaproxy_whitelist = Config.get([:media_proxy, :whitelist])
  39
  40     upload_base_url_domain =
  41       if !is_nil(Config.get([Upload, :base_url])) do
  42         [URI.parse(Config.get([Upload, :base_url])).host]
  43       else
  44         []
  45       end
  46
  47     whitelist = mediaproxy_whitelist ++ upload_base_url_domain
  48
  49     Enum.any?(whitelist, fn pattern ->
  50       String.equivalent?(domain, pattern)
  51     end)
  52   end
  53
  54   defp base64_sig64(url) do
  55     base64 = Base.url_encode64(url, @base64_opts)
  56
  57     sig64 =
  58       base64
  59       |> signed_url()
  60       |> Base.url_encode64(@base64_opts)
  61
  62     {base64, sig64}
  63   end
  64
  65   def encode_url(url) do
  66     {base64, sig64} = base64_sig64(url)
  67
  68     build_url(sig64, base64, filename(url))
  69   end
  70
  71   def encode_preview_url(url) do
  72     {base64, sig64} = base64_sig64(url)
  73
  74     build_preview_url(sig64, base64, filename(url))
  75   end
  76
  77   def decode_url(sig, url) do
  78     with {:ok, sig} <- Base.url_decode64(sig, @base64_opts),
  79          signature when signature == sig <- signed_url(url) do
  80       {:ok, Base.url_decode64!(url, @base64_opts)}
  81     else
  82       _ -> {:error, :invalid_signature}
  83     end
  84   end
  85
  86   defp signed_url(url) do
  87     :crypto.hmac(:sha, Config.get([Web.Endpoint, :secret_key_base]), url)
  88   end
  89
  90   def filename(url_or_path) do
  91     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  92   end
  93
  94   defp proxy_url(path, sig_base64, url_base64, filename) do
  95     [
  96       Pleroma.Config.get([:media_proxy, :base_url], Web.base_url()),
  97       path,
  98       sig_base64,
  99       url_base64,
 100       filename
 101     ]
 102     |> Enum.filter(& &1)
 103     |> Path.join()
 104   end
 105
 106   def build_url(sig_base64, url_base64, filename \\ nil) do
 107     proxy_url("proxy", sig_base64, url_base64, filename)
 108   end
 109
 110   def build_preview_url(sig_base64, url_base64, filename \\ nil) do
 111     proxy_url("proxy/preview", sig_base64, url_base64, filename)
 112   end
 113
 114   def filename_matches(%{"filename" => _} = _, path, url) do
 115     filename = filename(url)
 116
 117     if filename && not basename_matches?(path, filename) do
 118       {:wrong_filename, filename}
 119     else
 120       :ok
 121     end
 122   end
 123
 124   def filename_matches(_, _, _), do: :ok
 125
 126   defp basename_matches?(path, filename) do
 127     basename = Path.basename(path)
 128     basename == filename or URI.decode(basename) == filename or URI.encode(basename) == filename
 129   end
 130 end