git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.CommonAPI.Utils
  15   alias Pleroma.Web.MastodonAPI.AccountView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17   alias Pleroma.Web.MediaProxy
  18
  19   # TODO: Add cached version.
  20   defp get_replied_to_activities(activities) do
  21     activities
  22     |> Enum.map(fn
  23       %{data: %{"type" => "Create", "object" => object}} ->
  24         object = Object.normalize(object)
  25         object.data["inReplyTo"] != "" && object.data["inReplyTo"]
  26
  27       _ ->
  28         nil
  29     end)
  30     |> Enum.filter(& &1)
  31     |> Activity.create_by_object_ap_id()
  32     |> Repo.all()
  33     |> Enum.reduce(%{}, fn activity, acc ->
  34       object = Object.normalize(activity.data["object"])
  35       Map.put(acc, object.data["id"], activity)
  36     end)
  37   end
  38
  39   defp get_user(ap_id) do
  40     cond do
  41       user = User.get_cached_by_ap_id(ap_id) ->
  42         user
  43
  44       user = User.get_by_guessed_nickname(ap_id) ->
  45         user
  46
  47       true ->
  48         User.error_user(ap_id)
  49     end
  50   end
  51
  52   defp get_context_id(%{data: %{"context_id" => context_id}}) when not is_nil(context_id),
  53     do: context_id
  54
  55   defp get_context_id(%{data: %{"context" => context}}) when is_binary(context),
  56     do: Utils.context_to_conversation_id(context)
  57
  58   defp get_context_id(_), do: nil
  59
  60   defp reblogged?(activity, user) do
  61     object = Object.normalize(activity) || %{}
  62     present?(user && user.ap_id in (object.data["announcements"] || []))
  63   end
  64
  65   def render("index.json", opts) do
  66     replied_to_activities = get_replied_to_activities(opts.activities)
  67
  68     opts.activities
  69     |> safe_render_many(
  70       StatusView,
  71       "status.json",
  72       Map.put(opts, :replied_to_activities, replied_to_activities)
  73     )
  74   end
  75
  76   def render(
  77         "status.json",
  78         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  79       ) do
  80     user = get_user(activity.data["actor"])
  81     created_at = Utils.to_masto_date(activity.data["published"])
  82
  83     reblogged_activity = Activity.get_create_by_object_ap_id(object)
  84     reblogged = render("status.json", Map.put(opts, :activity, reblogged_activity))
  85
  86     activity_object = Object.normalize(activity)
  87     favorited = opts[:for] && opts[:for].ap_id in (activity_object.data["likes"] || [])
  88     bookmarked = opts[:for] && activity_object.data["id"] in opts[:for].bookmarks
  89
  90     mentions =
  91       activity.recipients
  92       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  93       |> Enum.filter(& &1)
  94       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  95
  96     %{
  97       id: to_string(activity.id),
  98       uri: object,
  99       url: object,
 100       account: AccountView.render("account.json", %{user: user}),
 101       in_reply_to_id: nil,
 102       in_reply_to_account_id: nil,
 103       reblog: reblogged,
 104       content: reblogged[:content] || "",
 105       created_at: created_at,
 106       reblogs_count: 0,
 107       replies_count: 0,
 108       favourites_count: 0,
 109       reblogged: reblogged?(reblogged_activity, opts[:for]),
 110       favourited: present?(favorited),
 111       bookmarked: present?(bookmarked),
 112       muted: false,
 113       pinned: pinned?(activity, user),
 114       sensitive: false,
 115       spoiler_text: "",
 116       visibility: "public",
 117       media_attachments: reblogged[:media_attachments] || [],
 118       mentions: mentions,
 119       tags: reblogged[:tags] || [],
 120       application: %{
 121         name: "Web",
 122         website: nil
 123       },
 124       language: nil,
 125       emojis: [],
 126       pleroma: %{
 127         local: activity.local
 128       }
 129     }
 130   end
 131
 132   def render("status.json", %{activity: %{data: %{"object" => _object}} = activity} = opts) do
 133     object = Object.normalize(activity)
 134
 135     user = get_user(activity.data["actor"])
 136
 137     like_count = object.data["like_count"] || 0
 138     announcement_count = object.data["announcement_count"] || 0
 139
 140     tags = object.data["tag"] || []
 141     sensitive = object.data["sensitive"] || Enum.member?(tags, "nsfw")
 142
 143     mentions =
 144       activity.recipients
 145       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 146       |> Enum.filter(& &1)
 147       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 148
 149     favorited = opts[:for] && opts[:for].ap_id in (object.data["likes"] || [])
 150
 151     bookmarked = opts[:for] && object.data["id"] in opts[:for].bookmarks
 152
 153     attachment_data = object.data["attachment"] || []
 154     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 155
 156     created_at = Utils.to_masto_date(object.data["published"])
 157
 158     reply_to = get_reply_to(activity, opts)
 159
 160     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 161
 162     content =
 163       object
 164       |> render_content()
 165
 166     content_html =
 167       content
 168       |> HTML.get_cached_scrubbed_html_for_activity(
 169         User.html_filter_policy(opts[:for]),
 170         activity,
 171         "mastoapi:content"
 172       )
 173
 174     content_plaintext =
 175       content
 176       |> HTML.get_cached_stripped_html_for_activity(
 177         activity,
 178         "mastoapi:content"
 179       )
 180
 181     summary = object.data["summary"] || ""
 182
 183     summary_html =
 184       summary
 185       |> HTML.get_cached_scrubbed_html_for_activity(
 186         User.html_filter_policy(opts[:for]),
 187         activity,
 188         "mastoapi:summary"
 189       )
 190
 191     summary_plaintext =
 192       summary
 193       |> HTML.get_cached_stripped_html_for_activity(
 194         activity,
 195         "mastoapi:summary"
 196       )
 197
 198     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 199
 200     url =
 201       if user.local do
 202         Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 203       else
 204         object.data["external_url"] || object.data["id"]
 205       end
 206
 207     %{
 208       id: to_string(activity.id),
 209       uri: object.data["id"],
 210       url: url,
 211       account: AccountView.render("account.json", %{user: user}),
 212       in_reply_to_id: reply_to && to_string(reply_to.id),
 213       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 214       reblog: nil,
 215       card: card,
 216       content: content_html,
 217       created_at: created_at,
 218       reblogs_count: announcement_count,
 219       replies_count: object.data["repliesCount"] || 0,
 220       favourites_count: like_count,
 221       reblogged: reblogged?(activity, opts[:for]),
 222       favourited: present?(favorited),
 223       bookmarked: present?(bookmarked),
 224       muted: CommonAPI.thread_muted?(user, activity) || User.mutes?(opts[:for], user),
 225       pinned: pinned?(activity, user),
 226       sensitive: sensitive,
 227       spoiler_text: summary_html,
 228       visibility: get_visibility(object),
 229       media_attachments: attachments,
 230       mentions: mentions,
 231       tags: build_tags(tags),
 232       application: %{
 233         name: "Web",
 234         website: nil
 235       },
 236       language: nil,
 237       emojis: build_emojis(object.data["emoji"]),
 238       pleroma: %{
 239         local: activity.local,
 240         conversation_id: get_context_id(activity),
 241         in_reply_to_account_acct: reply_to_user && reply_to_user.nickname,
 242         content: %{"text/plain" => content_plaintext},
 243         spoiler_text: %{"text/plain" => summary_plaintext}
 244       }
 245     }
 246   end
 247
 248   def render("status.json", _) do
 249     nil
 250   end
 251
 252   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 253     page_url_data = URI.parse(page_url)
 254
 255     page_url_data =
 256       if rich_media[:url] != nil do
 257         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 258       else
 259         page_url_data
 260       end
 261
 262     page_url = page_url_data |> to_string
 263
 264     image_url =
 265       if rich_media[:image] != nil do
 266         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 267         |> to_string
 268       else
 269         nil
 270       end
 271
 272     site_name = rich_media[:site_name] || page_url_data.host
 273
 274     %{
 275       type: "link",
 276       provider_name: site_name,
 277       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 278       url: page_url,
 279       image: image_url |> MediaProxy.url(),
 280       title: rich_media[:title],
 281       description: rich_media[:description],
 282       pleroma: %{
 283         opengraph: rich_media
 284       }
 285     }
 286   end
 287
 288   def render("card.json", _) do
 289     nil
 290   end
 291
 292   def render("attachment.json", %{attachment: attachment}) do
 293     [attachment_url | _] = attachment["url"]
 294     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 295     href = attachment_url["href"] |> MediaProxy.url()
 296
 297     type =
 298       cond do
 299         String.contains?(media_type, "image") -> "image"
 300         String.contains?(media_type, "video") -> "video"
 301         String.contains?(media_type, "audio") -> "audio"
 302         true -> "unknown"
 303       end
 304
 305     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 306
 307     %{
 308       id: to_string(attachment["id"] || hash_id),
 309       url: href,
 310       remote_url: href,
 311       preview_url: href,
 312       text_url: href,
 313       type: type,
 314       description: attachment["name"],
 315       pleroma: %{mime_type: media_type}
 316     }
 317   end
 318
 319   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 320     object = Object.normalize(activity.data["object"])
 321
 322     with nil <- replied_to_activities[object.data["inReplyTo"]] do
 323       # If user didn't participate in the thread
 324       Activity.get_in_reply_to_activity(activity)
 325     end
 326   end
 327
 328   def get_reply_to(%{data: %{"object" => _object}} = activity, _) do
 329     object = Object.normalize(activity)
 330
 331     if object.data["inReplyTo"] && object.data["inReplyTo"] != "" do
 332       Activity.get_create_by_object_ap_id(object.data["inReplyTo"])
 333     else
 334       nil
 335     end
 336   end
 337
 338   def get_visibility(object) do
 339     public = "https://www.w3.org/ns/activitystreams#Public"
 340     to = object.data["to"] || []
 341     cc = object.data["cc"] || []
 342
 343     cond do
 344       public in to ->
 345         "public"
 346
 347       public in cc ->
 348         "unlisted"
 349
 350       # this should use the sql for the object's activity
 351       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 352         "private"
 353
 354       length(cc) > 0 ->
 355         "private"
 356
 357       true ->
 358         "direct"
 359     end
 360   end
 361
 362   def render_content(%{data: %{"type" => "Video"}} = object) do
 363     with name when not is_nil(name) and name != "" <- object.data["name"] do
 364       "<p><a href=\"#{object.data["id"]}\">#{name}</a></p>#{object.data["content"]}"
 365     else
 366       _ -> object.data["content"] || ""
 367     end
 368   end
 369
 370   def render_content(%{data: %{"type" => object_type}} = object)
 371       when object_type in ["Article", "Page"] do
 372     with summary when not is_nil(summary) and summary != "" <- object.data["name"],
 373          url when is_bitstring(url) <- object.data["url"] do
 374       "<p><a href=\"#{url}\">#{summary}</a></p>#{object.data["content"]}"
 375     else
 376       _ -> object.data["content"] || ""
 377     end
 378   end
 379
 380   def render_content(object), do: object.data["content"] || ""
 381
 382   @doc """
 383   Builds a dictionary tags.
 384
 385   ## Examples
 386
 387   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 388   [{"name": "fediverse", "url": "/tag/fediverse"},
 389    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 390
 391   """
 392   @spec build_tags(list(any())) :: list(map())
 393   def build_tags(object_tags) when is_list(object_tags) do
 394     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 395
 396     Enum.reduce(object_tags, [], fn tag, tags ->
 397       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 398     end)
 399   end
 400
 401   def build_tags(_), do: []
 402
 403   @doc """
 404   Builds list emojis.
 405
 406   Arguments: `nil` or list tuple of name and url.
 407
 408   Returns list emojis.
 409
 410   ## Examples
 411
 412   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 413   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 414
 415   """
 416   @spec build_emojis(nil | list(tuple())) :: list(map())
 417   def build_emojis(nil), do: []
 418
 419   def build_emojis(emojis) do
 420     emojis
 421     |> Enum.map(fn {name, url} ->
 422       name = HTML.strip_tags(name)
 423
 424       url =
 425         url
 426         |> HTML.strip_tags()
 427         |> MediaProxy.url()
 428
 429       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 430     end)
 431   end
 432
 433   defp present?(nil), do: false
 434   defp present?(false), do: false
 435   defp present?(_), do: true
 436
 437   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 438     do: id in pinned_activities
 439 end