git.squeep.com Git - akkoma/blob - lib/pleroma/web/media_proxy/controller.ex

   1 defmodule Pleroma.Web.MediaProxy.MediaProxyController do
   2   use Pleroma.Web, :controller
   3   require Logger
   4
   5   @max_body_length 25 * 1048576
   6
   7   @cache_control %{
   8     default: "public, max-age=1209600",
   9     error:   "public, must-revalidate, max-age=160",
  10   }
  11
  12   def remote(conn, %{"sig" => sig, "url" => url}) do
  13     config = Application.get_env(:pleroma, :media_proxy, [])
  14     with \
  15       true <- Keyword.get(config, :enabled, false),
  16       {:ok, url} <- Pleroma.Web.MediaProxy.decode_url(sig, url),
  17       url = URI.encode(url),
  18       {:ok, content_type, body} <- proxy_request(url)
  19     do
  20       conn
  21       |> put_resp_content_type(content_type)
  22       |> set_cache_header(:default)
  23       |> send_resp(200, body)
  24     else
  25       false -> send_error(conn, 404)
  26       {:error, :invalid_signature} -> send_error(conn, 403)
  27       {:error, {:http, _, url}} -> redirect_or_error(conn, url, Keyword.get(config, :redirect_on_failure, true))
  28     end
  29   end
  30
  31   defp proxy_request(link) do
  32     headers = [{"user-agent", "Pleroma/MediaProxy; #{Pleroma.Web.base_url()} <#{Application.get_env(:pleroma, :instance)[:email]}>"}]
  33     options = [:insecure, {:follow_redirect, true}]
  34     with \
  35       {:ok, 200, headers, client} <- :hackney.request(:get, link, headers, "", options),
  36       headers = Enum.into(headers, Map.new),
  37       {:ok, body} <- proxy_request_body(client),
  38       content_type <- proxy_request_content_type(headers, body)
  39     do
  40       {:ok, content_type, body}
  41     else
  42       {:ok, status, _, _} ->
  43         Logger.warn "MediaProxy: request failed, status #{status}, link: #{link}"
  44         {:error, {:http, :bad_status, link}}
  45       {:error, error} ->
  46         Logger.warn "MediaProxy: request failed, error #{inspect error}, link: #{link}"
  47         {:error, {:http, error, link}}
  48     end
  49   end
  50
  51   defp set_cache_header(conn, key) do
  52     Plug.Conn.put_resp_header(conn, "cache-control", @cache_control[key])
  53   end
  54
  55   defp redirect_or_error(conn, url, true), do: redirect(conn, external: url)
  56   defp redirect_or_error(conn, url, _), do: send_error(conn, 502, "Media proxy error: " <> url)
  57
  58   defp send_error(conn, code, body \\ "") do
  59     conn
  60     |> set_cache_header(:error)
  61     |> send_resp(code, body)
  62   end
  63
  64   defp proxy_request_body(client), do: proxy_request_body(client, <<>>)
  65   defp proxy_request_body(client, body) when byte_size(body) < @max_body_length do
  66     case :hackney.stream_body(client) do
  67       {:ok, data} -> proxy_request_body(client, <<body :: binary, data :: binary>>)
  68       :done -> {:ok, body}
  69       {:error, reason} -> {:error, reason}
  70     end
  71   end
  72   defp proxy_request_body(client, _) do
  73     :hackney.close(client)
  74     {:error, :body_too_large}
  75   end
  76
  77   # TODO: the body is passed here as well because some hosts do not provide a content-type.
  78   # At some point we may want to use magic numbers to discover the content-type and reply a proper one.
  79   defp proxy_request_content_type(headers, _body) do
  80     headers["Content-Type"] || headers["content-type"] || "image/jpeg"
  81   end
  82
  83 end