git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/controller.ex

   1 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4
   5   @cache_control %{
   6     default: "public, max-age=1209600",
   7     error:   "public, must-revalidate, max-age=160",
   8   }
   9
  10   def remote(conn, %{"sig" => sig, "url" => url}) do
  11     config = Application.get_env(:pleroma, :media_proxy, [])
  12     with \
  13       true <- Keyword.get(config, :enabled, false),
  14       {:ok, url} <- Pleroma.Web.MediaProxy.decode_url(sig, url),
  15       url = URI.encode(url),
  16       {:ok, content_type, body} <- proxy_request(url)
  17     do
  18       conn
  19       |> put_resp_content_type(content_type)
  20       |> set_cache_header(:default)
  21       |> send_resp(200, body)
  22     else
  23       false -> send_error(conn, 404)
  24       {:error, :invalid_signature} -> send_error(conn, 403)
  25       {:error, {:http, _, url}} -> redirect_or_error(conn, url, Keyword.get(config, :redirect_on_failure, true))
  26     end
  27   end
  28
  29   defp proxy_request(link) do
  30     headers = [{"user-agent", "Pleroma/MediaProxy; #{Pleroma.Web.base_url()} <#{Application.get_env(:pleroma, :instance)[:email]}>"}]
  31     options = [:insecure, {:follow_redirect, true}]
  32     case :hackney.request(:get, link, headers, "", options) do
  33       {:ok, 200, headers, client} ->
  34         headers = Enum.into(headers, Map.new)
  35         {:ok, body} = :hackney.body(client)
  36         {:ok, headers["Content-Type"], body}
  37       {:ok, status, _, _} ->
  38         Logger.warn "MediaProxy: request failed, status #{status}, link: #{link}"
  39         {:error, {:http, :bad_status, link}}
  40       {:error, error} ->
  41         Logger.warn "MediaProxy: request failed, error #{inspect error}, link: #{link}"
  42         {:error, {:http, error, link}}
  43     end
  44   end
  45
  46   defp set_cache_header(conn, key) do
  47     Plug.Conn.put_resp_header(conn, "cache-control", @cache_control[key])
  48   end
  49
  50   defp redirect_or_error(conn, url, true), do: redirect(conn, external: url)
  51   defp redirect_or_error(conn, url, _), do: send_error(conn, 502, "Media proxy error: " <> url)
  52
  53   defp send_error(conn, code, body \\ "") do
  54     conn
  55     |> set_cache_header(:error)
  56     |> send_resp(code, body)
  57   end
  58
  59 end