git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Repo
  11   alias Pleroma.User
  12   alias Pleroma.Web.CommonAPI.Utils
  13   alias Pleroma.Web.MastodonAPI.AccountView
  14   alias Pleroma.Web.MastodonAPI.StatusView
  15   alias Pleroma.Web.MediaProxy
  16
  17   # TODO: Add cached version.
  18   defp get_replied_to_activities(activities) do
  19     activities
  20     |> Enum.map(fn
  21       %{data: %{"type" => "Create", "object" => %{"inReplyTo" => in_reply_to}}} ->
  22         in_reply_to != "" && in_reply_to
  23
  24       _ ->
  25         nil
  26     end)
  27     |> Enum.filter(& &1)
  28     |> Activity.create_by_object_ap_id()
  29     |> Repo.all()
  30     |> Enum.reduce(%{}, fn activity, acc ->
  31       Map.put(acc, activity.data["object"]["id"], activity)
  32     end)
  33   end
  34
  35   defp get_user(ap_id) do
  36     cond do
  37       user = User.get_cached_by_ap_id(ap_id) ->
  38         user
  39
  40       user = User.get_by_guessed_nickname(ap_id) ->
  41         user
  42
  43       true ->
  44         User.error_user(ap_id)
  45     end
  46   end
  47
  48   def render("index.json", opts) do
  49     replied_to_activities = get_replied_to_activities(opts.activities)
  50
  51     opts.activities
  52     |> safe_render_many(
  53       StatusView,
  54       "status.json",
  55       Map.put(opts, :replied_to_activities, replied_to_activities)
  56     )
  57   end
  58
  59   def render(
  60         "status.json",
  61         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  62       ) do
  63     user = get_user(activity.data["actor"])
  64     created_at = Utils.to_masto_date(activity.data["published"])
  65
  66     reblogged = Activity.get_create_by_object_ap_id(object)
  67     reblogged = render("status.json", Map.put(opts, :activity, reblogged))
  68
  69     mentions =
  70       activity.recipients
  71       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  72       |> Enum.filter(& &1)
  73       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  74
  75     %{
  76       id: to_string(activity.id),
  77       uri: object,
  78       url: object,
  79       account: AccountView.render("account.json", %{user: user}),
  80       in_reply_to_id: nil,
  81       in_reply_to_account_id: nil,
  82       reblog: reblogged,
  83       content: reblogged[:content] || "",
  84       created_at: created_at,
  85       reblogs_count: 0,
  86       replies_count: 0,
  87       favourites_count: 0,
  88       reblogged: false,
  89       favourited: false,
  90       bookmarked: false,
  91       muted: false,
  92       pinned: pinned?(activity, user),
  93       sensitive: false,
  94       spoiler_text: "",
  95       visibility: "public",
  96       media_attachments: reblogged[:media_attachments] || [],
  97       mentions: mentions,
  98       tags: reblogged[:tags] || [],
  99       application: %{
 100         name: "Web",
 101         website: nil
 102       },
 103       language: nil,
 104       emojis: []
 105     }
 106   end
 107
 108   def render("status.json", %{activity: %{data: %{"object" => object}} = activity} = opts) do
 109     user = get_user(activity.data["actor"])
 110
 111     like_count = object["like_count"] || 0
 112     announcement_count = object["announcement_count"] || 0
 113
 114     tags = object["tag"] || []
 115     sensitive = object["sensitive"] || Enum.member?(tags, "nsfw")
 116
 117     mentions =
 118       activity.recipients
 119       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 120       |> Enum.filter(& &1)
 121       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 122
 123     repeated = opts[:for] && opts[:for].ap_id in (object["announcements"] || [])
 124     favorited = opts[:for] && opts[:for].ap_id in (object["likes"] || [])
 125     bookmarked = opts[:for] && object["id"] in opts[:for].bookmarks
 126
 127     attachment_data = object["attachment"] || []
 128     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 129
 130     created_at = Utils.to_masto_date(object["published"])
 131
 132     reply_to = get_reply_to(activity, opts)
 133     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 134
 135     content =
 136       object
 137       |> render_content()
 138       |> HTML.get_cached_scrubbed_html_for_object(
 139         User.html_filter_policy(opts[:for]),
 140         activity,
 141         __MODULE__
 142       )
 143
 144     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 145
 146     %{
 147       id: to_string(activity.id),
 148       uri: object["id"],
 149       url: object["external_url"] || object["id"],
 150       account: AccountView.render("account.json", %{user: user}),
 151       in_reply_to_id: reply_to && to_string(reply_to.id),
 152       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 153       reblog: nil,
 154       card: card,
 155       content: content,
 156       created_at: created_at,
 157       reblogs_count: announcement_count,
 158       replies_count: 0,
 159       favourites_count: like_count,
 160       reblogged: present?(repeated),
 161       favourited: present?(favorited),
 162       bookmarked: present?(bookmarked),
 163       muted: false,
 164       pinned: pinned?(activity, user),
 165       sensitive: sensitive,
 166       spoiler_text: object["summary"] || "",
 167       visibility: get_visibility(object),
 168       media_attachments: attachments |> Enum.take(4),
 169       mentions: mentions,
 170       tags: build_tags(tags),
 171       application: %{
 172         name: "Web",
 173         website: nil
 174       },
 175       language: nil,
 176       emojis: build_emojis(activity.data["object"]["emoji"])
 177     }
 178   end
 179
 180   def render("status.json", _) do
 181     nil
 182   end
 183
 184   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 185     page_url_data = URI.parse(page_url)
 186
 187     page_url_data =
 188       if rich_media[:url] != nil do
 189         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 190       else
 191         page_url_data
 192       end
 193
 194     page_url = page_url_data |> to_string
 195
 196     image_url =
 197       if rich_media[:image] != nil do
 198         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 199         |> to_string
 200       else
 201         nil
 202       end
 203
 204     site_name = rich_media[:site_name] || page_url_data.host
 205
 206     %{
 207       type: "link",
 208       provider_name: site_name,
 209       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 210       url: page_url,
 211       image: image_url |> MediaProxy.url(),
 212       title: rich_media[:title],
 213       description: rich_media[:description],
 214       pleroma: %{
 215         opengraph: rich_media
 216       }
 217     }
 218   end
 219
 220   def render("card.json", _) do
 221     nil
 222   end
 223
 224   def render("attachment.json", %{attachment: attachment}) do
 225     [attachment_url | _] = attachment["url"]
 226     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 227     href = attachment_url["href"] |> MediaProxy.url()
 228
 229     type =
 230       cond do
 231         String.contains?(media_type, "image") -> "image"
 232         String.contains?(media_type, "video") -> "video"
 233         String.contains?(media_type, "audio") -> "audio"
 234         true -> "unknown"
 235       end
 236
 237     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 238
 239     %{
 240       id: to_string(attachment["id"] || hash_id),
 241       url: href,
 242       remote_url: href,
 243       preview_url: href,
 244       text_url: href,
 245       type: type,
 246       description: attachment["name"]
 247     }
 248   end
 249
 250   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 251     _id = activity.data["object"]["inReplyTo"]
 252     replied_to_activities[activity.data["object"]["inReplyTo"]]
 253   end
 254
 255   def get_reply_to(%{data: %{"object" => object}}, _) do
 256     if object["inReplyTo"] && object["inReplyTo"] != "" do
 257       Activity.get_create_by_object_ap_id(object["inReplyTo"])
 258     else
 259       nil
 260     end
 261   end
 262
 263   def get_visibility(object) do
 264     public = "https://www.w3.org/ns/activitystreams#Public"
 265     to = object["to"] || []
 266     cc = object["cc"] || []
 267
 268     cond do
 269       public in to ->
 270         "public"
 271
 272       public in cc ->
 273         "unlisted"
 274
 275       # this should use the sql for the object's activity
 276       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 277         "private"
 278
 279       length(cc) > 0 ->
 280         "private"
 281
 282       true ->
 283         "direct"
 284     end
 285   end
 286
 287   def render_content(%{"type" => "Video"} = object) do
 288     with name when not is_nil(name) and name != "" <- object["name"] do
 289       "<p><a href=\"#{object["id"]}\">#{name}</a></p>#{object["content"]}"
 290     else
 291       _ -> object["content"] || ""
 292     end
 293   end
 294
 295   def render_content(%{"type" => object_type} = object)
 296       when object_type in ["Article", "Page"] do
 297     with summary when not is_nil(summary) and summary != "" <- object["name"],
 298          url when is_bitstring(url) <- object["url"] do
 299       "<p><a href=\"#{url}\">#{summary}</a></p>#{object["content"]}"
 300     else
 301       _ -> object["content"] || ""
 302     end
 303   end
 304
 305   def render_content(object), do: object["content"] || ""
 306
 307   @doc """
 308   Builds a dictionary tags.
 309
 310   ## Examples
 311
 312   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 313   [{"name": "fediverse", "url": "/tag/fediverse"},
 314    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 315
 316   """
 317   @spec build_tags(list(any())) :: list(map())
 318   def build_tags(object_tags) when is_list(object_tags) do
 319     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 320
 321     Enum.reduce(object_tags, [], fn tag, tags ->
 322       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 323     end)
 324   end
 325
 326   def build_tags(_), do: []
 327
 328   @doc """
 329   Builds list emojis.
 330
 331   Arguments: `nil` or list tuple of name and url.
 332
 333   Returns list emojis.
 334
 335   ## Examples
 336
 337   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 338   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 339
 340   """
 341   @spec build_emojis(nil | list(tuple())) :: list(map())
 342   def build_emojis(nil), do: []
 343
 344   def build_emojis(emojis) do
 345     emojis
 346     |> Enum.map(fn {name, url} ->
 347       name = HTML.strip_tags(name)
 348
 349       url =
 350         url
 351         |> HTML.strip_tags()
 352         |> MediaProxy.url()
 353
 354       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 355     end)
 356   end
 357
 358   defp present?(nil), do: false
 359   defp present?(false), do: false
 360   defp present?(_), do: true
 361
 362   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 363     do: id in pinned_activities
 364 end