git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.CommonAPI.Utils
  15   alias Pleroma.Web.MastodonAPI.AccountView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17   alias Pleroma.Web.MediaProxy
  18
  19   # TODO: Add cached version.
  20   defp get_replied_to_activities(activities) do
  21     activities
  22     |> Enum.map(fn
  23       %{data: %{"type" => "Create", "object" => object}} ->
  24         object = Object.normalize(object)
  25         object.data["inReplyTo"] != "" && object.data["inReplyTo"]
  26
  27       _ ->
  28         nil
  29     end)
  30     |> Enum.filter(& &1)
  31     |> Activity.create_by_object_ap_id()
  32     |> Repo.all()
  33     |> Enum.reduce(%{}, fn activity, acc ->
  34       object = Object.normalize(activity)
  35       Map.put(acc, object.data["id"], activity)
  36     end)
  37   end
  38
  39   defp get_user(ap_id) do
  40     cond do
  41       user = User.get_cached_by_ap_id(ap_id) ->
  42         user
  43
  44       user = User.get_by_guessed_nickname(ap_id) ->
  45         user
  46
  47       true ->
  48         User.error_user(ap_id)
  49     end
  50   end
  51
  52   defp get_context_id(%{data: %{"context_id" => context_id}}) when not is_nil(context_id),
  53     do: context_id
  54
  55   defp get_context_id(%{data: %{"context" => context}}) when is_binary(context),
  56     do: Utils.context_to_conversation_id(context)
  57
  58   defp get_context_id(_), do: nil
  59
  60   defp reblogged?(activity, user) do
  61     object = Object.normalize(activity) || %{}
  62     present?(user && user.ap_id in (object.data["announcements"] || []))
  63   end
  64
  65   def render("index.json", opts) do
  66     replied_to_activities = get_replied_to_activities(opts.activities)
  67
  68     opts.activities
  69     |> safe_render_many(
  70       StatusView,
  71       "status.json",
  72       Map.put(opts, :replied_to_activities, replied_to_activities)
  73     )
  74   end
  75
  76   def render(
  77         "status.json",
  78         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  79       ) do
  80     user = get_user(activity.data["actor"])
  81     created_at = Utils.to_masto_date(activity.data["published"])
  82
  83     reblogged_activity = Activity.get_create_by_object_ap_id(object)
  84     reblogged = render("status.json", Map.put(opts, :activity, reblogged_activity))
  85
  86     activity_object = Object.normalize(activity)
  87     favorited = opts[:for] && opts[:for].ap_id in (activity_object.data["likes"] || [])
  88
  89     bookmarked =
  90       opts[:for] && Ecto.assoc_loaded?(opts[:for].bookmarks) &&
  91         Enum.any?(opts[:for].bookmarks, fn b ->
  92           b.activity_id == activity.id or b.activity.data["object"]["id"] == object
  93         end)
  94
  95     mentions =
  96       activity.recipients
  97       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  98       |> Enum.filter(& &1)
  99       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 100
 101     %{
 102       id: to_string(activity.id),
 103       uri: object,
 104       url: object,
 105       account: AccountView.render("account.json", %{user: user}),
 106       in_reply_to_id: nil,
 107       in_reply_to_account_id: nil,
 108       reblog: reblogged,
 109       content: reblogged[:content] || "",
 110       created_at: created_at,
 111       reblogs_count: 0,
 112       replies_count: 0,
 113       favourites_count: 0,
 114       reblogged: reblogged?(reblogged_activity, opts[:for]),
 115       favourited: present?(favorited),
 116       bookmarked: present?(bookmarked),
 117       muted: false,
 118       pinned: pinned?(activity, user),
 119       sensitive: false,
 120       spoiler_text: "",
 121       visibility: "public",
 122       media_attachments: reblogged[:media_attachments] || [],
 123       mentions: mentions,
 124       tags: reblogged[:tags] || [],
 125       application: %{
 126         name: "Web",
 127         website: nil
 128       },
 129       language: nil,
 130       emojis: [],
 131       pleroma: %{
 132         local: activity.local
 133       }
 134     }
 135   end
 136
 137   def render("status.json", %{activity: %{data: %{"object" => _object}} = activity} = opts) do
 138     object = Object.normalize(activity)
 139
 140     user = get_user(activity.data["actor"])
 141
 142     like_count = object.data["like_count"] || 0
 143     announcement_count = object.data["announcement_count"] || 0
 144
 145     tags = object.data["tag"] || []
 146     sensitive = object.data["sensitive"] || Enum.member?(tags, "nsfw")
 147
 148     mentions =
 149       activity.recipients
 150       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 151       |> Enum.filter(& &1)
 152       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 153
 154     favorited = opts[:for] && opts[:for].ap_id in (object.data["likes"] || [])
 155
 156     bookmarked =
 157       opts[:for] && Ecto.assoc_loaded?(opts[:for].bookmarks) &&
 158         Enum.any?(opts[:for].bookmarks, fn b ->
 159           b.activity_id == activity.id
 160         end)
 161
 162     attachment_data = object.data["attachment"] || []
 163     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 164
 165     created_at = Utils.to_masto_date(object.data["published"])
 166
 167     reply_to = get_reply_to(activity, opts)
 168
 169     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 170
 171     content =
 172       object
 173       |> render_content()
 174
 175     content_html =
 176       content
 177       |> HTML.get_cached_scrubbed_html_for_activity(
 178         User.html_filter_policy(opts[:for]),
 179         activity,
 180         "mastoapi:content"
 181       )
 182
 183     content_plaintext =
 184       content
 185       |> HTML.get_cached_stripped_html_for_activity(
 186         activity,
 187         "mastoapi:content"
 188       )
 189
 190     summary = object.data["summary"] || ""
 191
 192     summary_html =
 193       summary
 194       |> HTML.get_cached_scrubbed_html_for_activity(
 195         User.html_filter_policy(opts[:for]),
 196         activity,
 197         "mastoapi:summary"
 198       )
 199
 200     summary_plaintext =
 201       summary
 202       |> HTML.get_cached_stripped_html_for_activity(
 203         activity,
 204         "mastoapi:summary"
 205       )
 206
 207     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 208
 209     url =
 210       if user.local do
 211         Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 212       else
 213         object.data["external_url"] || object.data["id"]
 214       end
 215
 216     %{
 217       id: to_string(activity.id),
 218       uri: object.data["id"],
 219       url: url,
 220       account: AccountView.render("account.json", %{user: user}),
 221       in_reply_to_id: reply_to && to_string(reply_to.id),
 222       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 223       reblog: nil,
 224       card: card,
 225       content: content_html,
 226       created_at: created_at,
 227       reblogs_count: announcement_count,
 228       replies_count: object.data["repliesCount"] || 0,
 229       favourites_count: like_count,
 230       reblogged: reblogged?(activity, opts[:for]),
 231       favourited: present?(favorited),
 232       bookmarked: present?(bookmarked),
 233       muted: CommonAPI.thread_muted?(user, activity) || User.mutes?(opts[:for], user),
 234       pinned: pinned?(activity, user),
 235       sensitive: sensitive,
 236       spoiler_text: summary_html,
 237       visibility: get_visibility(object),
 238       media_attachments: attachments,
 239       mentions: mentions,
 240       tags: build_tags(tags),
 241       application: %{
 242         name: "Web",
 243         website: nil
 244       },
 245       language: nil,
 246       emojis: build_emojis(object.data["emoji"]),
 247       pleroma: %{
 248         local: activity.local,
 249         conversation_id: get_context_id(activity),
 250         in_reply_to_account_acct: reply_to_user && reply_to_user.nickname,
 251         content: %{"text/plain" => content_plaintext},
 252         spoiler_text: %{"text/plain" => summary_plaintext}
 253       }
 254     }
 255   end
 256
 257   def render("status.json", _) do
 258     nil
 259   end
 260
 261   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 262     page_url_data = URI.parse(page_url)
 263
 264     page_url_data =
 265       if rich_media[:url] != nil do
 266         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 267       else
 268         page_url_data
 269       end
 270
 271     page_url = page_url_data |> to_string
 272
 273     image_url =
 274       if rich_media[:image] != nil do
 275         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 276         |> to_string
 277       else
 278         nil
 279       end
 280
 281     site_name = rich_media[:site_name] || page_url_data.host
 282
 283     %{
 284       type: "link",
 285       provider_name: site_name,
 286       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 287       url: page_url,
 288       image: image_url |> MediaProxy.url(),
 289       title: rich_media[:title],
 290       description: rich_media[:description],
 291       pleroma: %{
 292         opengraph: rich_media
 293       }
 294     }
 295   end
 296
 297   def render("card.json", _) do
 298     nil
 299   end
 300
 301   def render("attachment.json", %{attachment: attachment}) do
 302     [attachment_url | _] = attachment["url"]
 303     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 304     href = attachment_url["href"] |> MediaProxy.url()
 305
 306     type =
 307       cond do
 308         String.contains?(media_type, "image") -> "image"
 309         String.contains?(media_type, "video") -> "video"
 310         String.contains?(media_type, "audio") -> "audio"
 311         true -> "unknown"
 312       end
 313
 314     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 315
 316     %{
 317       id: to_string(attachment["id"] || hash_id),
 318       url: href,
 319       remote_url: href,
 320       preview_url: href,
 321       text_url: href,
 322       type: type,
 323       description: attachment["name"],
 324       pleroma: %{mime_type: media_type}
 325     }
 326   end
 327
 328   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 329     object = Object.normalize(activity)
 330
 331     with nil <- replied_to_activities[object.data["inReplyTo"]] do
 332       # If user didn't participate in the thread
 333       Activity.get_in_reply_to_activity(activity)
 334     end
 335   end
 336
 337   def get_reply_to(%{data: %{"object" => _object}} = activity, _) do
 338     object = Object.normalize(activity)
 339
 340     if object.data["inReplyTo"] && object.data["inReplyTo"] != "" do
 341       Activity.get_create_by_object_ap_id(object.data["inReplyTo"])
 342     else
 343       nil
 344     end
 345   end
 346
 347   def get_visibility(object) do
 348     public = "https://www.w3.org/ns/activitystreams#Public"
 349     to = object.data["to"] || []
 350     cc = object.data["cc"] || []
 351
 352     cond do
 353       public in to ->
 354         "public"
 355
 356       public in cc ->
 357         "unlisted"
 358
 359       # this should use the sql for the object's activity
 360       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 361         "private"
 362
 363       length(cc) > 0 ->
 364         "private"
 365
 366       true ->
 367         "direct"
 368     end
 369   end
 370
 371   def render_content(%{data: %{"type" => "Video"}} = object) do
 372     with name when not is_nil(name) and name != "" <- object.data["name"] do
 373       "<p><a href=\"#{object.data["id"]}\">#{name}</a></p>#{object.data["content"]}"
 374     else
 375       _ -> object.data["content"] || ""
 376     end
 377   end
 378
 379   def render_content(%{data: %{"type" => object_type}} = object)
 380       when object_type in ["Article", "Page"] do
 381     with summary when not is_nil(summary) and summary != "" <- object.data["name"],
 382          url when is_bitstring(url) <- object.data["url"] do
 383       "<p><a href=\"#{url}\">#{summary}</a></p>#{object.data["content"]}"
 384     else
 385       _ -> object.data["content"] || ""
 386     end
 387   end
 388
 389   def render_content(object), do: object.data["content"] || ""
 390
 391   @doc """
 392   Builds a dictionary tags.
 393
 394   ## Examples
 395
 396   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 397   [{"name": "fediverse", "url": "/tag/fediverse"},
 398    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 399
 400   """
 401   @spec build_tags(list(any())) :: list(map())
 402   def build_tags(object_tags) when is_list(object_tags) do
 403     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 404
 405     Enum.reduce(object_tags, [], fn tag, tags ->
 406       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 407     end)
 408   end
 409
 410   def build_tags(_), do: []
 411
 412   @doc """
 413   Builds list emojis.
 414
 415   Arguments: `nil` or list tuple of name and url.
 416
 417   Returns list emojis.
 418
 419   ## Examples
 420
 421   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 422   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 423
 424   """
 425   @spec build_emojis(nil | list(tuple())) :: list(map())
 426   def build_emojis(nil), do: []
 427
 428   def build_emojis(emojis) do
 429     emojis
 430     |> Enum.map(fn {name, url} ->
 431       name = HTML.strip_tags(name)
 432
 433       url =
 434         url
 435         |> HTML.strip_tags()
 436         |> MediaProxy.url()
 437
 438       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 439     end)
 440   end
 441
 442   defp present?(nil), do: false
 443   defp present?(false), do: false
 444   defp present?(_), do: true
 445
 446   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 447     do: id in pinned_activities
 448 end