git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   @base64_opts [padding: false]
   7
   8   def url(nil), do: nil
   9
  10   def url(""), do: nil
  11
  12   def url("/" <> _ = url), do: url
  13
  14   def url(url) do
  15     config = Application.get_env(:pleroma, :media_proxy, [])
  16     domain = URI.parse(url).host
  17
  18     cond do
  19       !Keyword.get(config, :enabled, false) or String.starts_with?(url, Pleroma.Web.base_url()) ->
  20         url
  21
  22       Enum.any?(Pleroma.Config.get([:media_proxy, :whitelist]), fn pattern ->
  23         String.equivalent?(domain, pattern)
  24       end) ->
  25         url
  26
  27       true ->
  28         encode_url(url)
  29     end
  30   end
  31
  32   def encode_url(url) do
  33     secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  34
  35     # Must preserve `%2F` for compatibility with S3
  36     # https://git.pleroma.social/pleroma/pleroma/issues/580
  37     replacement = get_replacement(url, ":2F:")
  38
  39     # The URL is url-decoded and encoded again to ensure it is correctly encoded and not twice.
  40     base64 =
  41       url
  42       |> String.replace("%2F", replacement)
  43       |> URI.decode()
  44       |> URI.encode()
  45       |> String.replace(replacement, "%2F")
  46       |> Base.url_encode64(@base64_opts)
  47
  48     sig = :crypto.hmac(:sha, secret, base64)
  49     sig64 = sig |> Base.url_encode64(@base64_opts)
  50
  51     build_url(sig64, base64, filename(url))
  52   end
  53
  54   def decode_url(sig, url) do
  55     secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  56     sig = Base.url_decode64!(sig, @base64_opts)
  57     local_sig = :crypto.hmac(:sha, secret, url)
  58
  59     if local_sig == sig do
  60       {:ok, Base.url_decode64!(url, @base64_opts)}
  61     else
  62       {:error, :invalid_signature}
  63     end
  64   end
  65
  66   def filename(url_or_path) do
  67     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  68   end
  69
  70   def build_url(sig_base64, url_base64, filename \\ nil) do
  71     [
  72       Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url()),
  73       "proxy",
  74       sig_base64,
  75       url_base64,
  76       filename
  77     ]
  78     |> Enum.filter(fn value -> value end)
  79     |> Path.join()
  80   end
  81
  82   defp get_replacement(url, replacement) do
  83     if String.contains?(url, replacement) do
  84       get_replacement(url, replacement <> replacement)
  85     else
  86       replacement
  87     end
  88   end
  89 end