git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Repo
  11   alias Pleroma.Object
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.CommonAPI.Utils
  15   alias Pleroma.Web.MastodonAPI.AccountView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17   alias Pleroma.Web.MediaProxy
  18
  19   # TODO: Add cached version.
  20   defp get_replied_to_activities(activities) do
  21     activities
  22     |> Enum.map(fn
  23       %{data: %{"type" => "Create", "object" => object}} ->
  24         object = Object.normalize(object)
  25         object.data["inReplyTo"] != "" && object.data["inReplyTo"]
  26
  27       _ ->
  28         nil
  29     end)
  30     |> Enum.filter(& &1)
  31     |> Activity.create_by_object_ap_id()
  32     |> Repo.all()
  33     |> Enum.reduce(%{}, fn activity, acc ->
  34       object = Object.normalize(activity.data["object"])
  35       Map.put(acc, object.data["id"], activity)
  36     end)
  37   end
  38
  39   defp get_user(ap_id) do
  40     cond do
  41       user = User.get_cached_by_ap_id(ap_id) ->
  42         user
  43
  44       user = User.get_by_guessed_nickname(ap_id) ->
  45         user
  46
  47       true ->
  48         User.error_user(ap_id)
  49     end
  50   end
  51
  52   defp get_context_id(%{data: %{"context_id" => context_id}}) when not is_nil(context_id),
  53     do: context_id
  54
  55   defp get_context_id(%{data: %{"context" => context}}) when is_binary(context),
  56     do: Utils.context_to_conversation_id(context)
  57
  58   defp get_context_id(_), do: nil
  59
  60   defp reblogged?(activity, user) do
  61     object = Object.normalize(activity) || %{}
  62     present?(user && user.ap_id in (object.data["announcements"] || []))
  63   end
  64
  65   def render("index.json", opts) do
  66     replied_to_activities = get_replied_to_activities(opts.activities)
  67
  68     opts.activities
  69     |> safe_render_many(
  70       StatusView,
  71       "status.json",
  72       Map.put(opts, :replied_to_activities, replied_to_activities)
  73     )
  74   end
  75
  76   def render(
  77         "status.json",
  78         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  79       ) do
  80     user = get_user(activity.data["actor"])
  81     created_at = Utils.to_masto_date(activity.data["published"])
  82
  83     reblogged_activity = Activity.get_create_by_object_ap_id(object)
  84     reblogged = render("status.json", Map.put(opts, :activity, reblogged_activity))
  85
  86     mentions =
  87       activity.recipients
  88       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  89       |> Enum.filter(& &1)
  90       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  91
  92     %{
  93       id: to_string(activity.id),
  94       uri: object,
  95       url: object,
  96       account: AccountView.render("account.json", %{user: user}),
  97       in_reply_to_id: nil,
  98       in_reply_to_account_id: nil,
  99       reblog: reblogged,
 100       content: reblogged[:content] || "",
 101       created_at: created_at,
 102       reblogs_count: 0,
 103       replies_count: 0,
 104       favourites_count: 0,
 105       reblogged: reblogged?(reblogged_activity, opts[:for]),
 106       favourited: false,
 107       bookmarked: false,
 108       muted: false,
 109       pinned: pinned?(activity, user),
 110       sensitive: false,
 111       spoiler_text: "",
 112       visibility: "public",
 113       media_attachments: reblogged[:media_attachments] || [],
 114       mentions: mentions,
 115       tags: reblogged[:tags] || [],
 116       application: %{
 117         name: "Web",
 118         website: nil
 119       },
 120       language: nil,
 121       emojis: [],
 122       pleroma: %{
 123         local: activity.local
 124       }
 125     }
 126   end
 127
 128   def render("status.json", %{activity: %{data: %{"object" => object}} = activity} = opts) do
 129     object = Object.normalize(object)
 130
 131     user = get_user(activity.data["actor"])
 132
 133     like_count = object.data["like_count"] || 0
 134     announcement_count = object.data["announcement_count"] || 0
 135
 136     tags = object.data["tag"] || []
 137     sensitive = object.data["sensitive"] || Enum.member?(tags, "nsfw")
 138
 139     mentions =
 140       activity.recipients
 141       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 142       |> Enum.filter(& &1)
 143       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 144
 145     favorited = opts[:for] && opts[:for].ap_id in (object.data["likes"] || [])
 146
 147     bookmarked = opts[:for] && object.data["id"] in opts[:for].bookmarks
 148
 149     attachment_data = object.data["attachment"] || []
 150     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 151
 152     created_at = Utils.to_masto_date(object.data["published"])
 153
 154     reply_to = get_reply_to(activity, opts)
 155
 156     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 157
 158     content =
 159       object
 160       |> render_content()
 161
 162     content_html =
 163       content
 164       |> HTML.get_cached_scrubbed_html_for_activity(
 165         User.html_filter_policy(opts[:for]),
 166         activity,
 167         "mastoapi:content"
 168       )
 169
 170     content_plaintext =
 171       content
 172       |> HTML.get_cached_stripped_html_for_activity(
 173         activity,
 174         "mastoapi:content"
 175       )
 176
 177     summary = object.data["summary"] || ""
 178
 179     summary_html =
 180       summary
 181       |> HTML.get_cached_scrubbed_html_for_activity(
 182         User.html_filter_policy(opts[:for]),
 183         activity,
 184         "mastoapi:summary"
 185       )
 186
 187     summary_plaintext =
 188       summary
 189       |> HTML.get_cached_stripped_html_for_activity(
 190         activity,
 191         "mastoapi:summary"
 192       )
 193
 194     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 195
 196     url =
 197       if user.local do
 198         Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 199       else
 200         object.data["external_url"] || object.data["id"]
 201       end
 202
 203     %{
 204       id: to_string(activity.id),
 205       uri: object.data["id"],
 206       url: url,
 207       account: AccountView.render("account.json", %{user: user}),
 208       in_reply_to_id: reply_to && to_string(reply_to.id),
 209       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 210       reblog: nil,
 211       card: card,
 212       content: content_html,
 213       created_at: created_at,
 214       reblogs_count: announcement_count,
 215       replies_count: object.data["repliesCount"] || 0,
 216       favourites_count: like_count,
 217       reblogged: reblogged?(activity, opts[:for]),
 218       favourited: present?(favorited),
 219       bookmarked: present?(bookmarked),
 220       muted: CommonAPI.thread_muted?(user, activity) || User.mutes?(opts[:for], user),
 221       pinned: pinned?(activity, user),
 222       sensitive: sensitive,
 223       spoiler_text: summary_html,
 224       visibility: get_visibility(object),
 225       media_attachments: attachments,
 226       mentions: mentions,
 227       tags: build_tags(tags),
 228       application: %{
 229         name: "Web",
 230         website: nil
 231       },
 232       language: nil,
 233       emojis: build_emojis(object.data["emoji"]),
 234       pleroma: %{
 235         local: activity.local,
 236         conversation_id: get_context_id(activity),
 237         content: %{"text/plain" => content_plaintext},
 238         spoiler_text: %{"text/plain" => summary_plaintext}
 239       }
 240     }
 241   end
 242
 243   def render("status.json", _) do
 244     nil
 245   end
 246
 247   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 248     page_url_data = URI.parse(page_url)
 249
 250     page_url_data =
 251       if rich_media[:url] != nil do
 252         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 253       else
 254         page_url_data
 255       end
 256
 257     page_url = page_url_data |> to_string
 258
 259     image_url =
 260       if rich_media[:image] != nil do
 261         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 262         |> to_string
 263       else
 264         nil
 265       end
 266
 267     site_name = rich_media[:site_name] || page_url_data.host
 268
 269     %{
 270       type: "link",
 271       provider_name: site_name,
 272       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 273       url: page_url,
 274       image: image_url |> MediaProxy.url(),
 275       title: rich_media[:title],
 276       description: rich_media[:description],
 277       pleroma: %{
 278         opengraph: rich_media
 279       }
 280     }
 281   end
 282
 283   def render("card.json", _) do
 284     nil
 285   end
 286
 287   def render("attachment.json", %{attachment: attachment}) do
 288     [attachment_url | _] = attachment["url"]
 289     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 290     href = attachment_url["href"] |> MediaProxy.url()
 291
 292     type =
 293       cond do
 294         String.contains?(media_type, "image") -> "image"
 295         String.contains?(media_type, "video") -> "video"
 296         String.contains?(media_type, "audio") -> "audio"
 297         true -> "unknown"
 298       end
 299
 300     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 301
 302     %{
 303       id: to_string(attachment["id"] || hash_id),
 304       url: href,
 305       remote_url: href,
 306       preview_url: href,
 307       text_url: href,
 308       type: type,
 309       description: attachment["name"],
 310       pleroma: %{mime_type: media_type}
 311     }
 312   end
 313
 314   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 315     object = Object.normalize(activity.data["object"])
 316
 317     with nil <- replied_to_activities[object.data["inReplyTo"]] do
 318       # If user didn't participate in the thread
 319       Activity.get_in_reply_to_activity(activity)
 320     end
 321   end
 322
 323   def get_reply_to(%{data: %{"object" => object}}, _) do
 324     object = Object.normalize(object)
 325
 326     if object.data["inReplyTo"] && object.data["inReplyTo"] != "" do
 327       Activity.get_create_by_object_ap_id(object.data["inReplyTo"])
 328     else
 329       nil
 330     end
 331   end
 332
 333   def get_visibility(object) do
 334     public = "https://www.w3.org/ns/activitystreams#Public"
 335     to = object.data["to"] || []
 336     cc = object.data["cc"] || []
 337
 338     cond do
 339       public in to ->
 340         "public"
 341
 342       public in cc ->
 343         "unlisted"
 344
 345       # this should use the sql for the object's activity
 346       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 347         "private"
 348
 349       length(cc) > 0 ->
 350         "private"
 351
 352       true ->
 353         "direct"
 354     end
 355   end
 356
 357   def render_content(%{data: %{"type" => "Video"}} = object) do
 358     with name when not is_nil(name) and name != "" <- object.data["name"] do
 359       "<p><a href=\"#{object.data["id"]}\">#{name}</a></p>#{object.data["content"]}"
 360     else
 361       _ -> object.data["content"] || ""
 362     end
 363   end
 364
 365   def render_content(%{data: %{"type" => object_type}} = object)
 366       when object_type in ["Article", "Page"] do
 367     with summary when not is_nil(summary) and summary != "" <- object.data["name"],
 368          url when is_bitstring(url) <- object.data["url"] do
 369       "<p><a href=\"#{url}\">#{summary}</a></p>#{object.data["content"]}"
 370     else
 371       _ -> object.data["content"] || ""
 372     end
 373   end
 374
 375   def render_content(object), do: object.data["content"] || ""
 376
 377   @doc """
 378   Builds a dictionary tags.
 379
 380   ## Examples
 381
 382   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 383   [{"name": "fediverse", "url": "/tag/fediverse"},
 384    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 385
 386   """
 387   @spec build_tags(list(any())) :: list(map())
 388   def build_tags(object_tags) when is_list(object_tags) do
 389     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 390
 391     Enum.reduce(object_tags, [], fn tag, tags ->
 392       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 393     end)
 394   end
 395
 396   def build_tags(_), do: []
 397
 398   @doc """
 399   Builds list emojis.
 400
 401   Arguments: `nil` or list tuple of name and url.
 402
 403   Returns list emojis.
 404
 405   ## Examples
 406
 407   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 408   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 409
 410   """
 411   @spec build_emojis(nil | list(tuple())) :: list(map())
 412   def build_emojis(nil), do: []
 413
 414   def build_emojis(emojis) do
 415     emojis
 416     |> Enum.map(fn {name, url} ->
 417       name = HTML.strip_tags(name)
 418
 419       url =
 420         url
 421         |> HTML.strip_tags()
 422         |> MediaProxy.url()
 423
 424       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 425     end)
 426   end
 427
 428   defp present?(nil), do: false
 429   defp present?(false), do: false
 430   defp present?(_), do: true
 431
 432   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 433     do: id in pinned_activities
 434 end