git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/media_proxy.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MediaProxy do
   6   alias Pleroma.Config
   7   alias Pleroma.Upload
   8   alias Pleroma.Web
   9   alias Pleroma.Web.MediaProxy.Invalidation
  10
  11   @base64_opts [padding: false]
  12
  13   @spec in_banned_urls(String.t()) :: boolean()
  14   def in_banned_urls(url), do: elem(Cachex.exists?(:banned_urls_cache, url(url)), 1)
  15
  16   def remove_from_banned_urls(urls) when is_list(urls) do
  17     Cachex.execute!(:banned_urls_cache, fn cache ->
  18       Enum.each(Invalidation.prepare_urls(urls), &Cachex.del(cache, &1))
  19     end)
  20   end
  21
  22   def remove_from_banned_urls(url) when is_binary(url) do
  23     Cachex.del(:banned_urls_cache, url(url))
  24   end
  25
  26   def put_in_banned_urls(urls) when is_list(urls) do
  27     Cachex.execute!(:banned_urls_cache, fn cache ->
  28       Enum.each(Invalidation.prepare_urls(urls), &Cachex.put(cache, &1, true))
  29     end)
  30   end
  31
  32   def put_in_banned_urls(url) when is_binary(url) do
  33     Cachex.put(:banned_urls_cache, url(url), true)
  34   end
  35
  36   def url(url) when is_nil(url) or url == "", do: nil
  37   def url("/" <> _ = url), do: url
  38
  39   def url(url) do
  40     if disabled?() or not url_proxiable?(url) do
  41       url
  42     else
  43       encode_url(url)
  44     end
  45   end
  46
  47   @spec url_proxiable?(String.t()) :: boolean()
  48   def url_proxiable?(url) do
  49     if local?(url) or whitelisted?(url) do
  50       false
  51     else
  52       true
  53     end
  54   end
  55
  56   defp disabled?, do: !Config.get([:media_proxy, :enabled], false)
  57
  58   defp local?(url), do: String.starts_with?(url, Pleroma.Web.base_url())
  59
  60   defp whitelisted?(url) do
  61     %{host: domain} = URI.parse(url)
  62
  63     mediaproxy_whitelist = Config.get([:media_proxy, :whitelist])
  64
  65     upload_base_url_domain =
  66       if !is_nil(Config.get([Upload, :base_url])) do
  67         [URI.parse(Config.get([Upload, :base_url])).host]
  68       else
  69         []
  70       end
  71
  72     whitelist = mediaproxy_whitelist ++ upload_base_url_domain
  73
  74     Enum.any?(whitelist, fn pattern ->
  75       String.equivalent?(domain, pattern)
  76     end)
  77   end
  78
  79   def encode_url(url) do
  80     base64 = Base.url_encode64(url, @base64_opts)
  81
  82     sig64 =
  83       base64
  84       |> signed_url
  85       |> Base.url_encode64(@base64_opts)
  86
  87     build_url(sig64, base64, filename(url))
  88   end
  89
  90   def decode_url(sig, url) do
  91     with {:ok, sig} <- Base.url_decode64(sig, @base64_opts),
  92          signature when signature == sig <- signed_url(url) do
  93       {:ok, Base.url_decode64!(url, @base64_opts)}
  94     else
  95       _ -> {:error, :invalid_signature}
  96     end
  97   end
  98
  99   defp signed_url(url) do
 100     :crypto.hmac(:sha, Config.get([Web.Endpoint, :secret_key_base]), url)
 101   end
 102
 103   def filename(url_or_path) do
 104     if path = URI.parse(url_or_path).path, do: Path.basename(path)
 105   end
 106
 107   def build_url(sig_base64, url_base64, filename \\ nil) do
 108     [
 109       Pleroma.Config.get([:media_proxy, :base_url], Web.base_url()),
 110       "proxy",
 111       sig_base64,
 112       url_base64,
 113       filename
 114     ]
 115     |> Enum.filter(& &1)
 116     |> Path.join()
 117   end
 118 end