git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/websocket_handler.ex

   1 defmodule Pleroma.Web.MastodonAPI.WebsocketHandler do
   2   require Logger
   3
   4   alias Pleroma.Web.OAuth.Token
   5   alias Pleroma.{User, Repo}
   6
   7   @behaviour :cowboy_websocket_handler
   8
   9   @streams [
  10     "public",
  11     "public:local",
  12     "public:media",
  13     "public:local:media",
  14     "user",
  15     "direct",
  16     "list",
  17     "hashtag"
  18   ]
  19   @anonymous_streams ["public", "public:local", "hashtag"]
  20
  21   # Handled by periodic keepalive in Pleroma.Web.Streamer.
  22   @timeout :infinity
  23
  24   def init(_type, _req, _opts) do
  25     {:upgrade, :protocol, :cowboy_websocket}
  26   end
  27
  28   def websocket_init(_type, req, _opts) do
  29     with {qs, req} <- :cowboy_req.qs(req),
  30          params <- :cow_qs.parse_qs(qs),
  31          access_token <- List.keyfind(params, "access_token", 0),
  32          {_, stream} <- List.keyfind(params, "stream", 0),
  33          {:ok, user} <- allow_request(stream, access_token),
  34          topic when is_binary(topic) <- expand_topic(stream, params) do
  35       send(self(), :subscribe)
  36       {:ok, req, %{user: user, topic: topic}, @timeout}
  37     else
  38       {:error, code} ->
  39         Logger.debug("#{__MODULE__} denied connection: #{inspect(code)} - #{inspect(req)}")
  40         {:ok, req} = :cowboy_req.reply(code, req)
  41         {:shutdown, req}
  42
  43       error ->
  44         Logger.debug("#{__MODULE__} denied connection: #{inspect(error)} - #{inspect(req)}")
  45         {:shutdown, req}
  46     end
  47   end
  48
  49   # We never receive messages.
  50   def websocket_handle(_frame, req, state) do
  51     {:ok, req, state}
  52   end
  53
  54   def websocket_info(:subscribe, req, state) do
  55     Logger.debug(
  56       "#{__MODULE__} accepted websocket connection for user #{
  57         (state.user || %{id: "anonymous"}).id
  58       }, topic #{state.topic}"
  59     )
  60
  61     Pleroma.Web.Streamer.add_socket(state.topic, streamer_socket(state))
  62     {:ok, req, state}
  63   end
  64
  65   def websocket_info({:text, message}, req, state) do
  66     {:reply, {:text, message}, req, state}
  67   end
  68
  69   def websocket_terminate(reason, _req, state) do
  70     Logger.debug(
  71       "#{__MODULE__} terminating websocket connection for user #{
  72         (state.user || %{id: "anonymous"}).id
  73       }, topic #{state.topic || "?"}: #{inspect(reason)}"
  74     )
  75
  76     Pleroma.Web.Streamer.remove_socket(state.topic, streamer_socket(state))
  77     :ok
  78   end
  79
  80   # Public streams without authentication.
  81   defp allow_request(stream, nil) when stream in @anonymous_streams do
  82     {:ok, nil}
  83   end
  84
  85   # Authenticated streams.
  86   defp allow_request(stream, {"access_token", access_token}) when stream in @streams do
  87     with %Token{user_id: user_id} <- Repo.get_by(Token, token: access_token),
  88          user = %User{} <- Repo.get(User, user_id) do
  89       {:ok, user}
  90     else
  91       _ -> {:error, 403}
  92     end
  93   end
  94
  95   # Not authenticated.
  96   defp allow_request(stream, _) when stream in @streams, do: {:error, 403}
  97
  98   # No matching stream.
  99   defp allow_request(_, _), do: {:error, 404}
 100
 101   defp expand_topic("hashtag", params) do
 102     case List.keyfind(params, "tag", 0) do
 103       {_, tag} -> "hashtag:#{tag}"
 104       _ -> nil
 105     end
 106   end
 107
 108   defp expand_topic("list", params) do
 109     case List.keyfind(params, "list", 0) do
 110       {_, list} -> "list:#{list}"
 111       _ -> nil
 112     end
 113   end
 114
 115   defp expand_topic(topic, _), do: topic
 116
 117   defp streamer_socket(state) do
 118     %{transport_pid: self(), assigns: state}
 119   end
 120 end