git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   @base64_opts [padding: false]
   7
   8   def url(nil), do: nil
   9
  10   def url(""), do: nil
  11
  12   def url("/" <> _ = url), do: url
  13
  14   def url(url) do
  15     config = Application.get_env(:pleroma, :media_proxy, [])
  16
  17     if !Keyword.get(config, :enabled, false) or String.starts_with?(url, Pleroma.Web.base_url()) do
  18       url
  19     else
  20       secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  21
  22       # Must preserve `%2F` for compatibility with S3
  23       # https://git.pleroma.social/pleroma/pleroma/issues/580
  24       replacement = get_replacement(url, ":2F:")
  25
  26       # The URL is url-decoded and encoded again to ensure it is correctly encoded and not twice.
  27       base64 =
  28         url
  29         |> String.replace("%2F", replacement)
  30         |> URI.decode()
  31         |> URI.encode()
  32         |> String.replace(replacement, "%2F")
  33         |> Base.url_encode64(@base64_opts)
  34
  35       sig = :crypto.hmac(:sha, secret, base64)
  36       sig64 = sig |> Base.url_encode64(@base64_opts)
  37
  38       build_url(sig64, base64, filename(url))
  39     end
  40   end
  41
  42   def decode_url(sig, url) do
  43     secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  44     sig = Base.url_decode64!(sig, @base64_opts)
  45     local_sig = :crypto.hmac(:sha, secret, url)
  46
  47     if local_sig == sig do
  48       {:ok, Base.url_decode64!(url, @base64_opts)}
  49     else
  50       {:error, :invalid_signature}
  51     end
  52   end
  53
  54   def filename(url_or_path) do
  55     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  56   end
  57
  58   def build_url(sig_base64, url_base64, filename \\ nil) do
  59     [
  60       Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url()),
  61       "proxy",
  62       sig_base64,
  63       url_base64,
  64       filename
  65     ]
  66     |> Enum.filter(fn value -> value end)
  67     |> Path.join()
  68   end
  69
  70   defp get_replacement(url, replacement) do
  71     if String.contains?(url, replacement) do
  72       get_replacement(url, replacement <> replacement)
  73     else
  74       replacement
  75     end
  76   end
  77 end