git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 defmodule Pleroma.Web.MediaProxy do
   2   @base64_opts [padding: false]
   3
   4   def url(nil), do: nil
   5
   6   def url(""), do: nil
   7
   8   def url(url = "/" <> _), do: url
   9
  10   def url(url) do
  11     config = Application.get_env(:pleroma, :media_proxy, [])
  12
  13     if !Keyword.get(config, :enabled, false) or String.starts_with?(url, Pleroma.Web.base_url()) do
  14       url
  15     else
  16       secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  17
  18       # The URL is url-decoded and encoded again to ensure it is correctly encoded and not twice.
  19       base64 =
  20         url
  21         |> URI.decode()
  22         |> URI.encode()
  23         |> Base.url_encode64(@base64_opts)
  24
  25       sig = :crypto.hmac(:sha, secret, base64)
  26       sig64 = sig |> Base.url_encode64(@base64_opts)
  27
  28       build_url(sig64, base64, filename(url))
  29     end
  30   end
  31
  32   def decode_url(sig, url) do
  33     secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  34     sig = Base.url_decode64!(sig, @base64_opts)
  35     local_sig = :crypto.hmac(:sha, secret, url)
  36
  37     if local_sig == sig do
  38       {:ok, Base.url_decode64!(url, @base64_opts)}
  39     else
  40       {:error, :invalid_signature}
  41     end
  42   end
  43
  44   def filename(url_or_path) do
  45     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  46   end
  47
  48   def build_url(sig_base64, url_base64, filename \\ nil) do
  49     [
  50       Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url()),
  51       "proxy",
  52       sig_base64,
  53       url_base64,
  54       filename
  55     ]
  56     |> Enum.filter(fn value -> value end)
  57     |> Path.join()
  58   end
  59 end