git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/controller.ex

   1 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   2   use Pleroma.Web, :controller
   3   alias Pleroma.{Web.MediaProxy, ReverseProxy}
   4
   5   @default_proxy_opts [max_body_length: 25 * 1_048_576, http: [follow_redirect: true]]
   6
   7   def remote(conn, params = %{"sig" => sig64, "url" => url64}) do
   8     with config <- Pleroma.Config.get([:media_proxy], []),
   9          true <- Keyword.get(config, :enabled, false),
  10          {:ok, url} <- MediaProxy.decode_url(sig64, url64),
  11          filename <- Path.basename(URI.parse(url).path),
  12          :ok <- filename_matches(Map.has_key?(params, "filename"), conn.request_path, url) do
  13       ReverseProxy.call(conn, url, Keyword.get(config, :proxy_opts, @default_proxy_opts))
  14     else
  15       false ->
  16         send_resp(conn, 404, Plug.Conn.Status.reason_phrase(404))
  17
  18       {:error, :invalid_signature} ->
  19         send_resp(conn, 403, Plug.Conn.Status.reason_phrase(403))
  20
  21       {:wrong_filename, filename} ->
  22         redirect(conn, external: MediaProxy.build_url(sig64, url64, filename))
  23     end
  24   end
  25
  26   def filename_matches(has_filename, path, url) do
  27     filename =
  28       url
  29       |> MediaProxy.filename()
  30       |> URI.decode()
  31
  32     path = URI.decode(path)
  33
  34     cond do
  35       has_filename && filename && Path.basename(path) != filename -> {:wrong_filename, filename}
  36       true -> :ok
  37     end
  38   end
  39 end