git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/controller.ex

   1 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4
   5   @httpoison Application.get_env(:pleroma, :httpoison)
   6
   7   @max_body_length 25 * 1048576
   8
   9   @cache_control %{
  10     default: "public, max-age=1209600",
  11     error:   "public, must-revalidate, max-age=160",
  12   }
  13
  14   def remote(conn, %{"sig" => sig, "url" => url}) do
  15     config = Application.get_env(:pleroma, :media_proxy, [])
  16     with \
  17       true <- Keyword.get(config, :enabled, false),
  18       {:ok, url} <- Pleroma.Web.MediaProxy.decode_url(sig, url),
  19       {:ok, content_type, body} <- proxy_request(url)
  20     do
  21       conn
  22       |> put_resp_content_type(content_type)
  23       |> set_cache_header(:default)
  24       |> send_resp(200, body)
  25     else
  26       false -> send_error(conn, 404)
  27       {:error, :invalid_signature} -> send_error(conn, 403)
  28       {:error, {:http, _, url}} -> redirect_or_error(conn, url, Keyword.get(config, :redirect_on_failure, true))
  29     end
  30   end
  31
  32   defp proxy_request(link) do
  33     headers = [{"user-agent", "Pleroma/MediaProxy; #{Pleroma.Web.base_url()} <#{Application.get_env(:pleroma, :instance)[:email]}>"}]
  34     options = @httpoison.process_request_options([:insecure, {:follow_redirect, true}])
  35     with \
  36       {:ok, 200, headers, client} <- :hackney.request(:get, link, headers, "", options),
  37       headers = Enum.into(headers, Map.new),
  38       {:ok, body} <- proxy_request_body(client),
  39       content_type <- proxy_request_content_type(headers, body)
  40     do
  41       {:ok, content_type, body}
  42     else
  43       {:ok, status, _, _} ->
  44         Logger.warn "MediaProxy: request failed, status #{status}, link: #{link}"
  45         {:error, {:http, :bad_status, link}}
  46       {:error, error} ->
  47         Logger.warn "MediaProxy: request failed, error #{inspect error}, link: #{link}"
  48         {:error, {:http, error, link}}
  49     end
  50   end
  51
  52   defp set_cache_header(conn, key) do
  53     Plug.Conn.put_resp_header(conn, "cache-control", @cache_control[key])
  54   end
  55
  56   defp redirect_or_error(conn, url, true), do: redirect(conn, external: url)
  57   defp redirect_or_error(conn, url, _), do: send_error(conn, 502, "Media proxy error: " <> url)
  58
  59   defp send_error(conn, code, body \\ "") do
  60     conn
  61     |> set_cache_header(:error)
  62     |> send_resp(code, body)
  63   end
  64
  65   defp proxy_request_body(client), do: proxy_request_body(client, <<>>)
  66   defp proxy_request_body(client, body) when byte_size(body) < @max_body_length do
  67     case :hackney.stream_body(client) do
  68       {:ok, data} -> proxy_request_body(client, <<body :: binary, data :: binary>>)
  69       :done -> {:ok, body}
  70       {:error, reason} -> {:error, reason}
  71     end
  72   end
  73   defp proxy_request_body(client, _) do
  74     :hackney.close(client)
  75     {:error, :body_too_large}
  76   end
  77
  78   # TODO: the body is passed here as well because some hosts do not provide a content-type.
  79   # At some point we may want to use magic numbers to discover the content-type and reply a proper one.
  80   defp proxy_request_content_type(headers, _body) do
  81     headers["Content-Type"] || headers["content-type"] || "image/jpeg"
  82   end
  83
  84 end