git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   @base64_opts [padding: false]
   7
   8   def url(nil), do: nil
   9
  10   def url(""), do: nil
  11
  12   def url("/" <> _ = url), do: url
  13
  14   def url(url) do
  15     if !enabled?() or local?(url) or whitelisted?(url) do
  16       url
  17     else
  18       encode_url(url)
  19     end
  20   end
  21
  22   defp enabled?, do: Pleroma.Config.get([:media_proxy, :enabled], false)
  23
  24   defp local?(url), do: String.starts_with?(url, Pleroma.Web.base_url())
  25
  26   defp whitelisted?(url) do
  27     %{host: domain} = URI.parse(url)
  28
  29     Enum.any?(Pleroma.Config.get([:media_proxy, :whitelist]), fn pattern ->
  30       String.equivalent?(domain, pattern)
  31     end)
  32   end
  33
  34   def encode_url(url) do
  35     secret = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  36     base64 = Base.url_encode64(url, @base64_opts)
  37     sig = :crypto.hmac(:sha, secret, base64)
  38     sig64 = sig |> Base.url_encode64(@base64_opts)
  39
  40     build_url(sig64, base64, filename(url))
  41   end
  42
  43   def decode_url(sig, url) do
  44     secret = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  45     sig = Base.url_decode64!(sig, @base64_opts)
  46     local_sig = :crypto.hmac(:sha, secret, url)
  47
  48     if local_sig == sig do
  49       {:ok, Base.url_decode64!(url, @base64_opts)}
  50     else
  51       {:error, :invalid_signature}
  52     end
  53   end
  54
  55   def filename(url_or_path) do
  56     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  57   end
  58
  59   def build_url(sig_base64, url_base64, filename \\ nil) do
  60     [
  61       Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url()),
  62       "proxy",
  63       sig_base64,
  64       url_base64,
  65       filename
  66     ]
  67     |> Enum.filter(fn value -> value end)
  68     |> Path.join()
  69   end
  70 end