git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/controller.ex

   1 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4
   5   @max_body_length 25 * 1048576
   6
   7   @cache_control %{
   8     default: "public, max-age=1209600",
   9     error:   "public, must-revalidate, max-age=160",
  10   }
  11
  12   def remote(conn, %{"sig" => sig, "url" => url}) do
  13     config = Application.get_env(:pleroma, :media_proxy, [])
  14     with \
  15       true <- Keyword.get(config, :enabled, false),
  16       {:ok, url} <- Pleroma.Web.MediaProxy.decode_url(sig, url),
  17       {:ok, content_type, body} <- proxy_request(url)
  18     do
  19       conn
  20       |> put_resp_content_type(content_type)
  21       |> set_cache_header(:default)
  22       |> send_resp(200, body)
  23     else
  24       false -> send_error(conn, 404)
  25       {:error, :invalid_signature} -> send_error(conn, 403)
  26       {:error, {:http, _, url}} -> redirect_or_error(conn, url, Keyword.get(config, :redirect_on_failure, true))
  27     end
  28   end
  29
  30   defp proxy_request(link) do
  31     headers = [{"user-agent", "Pleroma/MediaProxy; #{Pleroma.Web.base_url()} <#{Application.get_env(:pleroma, :instance)[:email]}>"}]
  32     options = [:insecure, {:follow_redirect, true}]
  33     with \
  34       {:ok, 200, headers, client} <- :hackney.request(:get, link, headers, "", options),
  35       headers = Enum.into(headers, Map.new),
  36       {:ok, body} <- proxy_request_body(client),
  37       content_type <- proxy_request_content_type(headers, body)
  38     do
  39       {:ok, content_type, body}
  40     else
  41       {:ok, status, _, _} ->
  42         Logger.warn "MediaProxy: request failed, status #{status}, link: #{link}"
  43         {:error, {:http, :bad_status, link}}
  44       {:error, error} ->
  45         Logger.warn "MediaProxy: request failed, error #{inspect error}, link: #{link}"
  46         {:error, {:http, error, link}}
  47     end
  48   end
  49
  50   defp set_cache_header(conn, key) do
  51     Plug.Conn.put_resp_header(conn, "cache-control", @cache_control[key])
  52   end
  53
  54   defp redirect_or_error(conn, url, true), do: redirect(conn, external: url)
  55   defp redirect_or_error(conn, url, _), do: send_error(conn, 502, "Media proxy error: " <> url)
  56
  57   defp send_error(conn, code, body \\ "") do
  58     conn
  59     |> set_cache_header(:error)
  60     |> send_resp(code, body)
  61   end
  62
  63   defp proxy_request_body(client), do: proxy_request_body(client, <<>>)
  64   defp proxy_request_body(client, body) when byte_size(body) < @max_body_length do
  65     case :hackney.stream_body(client) do
  66       {:ok, data} -> proxy_request_body(client, <<body :: binary, data :: binary>>)
  67       :done -> {:ok, body}
  68       {:error, reason} -> {:error, reason}
  69     end
  70   end
  71   defp proxy_request_body(client, _) do
  72     :hackney.close(client)
  73     {:error, :body_too_large}
  74   end
  75
  76   # TODO: the body is passed here as well because some hosts do not provide a content-type.
  77   # At some point we may want to use magic numbers to discover the content-type and reply a proper one.
  78   defp proxy_request_content_type(headers, _body) do
  79     headers["Content-Type"] || headers["content-type"] || "image/jpeg"
  80   end
  81
  82 end