git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.CommonAPI.Utils
  15   alias Pleroma.Web.MastodonAPI.AccountView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17   alias Pleroma.Web.MediaProxy
  18
  19   # TODO: Add cached version.
  20   defp get_replied_to_activities(activities) do
  21     activities
  22     |> Enum.map(fn
  23       %{data: %{"type" => "Create", "object" => object}} ->
  24         object = Object.normalize(object)
  25         object.data["inReplyTo"] != "" && object.data["inReplyTo"]
  26
  27       _ ->
  28         nil
  29     end)
  30     |> Enum.filter(& &1)
  31     |> Activity.create_by_object_ap_id()
  32     |> Repo.all()
  33     |> Enum.reduce(%{}, fn activity, acc ->
  34       object = Object.normalize(activity)
  35       Map.put(acc, object.data["id"], activity)
  36     end)
  37   end
  38
  39   defp get_user(ap_id) do
  40     cond do
  41       user = User.get_cached_by_ap_id(ap_id) ->
  42         user
  43
  44       user = User.get_by_guessed_nickname(ap_id) ->
  45         user
  46
  47       true ->
  48         User.error_user(ap_id)
  49     end
  50   end
  51
  52   defp get_context_id(%{data: %{"context_id" => context_id}}) when not is_nil(context_id),
  53     do: context_id
  54
  55   defp get_context_id(%{data: %{"context" => context}}) when is_binary(context),
  56     do: Utils.context_to_conversation_id(context)
  57
  58   defp get_context_id(_), do: nil
  59
  60   defp reblogged?(activity, user) do
  61     object = Object.normalize(activity) || %{}
  62     present?(user && user.ap_id in (object.data["announcements"] || []))
  63   end
  64
  65   def render("index.json", opts) do
  66     replied_to_activities = get_replied_to_activities(opts.activities)
  67
  68     opts.activities
  69     |> safe_render_many(
  70       StatusView,
  71       "status.json",
  72       Map.put(opts, :replied_to_activities, replied_to_activities)
  73     )
  74   end
  75
  76   def render(
  77         "status.json",
  78         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  79       ) do
  80     user = get_user(activity.data["actor"])
  81     created_at = Utils.to_masto_date(activity.data["published"])
  82
  83     reblogged_activity =
  84       Activity.create_by_object_ap_id(object)
  85       |> Activity.with_preloaded_bookmarks()
  86       |> Repo.one()
  87
  88     reblogged = render("status.json", Map.put(opts, :activity, reblogged_activity))
  89
  90     activity_object = Object.normalize(activity)
  91     favorited = opts[:for] && opts[:for].ap_id in (activity_object.data["likes"] || [])
  92
  93     bookmarked =
  94       opts[:for] && Ecto.assoc_loaded?(reblogged_activity.bookmarks) &&
  95         Enum.any?(reblogged_activity.bookmarks, fn %{user_id: user_id} ->
  96           user_id == opts[:for].id
  97         end)
  98
  99     mentions =
 100       activity.recipients
 101       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 102       |> Enum.filter(& &1)
 103       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 104
 105     %{
 106       id: to_string(activity.id),
 107       uri: object,
 108       url: object,
 109       account: AccountView.render("account.json", %{user: user}),
 110       in_reply_to_id: nil,
 111       in_reply_to_account_id: nil,
 112       reblog: reblogged,
 113       content: reblogged[:content] || "",
 114       created_at: created_at,
 115       reblogs_count: 0,
 116       replies_count: 0,
 117       favourites_count: 0,
 118       reblogged: reblogged?(reblogged_activity, opts[:for]),
 119       favourited: present?(favorited),
 120       bookmarked: present?(bookmarked),
 121       muted: false,
 122       pinned: pinned?(activity, user),
 123       sensitive: false,
 124       spoiler_text: "",
 125       visibility: "public",
 126       media_attachments: reblogged[:media_attachments] || [],
 127       mentions: mentions,
 128       tags: reblogged[:tags] || [],
 129       application: %{
 130         name: "Web",
 131         website: nil
 132       },
 133       language: nil,
 134       emojis: [],
 135       pleroma: %{
 136         local: activity.local
 137       }
 138     }
 139   end
 140
 141   def render("status.json", %{activity: %{data: %{"object" => _object}} = activity} = opts) do
 142     object = Object.normalize(activity)
 143
 144     user = get_user(activity.data["actor"])
 145
 146     like_count = object.data["like_count"] || 0
 147     announcement_count = object.data["announcement_count"] || 0
 148
 149     tags = object.data["tag"] || []
 150     sensitive = object.data["sensitive"] || Enum.member?(tags, "nsfw")
 151
 152     mentions =
 153       activity.recipients
 154       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 155       |> Enum.filter(& &1)
 156       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 157
 158     favorited = opts[:for] && opts[:for].ap_id in (object.data["likes"] || [])
 159
 160     bookmarked =
 161       opts[:for] && Ecto.assoc_loaded?(activity.bookmarks) &&
 162         Enum.any?(activity.bookmarks, fn %{user_id: user_id} ->
 163           user_id == opts[:for].id
 164         end)
 165
 166     attachment_data = object.data["attachment"] || []
 167     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 168
 169     created_at = Utils.to_masto_date(object.data["published"])
 170
 171     reply_to = get_reply_to(activity, opts)
 172
 173     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 174
 175     content =
 176       object
 177       |> render_content()
 178
 179     content_html =
 180       content
 181       |> HTML.get_cached_scrubbed_html_for_activity(
 182         User.html_filter_policy(opts[:for]),
 183         activity,
 184         "mastoapi:content"
 185       )
 186
 187     content_plaintext =
 188       content
 189       |> HTML.get_cached_stripped_html_for_activity(
 190         activity,
 191         "mastoapi:content"
 192       )
 193
 194     summary = object.data["summary"] || ""
 195
 196     summary_html =
 197       summary
 198       |> HTML.get_cached_scrubbed_html_for_activity(
 199         User.html_filter_policy(opts[:for]),
 200         activity,
 201         "mastoapi:summary"
 202       )
 203
 204     summary_plaintext =
 205       summary
 206       |> HTML.get_cached_stripped_html_for_activity(
 207         activity,
 208         "mastoapi:summary"
 209       )
 210
 211     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 212
 213     url =
 214       if user.local do
 215         Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 216       else
 217         object.data["external_url"] || object.data["id"]
 218       end
 219
 220     %{
 221       id: to_string(activity.id),
 222       uri: object.data["id"],
 223       url: url,
 224       account: AccountView.render("account.json", %{user: user}),
 225       in_reply_to_id: reply_to && to_string(reply_to.id),
 226       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 227       reblog: nil,
 228       card: card,
 229       content: content_html,
 230       created_at: created_at,
 231       reblogs_count: announcement_count,
 232       replies_count: object.data["repliesCount"] || 0,
 233       favourites_count: like_count,
 234       reblogged: reblogged?(activity, opts[:for]),
 235       favourited: present?(favorited),
 236       bookmarked: present?(bookmarked),
 237       muted: CommonAPI.thread_muted?(user, activity) || User.mutes?(opts[:for], user),
 238       pinned: pinned?(activity, user),
 239       sensitive: sensitive,
 240       spoiler_text: summary_html,
 241       visibility: get_visibility(object),
 242       media_attachments: attachments,
 243       mentions: mentions,
 244       tags: build_tags(tags),
 245       application: %{
 246         name: "Web",
 247         website: nil
 248       },
 249       language: nil,
 250       emojis: build_emojis(object.data["emoji"]),
 251       pleroma: %{
 252         local: activity.local,
 253         conversation_id: get_context_id(activity),
 254         in_reply_to_account_acct: reply_to_user && reply_to_user.nickname,
 255         content: %{"text/plain" => content_plaintext},
 256         spoiler_text: %{"text/plain" => summary_plaintext}
 257       }
 258     }
 259   end
 260
 261   def render("status.json", _) do
 262     nil
 263   end
 264
 265   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 266     page_url_data = URI.parse(page_url)
 267
 268     page_url_data =
 269       if rich_media[:url] != nil do
 270         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 271       else
 272         page_url_data
 273       end
 274
 275     page_url = page_url_data |> to_string
 276
 277     image_url =
 278       if rich_media[:image] != nil do
 279         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 280         |> to_string
 281       else
 282         nil
 283       end
 284
 285     site_name = rich_media[:site_name] || page_url_data.host
 286
 287     %{
 288       type: "link",
 289       provider_name: site_name,
 290       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 291       url: page_url,
 292       image: image_url |> MediaProxy.url(),
 293       title: rich_media[:title],
 294       description: rich_media[:description],
 295       pleroma: %{
 296         opengraph: rich_media
 297       }
 298     }
 299   end
 300
 301   def render("card.json", _) do
 302     nil
 303   end
 304
 305   def render("attachment.json", %{attachment: attachment}) do
 306     [attachment_url | _] = attachment["url"]
 307     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 308     href = attachment_url["href"] |> MediaProxy.url()
 309
 310     type =
 311       cond do
 312         String.contains?(media_type, "image") -> "image"
 313         String.contains?(media_type, "video") -> "video"
 314         String.contains?(media_type, "audio") -> "audio"
 315         true -> "unknown"
 316       end
 317
 318     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 319
 320     %{
 321       id: to_string(attachment["id"] || hash_id),
 322       url: href,
 323       remote_url: href,
 324       preview_url: href,
 325       text_url: href,
 326       type: type,
 327       description: attachment["name"],
 328       pleroma: %{mime_type: media_type}
 329     }
 330   end
 331
 332   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 333     object = Object.normalize(activity)
 334
 335     with nil <- replied_to_activities[object.data["inReplyTo"]] do
 336       # If user didn't participate in the thread
 337       Activity.get_in_reply_to_activity(activity)
 338     end
 339   end
 340
 341   def get_reply_to(%{data: %{"object" => _object}} = activity, _) do
 342     object = Object.normalize(activity)
 343
 344     if object.data["inReplyTo"] && object.data["inReplyTo"] != "" do
 345       Activity.get_create_by_object_ap_id(object.data["inReplyTo"])
 346     else
 347       nil
 348     end
 349   end
 350
 351   def get_visibility(object) do
 352     public = "https://www.w3.org/ns/activitystreams#Public"
 353     to = object.data["to"] || []
 354     cc = object.data["cc"] || []
 355
 356     cond do
 357       public in to ->
 358         "public"
 359
 360       public in cc ->
 361         "unlisted"
 362
 363       # this should use the sql for the object's activity
 364       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 365         "private"
 366
 367       length(cc) > 0 ->
 368         "private"
 369
 370       true ->
 371         "direct"
 372     end
 373   end
 374
 375   def render_content(%{data: %{"type" => "Video"}} = object) do
 376     with name when not is_nil(name) and name != "" <- object.data["name"] do
 377       "<p><a href=\"#{object.data["id"]}\">#{name}</a></p>#{object.data["content"]}"
 378     else
 379       _ -> object.data["content"] || ""
 380     end
 381   end
 382
 383   def render_content(%{data: %{"type" => object_type}} = object)
 384       when object_type in ["Article", "Page"] do
 385     with summary when not is_nil(summary) and summary != "" <- object.data["name"],
 386          url when is_bitstring(url) <- object.data["url"] do
 387       "<p><a href=\"#{url}\">#{summary}</a></p>#{object.data["content"]}"
 388     else
 389       _ -> object.data["content"] || ""
 390     end
 391   end
 392
 393   def render_content(object), do: object.data["content"] || ""
 394
 395   @doc """
 396   Builds a dictionary tags.
 397
 398   ## Examples
 399
 400   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 401   [{"name": "fediverse", "url": "/tag/fediverse"},
 402    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 403
 404   """
 405   @spec build_tags(list(any())) :: list(map())
 406   def build_tags(object_tags) when is_list(object_tags) do
 407     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 408
 409     Enum.reduce(object_tags, [], fn tag, tags ->
 410       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 411     end)
 412   end
 413
 414   def build_tags(_), do: []
 415
 416   @doc """
 417   Builds list emojis.
 418
 419   Arguments: `nil` or list tuple of name and url.
 420
 421   Returns list emojis.
 422
 423   ## Examples
 424
 425   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 426   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 427
 428   """
 429   @spec build_emojis(nil | list(tuple())) :: list(map())
 430   def build_emojis(nil), do: []
 431
 432   def build_emojis(emojis) do
 433     emojis
 434     |> Enum.map(fn {name, url} ->
 435       name = HTML.strip_tags(name)
 436
 437       url =
 438         url
 439         |> HTML.strip_tags()
 440         |> MediaProxy.url()
 441
 442       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 443     end)
 444   end
 445
 446   defp present?(nil), do: false
 447   defp present?(false), do: false
 448   defp present?(_), do: true
 449
 450   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 451     do: id in pinned_activities
 452 end