git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 defmodule Pleroma.Web.MediaProxy do
   2   @base64_opts [padding: false]
   3
   4   def url(nil), do: nil
   5
   6   def url(""), do: nil
   7
   8   def url(url = "/" <> _), do: url
   9
  10   def url(url) do
  11     config = Application.get_env(:pleroma, :media_proxy, [])
  12
  13     if !Keyword.get(config, :enabled, false) or String.starts_with?(url, Pleroma.Web.base_url()) do
  14       url
  15     else
  16       secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  17       base64 = Base.url_encode64(url, @base64_opts)
  18       sig = :crypto.hmac(:sha, secret, base64)
  19       sig64 = sig |> Base.url_encode64(@base64_opts)
  20       filename = if path = URI.parse(url).path, do: "/" <> Path.basename(path), else: ""
  21
  22       Keyword.get(config, :base_url, Pleroma.Web.base_url()) <>
  23         "/proxy/#{sig64}/#{base64}#{filename}"
  24     end
  25   end
  26
  27   def decode_url(sig, url) do
  28     secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  29     sig = Base.url_decode64!(sig, @base64_opts)
  30     local_sig = :crypto.hmac(:sha, secret, url)
  31
  32     if local_sig == sig do
  33       {:ok, Base.url_decode64!(url, @base64_opts)}
  34     else
  35       {:error, :invalid_signature}
  36     end
  37   end
  38 end