git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   @base64_opts [padding: false]
   7
   8   def url(nil), do: nil
   9
  10   def url(""), do: nil
  11
  12   def url("/" <> _ = url), do: url
  13
  14   def url(url) do
  15     if !enabled?() or local?(url) or whitelisted?(url) do
  16       url
  17     else
  18       encode_url(url)
  19     end
  20   end
  21
  22   defp enabled?, do: Pleroma.Config.get([:media_proxy, :enabled], false)
  23
  24   defp local?(url), do: String.starts_with?(url, Pleroma.Web.base_url())
  25
  26   defp whitelisted?(url) do
  27     %{host: domain} = URI.parse(url)
  28
  29     Enum.any?(Pleroma.Config.get([:media_proxy, :whitelist]), fn pattern ->
  30       String.equivalent?(domain, pattern)
  31     end)
  32   end
  33
  34   def encode_url(url) do
  35     secret = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  36
  37     # Must preserve `%2F` for compatibility with S3
  38     # https://git.pleroma.social/pleroma/pleroma/issues/580
  39     replacement = get_replacement(url, ":2F:")
  40
  41     # The URL is url-decoded and encoded again to ensure it is correctly encoded and not twice.
  42     base64 =
  43       url
  44       |> String.replace("%2F", replacement)
  45       |> URI.decode()
  46       |> URI.encode()
  47       |> String.replace(replacement, "%2F")
  48       |> Base.url_encode64(@base64_opts)
  49
  50     sig = :crypto.hmac(:sha, secret, base64)
  51     sig64 = sig |> Base.url_encode64(@base64_opts)
  52
  53     build_url(sig64, base64, filename(url))
  54   end
  55
  56   def decode_url(sig, url) do
  57     secret = Pleroma.Config.get([Pleroma.Web.Endpoint, :secret_key_base])
  58     sig = Base.url_decode64!(sig, @base64_opts)
  59     local_sig = :crypto.hmac(:sha, secret, url)
  60
  61     if local_sig == sig do
  62       {:ok, Base.url_decode64!(url, @base64_opts)}
  63     else
  64       {:error, :invalid_signature}
  65     end
  66   end
  67
  68   def filename(url_or_path) do
  69     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  70   end
  71
  72   def build_url(sig_base64, url_base64, filename \\ nil) do
  73     [
  74       Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url()),
  75       "proxy",
  76       sig_base64,
  77       url_base64,
  78       filename
  79     ]
  80     |> Enum.filter(fn value -> value end)
  81     |> Path.join()
  82   end
  83
  84   defp get_replacement(url, replacement) do
  85     if String.contains?(url, replacement) do
  86       get_replacement(url, replacement <> replacement)
  87     else
  88       replacement
  89     end
  90   end
  91 end