git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/websocket_handler.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.WebsocketHandler do
   6   require Logger
   7
   8   alias Pleroma.Repo
   9   alias Pleroma.User
  10   alias Pleroma.Web.OAuth.Token
  11
  12   @behaviour :cowboy_websocket
  13
  14   @streams [
  15     "public",
  16     "public:local",
  17     "public:media",
  18     "public:local:media",
  19     "user",
  20     "user:notification",
  21     "direct",
  22     "list",
  23     "hashtag"
  24   ]
  25   @anonymous_streams ["public", "public:local", "hashtag"]
  26
  27   # Handled by periodic keepalive in Pleroma.Web.Streamer.
  28   @timeout :infinity
  29
  30   def init(%{qs: qs} = req, state) do
  31     with params <- :cow_qs.parse_qs(qs),
  32          access_token <- List.keyfind(params, "access_token", 0),
  33          {_, stream} <- List.keyfind(params, "stream", 0),
  34          {:ok, user} <- allow_request(stream, access_token),
  35          topic when is_binary(topic) <- expand_topic(stream, params) do
  36       {:cowboy_websocket, req, %{user: user, topic: topic}, %{idle_timeout: @timeout}}
  37     else
  38       {:error, code} ->
  39         Logger.debug("#{__MODULE__} denied connection: #{inspect(code)} - #{inspect(req)}")
  40         {:ok, req} = :cowboy_req.reply(code, req)
  41         {:ok, req, state}
  42
  43       error ->
  44         Logger.debug("#{__MODULE__} denied connection: #{inspect(error)} - #{inspect(req)}")
  45         {:ok, req} = :cowboy_req.reply(400, req)
  46         {:ok, req, state}
  47     end
  48   end
  49
  50   def websocket_init(state) do
  51     send(self(), :subscribe)
  52     {:ok, state}
  53   end
  54
  55   # We never receive messages.
  56   def websocket_handle(_frame, state) do
  57     {:ok, state}
  58   end
  59
  60   def websocket_info(:subscribe, state) do
  61     Logger.debug(
  62       "#{__MODULE__} accepted websocket connection for user #{
  63         (state.user || %{id: "anonymous"}).id
  64       }, topic #{state.topic}"
  65     )
  66
  67     Pleroma.Web.Streamer.add_socket(state.topic, streamer_socket(state))
  68     {:ok, state}
  69   end
  70
  71   def websocket_info({:text, message}, state) do
  72     {:reply, {:text, message}, state}
  73   end
  74
  75   def terminate(reason, _req, state) do
  76     Logger.debug(
  77       "#{__MODULE__} terminating websocket connection for user #{
  78         (state.user || %{id: "anonymous"}).id
  79       }, topic #{state.topic || "?"}: #{inspect(reason)}"
  80     )
  81
  82     Pleroma.Web.Streamer.remove_socket(state.topic, streamer_socket(state))
  83     :ok
  84   end
  85
  86   # Public streams without authentication.
  87   defp allow_request(stream, nil) when stream in @anonymous_streams do
  88     {:ok, nil}
  89   end
  90
  91   # Authenticated streams.
  92   defp allow_request(stream, {"access_token", access_token}) when stream in @streams do
  93     with %Token{user_id: user_id} <- Repo.get_by(Token, token: access_token),
  94          user = %User{} <- User.get_cached_by_id(user_id) do
  95       {:ok, user}
  96     else
  97       _ -> {:error, 403}
  98     end
  99   end
 100
 101   # Not authenticated.
 102   defp allow_request(stream, _) when stream in @streams, do: {:error, 403}
 103
 104   # No matching stream.
 105   defp allow_request(_, _), do: {:error, 404}
 106
 107   defp expand_topic("hashtag", params) do
 108     case List.keyfind(params, "tag", 0) do
 109       {_, tag} -> "hashtag:#{tag}"
 110       _ -> nil
 111     end
 112   end
 113
 114   defp expand_topic("list", params) do
 115     case List.keyfind(params, "list", 0) do
 116       {_, list} -> "list:#{list}"
 117       _ -> nil
 118     end
 119   end
 120
 121   defp expand_topic(topic, _), do: topic
 122
 123   defp streamer_socket(state) do
 124     %{transport_pid: self(), assigns: state}
 125   end
 126 end