git.squeep.com Git - akkoma/blob - lib/pleroma/web/mastodon_api/views/status_view.ex

   1 # Pleroma: A lightweight social networking server
   2 # Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
   3 # SPDX-License-Identifier: AGPL-3.0-only
   4
   5 defmodule Pleroma.Web.MastodonAPI.StatusView do
   6   use Pleroma.Web, :view
   7
   8   alias Pleroma.Activity
   9   alias Pleroma.HTML
  10   alias Pleroma.Object
  11   alias Pleroma.Repo
  12   alias Pleroma.User
  13   alias Pleroma.Web.CommonAPI
  14   alias Pleroma.Web.CommonAPI.Utils
  15   alias Pleroma.Web.MastodonAPI.AccountView
  16   alias Pleroma.Web.MastodonAPI.StatusView
  17   alias Pleroma.Web.MediaProxy
  18
  19   # TODO: Add cached version.
  20   defp get_replied_to_activities(activities) do
  21     activities
  22     |> Enum.map(fn
  23       %{data: %{"type" => "Create", "object" => object}} ->
  24         object = Object.normalize(object)
  25         object.data["inReplyTo"] != "" && object.data["inReplyTo"]
  26
  27       _ ->
  28         nil
  29     end)
  30     |> Enum.filter(& &1)
  31     |> Activity.create_by_object_ap_id()
  32     |> Repo.all()
  33     |> Enum.reduce(%{}, fn activity, acc ->
  34       object = Object.normalize(activity)
  35       Map.put(acc, object.data["id"], activity)
  36     end)
  37   end
  38
  39   defp get_user(ap_id) do
  40     cond do
  41       user = User.get_cached_by_ap_id(ap_id) ->
  42         user
  43
  44       user = User.get_by_guessed_nickname(ap_id) ->
  45         user
  46
  47       true ->
  48         User.error_user(ap_id)
  49     end
  50   end
  51
  52   defp get_context_id(%{data: %{"context_id" => context_id}}) when not is_nil(context_id),
  53     do: context_id
  54
  55   defp get_context_id(%{data: %{"context" => context}}) when is_binary(context),
  56     do: Utils.context_to_conversation_id(context)
  57
  58   defp get_context_id(_), do: nil
  59
  60   defp reblogged?(activity, user) do
  61     object = Object.normalize(activity) || %{}
  62     present?(user && user.ap_id in (object.data["announcements"] || []))
  63   end
  64
  65   def render("index.json", opts) do
  66     replied_to_activities = get_replied_to_activities(opts.activities)
  67
  68     opts.activities
  69     |> safe_render_many(
  70       StatusView,
  71       "status.json",
  72       Map.put(opts, :replied_to_activities, replied_to_activities)
  73     )
  74   end
  75
  76   def render(
  77         "status.json",
  78         %{activity: %{data: %{"type" => "Announce", "object" => object}} = activity} = opts
  79       ) do
  80     user = get_user(activity.data["actor"])
  81     created_at = Utils.to_masto_date(activity.data["published"])
  82
  83     reblogged_activity = Activity.get_create_by_object_ap_id(object)
  84     reblogged = render("status.json", Map.put(opts, :activity, reblogged_activity))
  85
  86     activity_object = Object.normalize(activity)
  87     favorited = opts[:for] && opts[:for].ap_id in (activity_object.data["likes"] || [])
  88     bookmarked = opts[:for] && activity_object.data["id"] in opts[:for].bookmarks
  89
  90     mentions =
  91       activity.recipients
  92       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
  93       |> Enum.filter(& &1)
  94       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
  95
  96     %{
  97       id: to_string(activity.id),
  98       uri: object,
  99       url: object,
 100       account: AccountView.render("account.json", %{user: user}),
 101       in_reply_to_id: nil,
 102       in_reply_to_account_id: nil,
 103       reblog: reblogged,
 104       content: reblogged[:content] || "",
 105       created_at: created_at,
 106       reblogs_count: 0,
 107       replies_count: 0,
 108       favourites_count: 0,
 109       reblogged: reblogged?(reblogged_activity, opts[:for]),
 110       favourited: present?(favorited),
 111       bookmarked: present?(bookmarked),
 112       muted: false,
 113       pinned: pinned?(activity, user),
 114       sensitive: false,
 115       spoiler_text: "",
 116       visibility: "public",
 117       media_attachments: reblogged[:media_attachments] || [],
 118       mentions: mentions,
 119       tags: reblogged[:tags] || [],
 120       application: %{
 121         name: "Web",
 122         website: nil
 123       },
 124       language: nil,
 125       emojis: [],
 126       pleroma: %{
 127         local: activity.local
 128       }
 129     }
 130   end
 131
 132   def render("status.json", %{activity: %{data: %{"object" => _object}} = activity} = opts) do
 133     object = Object.normalize(activity)
 134
 135     user = get_user(activity.data["actor"])
 136
 137     like_count = object.data["like_count"] || 0
 138     announcement_count = object.data["announcement_count"] || 0
 139
 140     tags = object.data["tag"] || []
 141     sensitive = object.data["sensitive"] || Enum.member?(tags, "nsfw")
 142
 143     mentions =
 144       activity.recipients
 145       |> Enum.map(fn ap_id -> User.get_cached_by_ap_id(ap_id) end)
 146       |> Enum.filter(& &1)
 147       |> Enum.map(fn user -> AccountView.render("mention.json", %{user: user}) end)
 148
 149     favorited = opts[:for] && opts[:for].ap_id in (object.data["likes"] || [])
 150
 151     bookmarked =
 152       opts[:for] && Ecto.assoc_loaded?(opts[:for].bookmarks) &&
 153         Enum.any?(opts[:for].bookmarks, fn b -> b.activity_id == activity.id end)
 154
 155     attachment_data = object.data["attachment"] || []
 156     attachments = render_many(attachment_data, StatusView, "attachment.json", as: :attachment)
 157
 158     created_at = Utils.to_masto_date(object.data["published"])
 159
 160     reply_to = get_reply_to(activity, opts)
 161
 162     reply_to_user = reply_to && get_user(reply_to.data["actor"])
 163
 164     content =
 165       object
 166       |> render_content()
 167
 168     content_html =
 169       content
 170       |> HTML.get_cached_scrubbed_html_for_activity(
 171         User.html_filter_policy(opts[:for]),
 172         activity,
 173         "mastoapi:content"
 174       )
 175
 176     content_plaintext =
 177       content
 178       |> HTML.get_cached_stripped_html_for_activity(
 179         activity,
 180         "mastoapi:content"
 181       )
 182
 183     summary = object.data["summary"] || ""
 184
 185     summary_html =
 186       summary
 187       |> HTML.get_cached_scrubbed_html_for_activity(
 188         User.html_filter_policy(opts[:for]),
 189         activity,
 190         "mastoapi:summary"
 191       )
 192
 193     summary_plaintext =
 194       summary
 195       |> HTML.get_cached_stripped_html_for_activity(
 196         activity,
 197         "mastoapi:summary"
 198       )
 199
 200     card = render("card.json", Pleroma.Web.RichMedia.Helpers.fetch_data_for_activity(activity))
 201
 202     url =
 203       if user.local do
 204         Pleroma.Web.Router.Helpers.o_status_url(Pleroma.Web.Endpoint, :notice, activity)
 205       else
 206         object.data["external_url"] || object.data["id"]
 207       end
 208
 209     %{
 210       id: to_string(activity.id),
 211       uri: object.data["id"],
 212       url: url,
 213       account: AccountView.render("account.json", %{user: user}),
 214       in_reply_to_id: reply_to && to_string(reply_to.id),
 215       in_reply_to_account_id: reply_to_user && to_string(reply_to_user.id),
 216       reblog: nil,
 217       card: card,
 218       content: content_html,
 219       created_at: created_at,
 220       reblogs_count: announcement_count,
 221       replies_count: object.data["repliesCount"] || 0,
 222       favourites_count: like_count,
 223       reblogged: reblogged?(activity, opts[:for]),
 224       favourited: present?(favorited),
 225       bookmarked: present?(bookmarked),
 226       muted: CommonAPI.thread_muted?(user, activity) || User.mutes?(opts[:for], user),
 227       pinned: pinned?(activity, user),
 228       sensitive: sensitive,
 229       spoiler_text: summary_html,
 230       visibility: get_visibility(object),
 231       media_attachments: attachments,
 232       mentions: mentions,
 233       tags: build_tags(tags),
 234       application: %{
 235         name: "Web",
 236         website: nil
 237       },
 238       language: nil,
 239       emojis: build_emojis(object.data["emoji"]),
 240       pleroma: %{
 241         local: activity.local,
 242         conversation_id: get_context_id(activity),
 243         in_reply_to_account_acct: reply_to_user && reply_to_user.nickname,
 244         content: %{"text/plain" => content_plaintext},
 245         spoiler_text: %{"text/plain" => summary_plaintext}
 246       }
 247     }
 248   end
 249
 250   def render("status.json", _) do
 251     nil
 252   end
 253
 254   def render("card.json", %{rich_media: rich_media, page_url: page_url}) do
 255     page_url_data = URI.parse(page_url)
 256
 257     page_url_data =
 258       if rich_media[:url] != nil do
 259         URI.merge(page_url_data, URI.parse(rich_media[:url]))
 260       else
 261         page_url_data
 262       end
 263
 264     page_url = page_url_data |> to_string
 265
 266     image_url =
 267       if rich_media[:image] != nil do
 268         URI.merge(page_url_data, URI.parse(rich_media[:image]))
 269         |> to_string
 270       else
 271         nil
 272       end
 273
 274     site_name = rich_media[:site_name] || page_url_data.host
 275
 276     %{
 277       type: "link",
 278       provider_name: site_name,
 279       provider_url: page_url_data.scheme <> "://" <> page_url_data.host,
 280       url: page_url,
 281       image: image_url |> MediaProxy.url(),
 282       title: rich_media[:title],
 283       description: rich_media[:description],
 284       pleroma: %{
 285         opengraph: rich_media
 286       }
 287     }
 288   end
 289
 290   def render("card.json", _) do
 291     nil
 292   end
 293
 294   def render("attachment.json", %{attachment: attachment}) do
 295     [attachment_url | _] = attachment["url"]
 296     media_type = attachment_url["mediaType"] || attachment_url["mimeType"] || "image"
 297     href = attachment_url["href"] |> MediaProxy.url()
 298
 299     type =
 300       cond do
 301         String.contains?(media_type, "image") -> "image"
 302         String.contains?(media_type, "video") -> "video"
 303         String.contains?(media_type, "audio") -> "audio"
 304         true -> "unknown"
 305       end
 306
 307     <<hash_id::signed-32, _rest::binary>> = :crypto.hash(:md5, href)
 308
 309     %{
 310       id: to_string(attachment["id"] || hash_id),
 311       url: href,
 312       remote_url: href,
 313       preview_url: href,
 314       text_url: href,
 315       type: type,
 316       description: attachment["name"],
 317       pleroma: %{mime_type: media_type}
 318     }
 319   end
 320
 321   def get_reply_to(activity, %{replied_to_activities: replied_to_activities}) do
 322     object = Object.normalize(activity)
 323
 324     with nil <- replied_to_activities[object.data["inReplyTo"]] do
 325       # If user didn't participate in the thread
 326       Activity.get_in_reply_to_activity(activity)
 327     end
 328   end
 329
 330   def get_reply_to(%{data: %{"object" => _object}} = activity, _) do
 331     object = Object.normalize(activity)
 332
 333     if object.data["inReplyTo"] && object.data["inReplyTo"] != "" do
 334       Activity.get_create_by_object_ap_id(object.data["inReplyTo"])
 335     else
 336       nil
 337     end
 338   end
 339
 340   def get_visibility(object) do
 341     public = "https://www.w3.org/ns/activitystreams#Public"
 342     to = object.data["to"] || []
 343     cc = object.data["cc"] || []
 344
 345     cond do
 346       public in to ->
 347         "public"
 348
 349       public in cc ->
 350         "unlisted"
 351
 352       # this should use the sql for the object's activity
 353       Enum.any?(to, &String.contains?(&1, "/followers")) ->
 354         "private"
 355
 356       length(cc) > 0 ->
 357         "private"
 358
 359       true ->
 360         "direct"
 361     end
 362   end
 363
 364   def render_content(%{data: %{"type" => "Video"}} = object) do
 365     with name when not is_nil(name) and name != "" <- object.data["name"] do
 366       "<p><a href=\"#{object.data["id"]}\">#{name}</a></p>#{object.data["content"]}"
 367     else
 368       _ -> object.data["content"] || ""
 369     end
 370   end
 371
 372   def render_content(%{data: %{"type" => object_type}} = object)
 373       when object_type in ["Article", "Page"] do
 374     with summary when not is_nil(summary) and summary != "" <- object.data["name"],
 375          url when is_bitstring(url) <- object.data["url"] do
 376       "<p><a href=\"#{url}\">#{summary}</a></p>#{object.data["content"]}"
 377     else
 378       _ -> object.data["content"] || ""
 379     end
 380   end
 381
 382   def render_content(object), do: object.data["content"] || ""
 383
 384   @doc """
 385   Builds a dictionary tags.
 386
 387   ## Examples
 388
 389   iex> Pleroma.Web.MastodonAPI.StatusView.build_tags(["fediverse", "nextcloud"])
 390   [{"name": "fediverse", "url": "/tag/fediverse"},
 391    {"name": "nextcloud", "url": "/tag/nextcloud"}]
 392
 393   """
 394   @spec build_tags(list(any())) :: list(map())
 395   def build_tags(object_tags) when is_list(object_tags) do
 396     object_tags = for tag when is_binary(tag) <- object_tags, do: tag
 397
 398     Enum.reduce(object_tags, [], fn tag, tags ->
 399       tags ++ [%{name: tag, url: "/tag/#{tag}"}]
 400     end)
 401   end
 402
 403   def build_tags(_), do: []
 404
 405   @doc """
 406   Builds list emojis.
 407
 408   Arguments: `nil` or list tuple of name and url.
 409
 410   Returns list emojis.
 411
 412   ## Examples
 413
 414   iex> Pleroma.Web.MastodonAPI.StatusView.build_emojis([{"2hu", "corndog.png"}])
 415   [%{shortcode: "2hu", static_url: "corndog.png", url: "corndog.png", visible_in_picker: false}]
 416
 417   """
 418   @spec build_emojis(nil | list(tuple())) :: list(map())
 419   def build_emojis(nil), do: []
 420
 421   def build_emojis(emojis) do
 422     emojis
 423     |> Enum.map(fn {name, url} ->
 424       name = HTML.strip_tags(name)
 425
 426       url =
 427         url
 428         |> HTML.strip_tags()
 429         |> MediaProxy.url()
 430
 431       %{shortcode: name, url: url, static_url: url, visible_in_picker: false}
 432     end)
 433   end
 434
 435   defp present?(nil), do: false
 436   defp present?(false), do: false
 437   defp present?(_), do: true
 438
 439   defp pinned?(%Activity{id: id}, %User{info: %{pinned_activities: pinned_activities}}),
 440     do: id in pinned_activities
 441 end