git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   @base64_opts [padding: false]
   7
   8   def url(nil), do: nil
   9
  10   def url(""), do: nil
  11
  12   def url("/" <> _ = url), do: url
  13
  14   def url(url) do
  15     config = Application.get_env(:pleroma, :media_proxy, [])
  16
  17     if !Keyword.get(config, :enabled, false) or String.starts_with?(url, Pleroma.Web.base_url()) do
  18       url
  19     else
  20       secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  21
  22       # The URL is url-decoded and encoded again to ensure it is correctly encoded and not twice.
  23       base64 =
  24         url
  25         |> URI.decode()
  26         |> URI.encode()
  27         |> Base.url_encode64(@base64_opts)
  28
  29       sig = :crypto.hmac(:sha, secret, base64)
  30       sig64 = sig |> Base.url_encode64(@base64_opts)
  31
  32       build_url(sig64, base64, filename(url))
  33     end
  34   end
  35
  36   def decode_url(sig, url) do
  37     secret = Application.get_env(:pleroma, Pleroma.Web.Endpoint)[:secret_key_base]
  38     sig = Base.url_decode64!(sig, @base64_opts)
  39     local_sig = :crypto.hmac(:sha, secret, url)
  40
  41     if local_sig == sig do
  42       {:ok, Base.url_decode64!(url, @base64_opts)}
  43     else
  44       {:error, :invalid_signature}
  45     end
  46   end
  47
  48   def filename(url_or_path) do
  49     if path = URI.parse(url_or_path).path, do: Path.basename(path)
  50   end
  51
  52   def build_url(sig_base64, url_base64, filename \\ nil) do
  53     [
  54       Pleroma.Config.get([:media_proxy, :base_url], Pleroma.Web.base_url()),
  55       "proxy",
  56       sig_base64,
  57       url_base64,
  58       filename
  59     ]
  60     |> Enum.filter(fn value -> value end)
  61     |> Path.join()
  62   end
  63 end