git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/controller.ex

   1 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4
   5   @httpoison Application.get_env(:pleroma, :httpoison)
   6
   7   @max_body_length 25 * 1_048_576
   8
   9   @cache_control %{
  10     default: "public, max-age=1209600",
  11     error: "public, must-revalidate, max-age=160"
  12   }
  13
  14   def remote(conn, %{"sig" => sig, "url" => url}) do
  15     config = Application.get_env(:pleroma, :media_proxy, [])
  16
  17     with true <- Keyword.get(config, :enabled, false),
  18          {:ok, url} <- Pleroma.Web.MediaProxy.decode_url(sig, url),
  19          {:ok, content_type, body} <- proxy_request(url) do
  20       conn
  21       |> put_resp_content_type(content_type)
  22       |> set_cache_header(:default)
  23       |> send_resp(200, body)
  24     else
  25       false ->
  26         send_error(conn, 404)
  27
  28       {:error, :invalid_signature} ->
  29         send_error(conn, 403)
  30
  31       {:error, {:http, _, url}} ->
  32         redirect_or_error(conn, url, Keyword.get(config, :redirect_on_failure, true))
  33     end
  34   end
  35
  36   defp proxy_request(link) do
  37     headers = [
  38       {"user-agent",
  39        "Pleroma/MediaProxy; #{Pleroma.Web.base_url()} <#{
  40          Application.get_env(:pleroma, :instance)[:email]
  41        }>"}
  42     ]
  43
  44     options =
  45       @httpoison.process_request_options([:insecure, {:follow_redirect, true}]) ++
  46         [{:pool, :default}]
  47
  48     with {:ok, 200, headers, client} <- :hackney.request(:get, link, headers, "", options),
  49          headers = Enum.into(headers, Map.new()),
  50          {:ok, body} <- proxy_request_body(client),
  51          content_type <- proxy_request_content_type(headers, body) do
  52       {:ok, content_type, body}
  53     else
  54       {:ok, status, _, _} ->
  55         Logger.warn("MediaProxy: request failed, status #{status}, link: #{link}")
  56         {:error, {:http, :bad_status, link}}
  57
  58       {:error, error} ->
  59         Logger.warn("MediaProxy: request failed, error #{inspect(error)}, link: #{link}")
  60         {:error, {:http, error, link}}
  61     end
  62   end
  63
  64   defp set_cache_header(conn, key) do
  65     Plug.Conn.put_resp_header(conn, "cache-control", @cache_control[key])
  66   end
  67
  68   defp redirect_or_error(conn, url, true), do: redirect(conn, external: url)
  69   defp redirect_or_error(conn, url, _), do: send_error(conn, 502, "Media proxy error: " <> url)
  70
  71   defp send_error(conn, code, body \\ "") do
  72     conn
  73     |> set_cache_header(:error)
  74     |> send_resp(code, body)
  75   end
  76
  77   defp proxy_request_body(client), do: proxy_request_body(client, <<>>)
  78
  79   defp proxy_request_body(client, body) when byte_size(body) < @max_body_length do
  80     case :hackney.stream_body(client) do
  81       {:ok, data} -> proxy_request_body(client, <<body::binary, data::binary>>)
  82       :done -> {:ok, body}
  83       {:error, reason} -> {:error, reason}
  84     end
  85   end
  86
  87   defp proxy_request_body(client, _) do
  88     :hackney.close(client)
  89     {:error, :body_too_large}
  90   end
  91
  92   # TODO: the body is passed here as well because some hosts do not provide a content-type.
  93   # At some point we may want to use magic numbers to discover the content-type and reply a proper one.
  94   defp proxy_request_content_type(headers, _body) do
  95     headers["Content-Type"] || headers["content-type"] || "image/jpeg"
  96   end
  97 end