git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.CommonAPI.Utils
  15   alias Pleroma.Web.MastodonAPI.AccountView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17   alias Pleroma.Web.MediaProxy
  18
  19   # TODO: Add cached version.
  20   defp get_replied_to_activities(activities) do
  21     activities
  22     |> Enum.map(fn
  23       %{data: %{"type" => "Create", "object" => object}} ->
  24         object = Object.normalize(object)
  25         object.data["inReplyTo"] != "" && object.data["inReplyTo"]
  26
  27       _ ->
  28         nil
  29     end)
  30     |> Enum.filter(& &1)
  31     |> Activity.create_by_object_ap_id()
  32     |> Repo.all()
  33     |> Enum.reduce(%{}, fn activity, acc ->
  34       object = Object.normalize(activity)
  35       Map.put(acc, object.data["id"], activity)
  36     end)
  37   end
  38
  39   defp get_user(ap_id) do
  40     cond do
  41       user = User.get_cached_by_ap_id(ap_id) ->
  42         user
  43
  44       user = User.get_by_guessed_nickname(ap_id) ->
  45         user
  46
  47       true ->
  48         User.error_user(ap_id)
  49     end
  50   end
  51
  52   defp get_context_id(%{data: %{"context_id" => context_id}}) when not is_nil(context_id),
  53     do: context_id
  54
  55   defp get_context_id(%{data: %{"context" => context}}) when is_binary(context),
  56     do: Utils.context_to_conversation_id(context)
  57
  58   defp get_context_id(_), do: nil
  59
  60   defp reblogged?(activity, user) do
  61     object = Object.normalize(activity) || %{}
  62     present?(user && user.ap_id in (object.data["announcements"] || []))
  63   end
  64
  65   def render("index.json", opts) do
  66     replied_to_activities = get_replied_to_activities(opts.activities)
  67
  68     opts.activities
  69     |> safe_render_many(
  70       StatusView,
  71       "status.json",
  72       Map.put(opts, :replied_to_activities, replied_to_activities)
  73     )
  74   end
  75
  76   def render(
  77         "status.json",
  78         %{activity: %{data: %{"type" => "Announce", "object" => _object}} = activity} = opts
  79       ) do
  80     user = get_user(activity.data["actor"])
  81     created_at = Utils.to_masto_date(activity.data["published"])
  82     activity_object = Object.normalize(activity)
  83
  84     reblogged_activity =
  85       Activity.create_by_object_ap_id(activity_object.data["id"])
  86       |> Activity.with_preloaded_bookmark(opts[:for])
  87       |> Repo.one()
  88
  89     reblogged = render("status.json", Map.put(opts, :activity, reblogged_activity))
  90
  91     favorited = opts[:for] && opts[:for].ap_id in (activity_object.data["likes"] || [])
  92
  93     bookmarked = Activity.get_bookmark(reblogged_activity, opts[:for]) != nil
  94
  95     mentions =
  96       activity.recipients
  97       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  98       |> Enum.filter(& &1)
  99       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 100
 101     %{
 102       id: to_string(activity.id),
 103       uri: activity_object.data["id"],
 104       url: activity_object.data["id"],
 105       account: AccountView.render("account.json", %{user: user}),
 106       in_reply_to_id: nil,
 107       in_reply_to_account_id: nil,
 108       reblog: reblogged,
 109       content: reblogged[:content] || "",
 110       created_at: created_at,
 111       reblogs_count: 0,
 112       replies_count: 0,
 113       favourites_count: 0,
 114       reblogged: reblogged?(reblogged_activity, opts[:for]),
 115       favourited: present?(favorited),
 116       bookmarked: present?(bookmarked),
 117       muted: false,
 118       pinned: pinned?(activity, user),
 119       sensitive: false,
 120       spoiler_text: "",
 121       visibility: "public",
 122       media_attachments: reblogged[:media_attachments] || [],
 123       mentions: mentions,
 124       tags: reblogged[:tags] || [],
 125       application: %{
 126         name: "Web",
 127         website: nil
 128       },
 129       language: nil,
 130       emojis: [],
 131       pleroma: %{
 132         local: activity.local
 133       }
 134     }
 135   end
 136
 137   def render("status.json", %{activity: %{data: %{"object" => _object}} = activity} = opts) do
 138     object = Object.normalize(activity)
 139
 140     user = get_user(activity.data["actor"])
 141
 142     like_count = object.data["like_count"] || 0
 143     announcement_count = object.data["announcement_count"] || 0
 144
 145     tags = object.data["tag"] || []
 146     sensitive = object.data["sensitive"] || Enum.member?(tags, "nsfw")
 147
 148     mentions =
 149       activity.recipients
 150       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 151       |> Enum.filter(& &1)
 152       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 153
 154     favorited = opts[:for] && opts[:for].ap_id in (object.data["likes"] || [])
 155
 156     bookmarked = Activity.get_bookmark(activity, opts[:for]) != nil
 157
 158     attachment_data = object.data["attachment"] || []
 159     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 160
 161     created_at = Utils.to_masto_date(object.data["published"])
 162
 163     reply_to = get_reply_to(activity, opts)
 164
 165     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 166
 167     content =
 168       object
 169       |> render_content()
 170
 171     content_html =
 172       content
 173       |> HTML.get_cached_scrubbed_html_for_activity(
 174         User.html_filter_policy(opts[:for]),
 175         activity,
 176         "mastoapi:content"
 177       )
 178
 179     content_plaintext =
 180       content
 181       |> HTML.get_cached_stripped_html_for_activity(
 182         activity,
 183         "mastoapi:content"
 184       )
 185
 186     summary = object.data["summary"] || ""
 187
 188     summary_html =
 189       summary
 190       |> HTML.get_cached_scrubbed_html_for_activity(
 191         User.html_filter_policy(opts[:for]),
 192         activity,
 193         "mastoapi:summary"
 194       )
 195
 196     summary_plaintext =
 197       summary
 198       |> HTML.get_cached_stripped_html_for_activity(
 199         activity,
 200         "mastoapi:summary"
 201       )
 202
 203     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 204
 205     url =
 206       if user.local do
 207         Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 208       else
 209         object.data["external_url"] || object.data["id"]
 210       end
 211
 212     %{
 213       id: to_string(activity.id),
 214       uri: object.data["id"],
 215       url: url,
 216       account: AccountView.render("account.json", %{user: user}),
 217       in_reply_to_id: reply_to && to_string(reply_to.id),
 218       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 219       reblog: nil,
 220       card: card,
 221       content: content_html,
 222       created_at: created_at,
 223       reblogs_count: announcement_count,
 224       replies_count: object.data["repliesCount"] || 0,
 225       favourites_count: like_count,
 226       reblogged: reblogged?(activity, opts[:for]),
 227       favourited: present?(favorited),
 228       bookmarked: present?(bookmarked),
 229       muted: CommonAPI.thread_muted?(user, activity) || User.mutes?(opts[:for], user),
 230       pinned: pinned?(activity, user),
 231       sensitive: sensitive,
 232       spoiler_text: summary_html,
 233       visibility: get_visibility(object),
 234       media_attachments: attachments,
 235       mentions: mentions,
 236       tags: build_tags(tags),
 237       application: %{
 238         name: "Web",
 239         website: nil
 240       },
 241       language: nil,
 242       emojis: build_emojis(object.data["emoji"]),
 243       pleroma: %{
 244         local: activity.local,
 245         conversation_id: get_context_id(activity),
 246         in_reply_to_account_acct: reply_to_user && reply_to_user.nickname,
 247         content: %{"text/plain" => content_plaintext},
 248         spoiler_text: %{"text/plain" => summary_plaintext}
 249       }
 250     }
 251   end
 252
 253   def render("status.json", _) do
 254     nil
 255   end
 256
 257   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 258     page_url_data = URI.parse(page_url)
 259
 260     page_url_data =
 261       if rich_media[:url] != nil do
 262         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 263       else
 264         page_url_data
 265       end
 266
 267     page_url = page_url_data |> to_string
 268
 269     image_url =
 270       if rich_media[:image] != nil do
 271         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 272         |> to_string
 273       else
 274         nil
 275       end
 276
 277     site_name = rich_media[:site_name] || page_url_data.host
 278
 279     %{
 280       type: "link",
 281       provider_name: site_name,
 282       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 283       url: page_url,
 284       image: image_url |> MediaProxy.url(),
 285       title: rich_media[:title],
 286       description: rich_media[:description],
 287       pleroma: %{
 288         opengraph: rich_media
 289       }
 290     }
 291   end
 292
 293   def render("card.json", _) do
 294     nil
 295   end
 296
 297   def render("attachment.json", %{attachment: attachment}) do
 298     [attachment_url | _] = attachment["url"]
 299     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 300     href = attachment_url["href"] |> MediaProxy.url()
 301
 302     type =
 303       cond do
 304         String.contains?(media_type, "image") -> "image"
 305         String.contains?(media_type, "video") -> "video"
 306         String.contains?(media_type, "audio") -> "audio"
 307         true -> "unknown"
 308       end
 309
 310     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 311
 312     %{
 313       id: to_string(attachment["id"] || hash_id),
 314       url: href,
 315       remote_url: href,
 316       preview_url: href,
 317       text_url: href,
 318       type: type,
 319       description: attachment["name"],
 320       pleroma: %{mime_type: media_type}
 321     }
 322   end
 323
 324   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 325     object = Object.normalize(activity)
 326
 327     with nil <- replied_to_activities[object.data["inReplyTo"]] do
 328       # If user didn't participate in the thread
 329       Activity.get_in_reply_to_activity(activity)
 330     end
 331   end
 332
 333   def get_reply_to(%{data: %{"object" => _object}} = activity, _) do
 334     object = Object.normalize(activity)
 335
 336     if object.data["inReplyTo"] && object.data["inReplyTo"] != "" do
 337       Activity.get_create_by_object_ap_id(object.data["inReplyTo"])
 338     else
 339       nil
 340     end
 341   end
 342
 343   def get_visibility(object) do
 344     public = "https://www.w3.org/ns/activitystreams#Public"
 345     to = object.data["to"] || []
 346     cc = object.data["cc"] || []
 347
 348     cond do
 349       public in to ->
 350         "public"
 351
 352       public in cc ->
 353         "unlisted"
 354
 355       # this should use the sql for the object's activity
 356       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 357         "private"
 358
 359       length(cc) > 0 ->
 360         "private"
 361
 362       true ->
 363         "direct"
 364     end
 365   end
 366
 367   def render_content(%{data: %{"type" => "Video"}} = object) do
 368     with name when not is_nil(name) and name != "" <- object.data["name"] do
 369       "<p><a href=\"#{object.data["id"]}\">#{name}</a></p>#{object.data["content"]}"
 370     else
 371       _ -> object.data["content"] || ""
 372     end
 373   end
 374
 375   def render_content(%{data: %{"type" => object_type}} = object)
 376       when object_type in ["Article", "Page"] do
 377     with summary when not is_nil(summary) and summary != "" <- object.data["name"],
 378          url when is_bitstring(url) <- object.data["url"] do
 379       "<p><a href=\"#{url}\">#{summary}</a></p>#{object.data["content"]}"
 380     else
 381       _ -> object.data["content"] || ""
 382     end
 383   end
 384
 385   def render_content(object), do: object.data["content"] || ""
 386
 387   @doc """
 388   Builds a dictionary tags.
 389
 390   ## Examples
 391
 392   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 393   [{"name": "fediverse", "url": "/tag/fediverse"},
 394    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 395
 396   """
 397   @spec build_tags(list(any())) :: list(map())
 398   def build_tags(object_tags) when is_list(object_tags) do
 399     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 400
 401     Enum.reduce(object_tags, [], fn tag, tags ->
 402       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 403     end)
 404   end
 405
 406   def build_tags(_), do: []
 407
 408   @doc """
 409   Builds list emojis.
 410
 411   Arguments: `nil` or list tuple of name and url.
 412
 413   Returns list emojis.
 414
 415   ## Examples
 416
 417   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 418   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 419
 420   """
 421   @spec build_emojis(nil | list(tuple())) :: list(map())
 422   def build_emojis(nil), do: []
 423
 424   def build_emojis(emojis) do
 425     emojis
 426     |> Enum.map(fn {name, url} ->
 427       name = HTML.strip_tags(name)
 428
 429       url =
 430         url
 431         |> HTML.strip_tags()
 432         |> MediaProxy.url()
 433
 434       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 435     end)
 436   end
 437
 438   defp present?(nil), do: false
 439   defp present?(false), do: false
 440   defp present?(_), do: true
 441
 442   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 443     do: id in pinned_activities
 444 end